在 Excel VBA 中引用 PowerPoint 对象

Question

长话短说 - 我正在尝试将字符串从 PowerShell 传递到 PowerPoint 以更新母版幻灯片上的文本框。我可以在 PowerPoint vba 中执行此操作，但它是完全静态的。当我尝试通过 PowerShell 将数据传递到 PowerPoint 时，我会收到一个我无法解决的错误。 (see here)

因此，我尝试通过 Excel 代理来实现！我已经使用 Excel VBA 来更新 PowerPoint 幻灯片上的内容，所以认为这很合适。我目前在 Excel 中设置了形状，更新了数据，然后将其粘贴到 PowerPoint 幻灯片中，保存并关闭。

我现在需要扩展这个 Excel 宏，使其具有更新母版幻灯片上的文本框的功能。我需要将“PowerPoint VBA”翻译成“Excel VBA for PowerPoint”，多么可怕的一句话……我跑题了：

PowerPoint VBA

Function UpdateMasterF(message As Variant)
    Dim sourceLabel As Shape
    Dim curSLD As Long
    curSLD = ActiveWindow.View.Slide.SlideIndex

    'switch to SlideMaster
    Application.Windows(1).ViewType = ppViewSlideMaster

    Set sourceLabel = ActivePresentation.SlideMaster.CustomLayouts(1).Shapes("sourcelabel")
    sourceLabel.TextFrame.TextRange.Text = message

    'return to default
    Application.Windows(1).ViewType = ppViewNormal

    'set slide
    ActiveWindow.Presentation.Slides(curSLD).Select

Excel VBA

Function TestPowerPoint(message As Variant, presPath As Variant)
    Dim oPPTApp As Object
    Dim oPPTFile As Object

    Set oPPTApp = CreateObject("PowerPoint.Application")
    oPPTApp.Visible = msoTrue
    Set oPPTFile = oPPTApp.Presentations.Open(presPath)

    ' translate e.g. ApplicationWindow, ActivePresentation etc

    oPPTFile.Save
    oPPTFile.Close
    Set oPPTFile = Nothing
    oPPTApp.Quit
    Set oPPTApp = Nothing

我需要能够在 Excel 宏中完成与 PowerPoint VBA 中相同的步骤。不过，我在为它找到正确的名称时遇到了问题。所以它说的地方

Application.Windows(1).ViewType = ppViewSlideMaster

可以用 oPPTApp 或 oPPTFile 代替吗？我已经阅读了MSDN Docs，它似乎匹配但不起作用。

希望这传达了我的要求！我希望大多数人在这种情况下阅读和颤抖......

Answer 1

层次结构是这样的：

要访问在 PPT 中打开的演示文稿，您可以使用例如

Set oPPTPres = oPPTApp.Presentations(1) or
Set oPPTPres = oPPTApp.ActivePresentation

每个演示文稿对象都有一个 Designs 集合，代表演示文稿中的不同母版，因此要访问第一个设计的 SlideMaster，

With oPPTPres.Designs(1).SlideMaster
   ' for example:
   With .Shapes.AddTextbox(msoTextOrientationHorizontal, 100, 100, 500, 50)
      .TextFrame.TextRange.Text = "Well, look at that, will ya!"
   End With

End with

每个设计都有一组自定义布局（您在幻灯片母版视图中看到的缩进主母版下方的缩略图）。可以类似地访问它们。

Answer 2

所以扩展史蒂夫的答案，我决定用一个新的盒子替换现有的盒子，以节省尝试编辑现有形状的痛苦。

我很幸运，我所做的自动化是为了创建新的 PowerPoint 幻灯片，所以当我从一张空白画布创建多个幻灯片时，我可以将这些新形状放在它们上面。

我最终得到相同格式的代码是：

Function TestPowerPoint(message1 As String, message2 As String, presPath As Variant)

set up variables to be used
Dim oPPTApp As PowerPoint.Application
Dim oPPTFile As Object
Dim oPPTPres As PowerPoint.Presentation

Set oPPTApp = CreateObject("PowerPoint.Application")
oPPTApp.Visible = msoTrue
Set oPPTFile = oPPTApp.Presentations.Open(presPath)
Set oPPTPres = oPPTApp.ActivePresentation

With oPPTPres.Designs(1).SlideMaster.CustomLayouts(1)
    With .Shapes.AddTextbox(msoTextOrientationHorizontal, 28, 60, 500, 25)
        .ZOrder msoBringToFront
        With .TextFrame.TextRange
            .Text = message1
            With .Font
                .Size = 10
                .Name = "Calibri"
                .Color = RGB(255, 0, 0)
                .Bold = msoTrue
            End With
        End With
    End With
End With

With oPPTPres.Designs(1).SlideMaster.CustomLayouts(2)
    With .Shapes.AddTextbox(msoTextOrientationHorizontal, 28, 200, 736, 50)
        .ZOrder msoBringToFront
        With .TextFrame.TextRange
            .Text = message2
            .ParagraphFormat.Alignment = ppAlignCenter
            With .Font
                .Size = 32
                .Name = "Calibri"
                .Color = RGB(255, 255, 255)
                .Bold = msoFalse
            End With
        End With
    End With
End With

oPPTFile.Save
oPPTFile.Close
Set oPPTFile = Nothing
oPPTApp.Quit
Set oPPTApp = Nothing

End Function

太棒了！感谢所有做出贡献的人。