如何递归使用 FsCheck 生成器？

Question

我使用 FsCheck 进行基于属性的测试，因此我为自定义类型定义了一组生成器。一些类型由其他类型组成，并且所有类型都有生成器。为字母数字类型定义了一个生成器后，我想为 RelativeUrl 类型定义一个生成器，RelativeUrl 是由斜线符号分隔的 1-9 个字母数字值的列表。这是有效的定义（Alpanumeric 具有将其转换为字符串的“Value”属性）：

static member RelativeUrl() =
    Gen.listOfLength (System.Random().Next(1, 10)) <| Generators.Alphanumeric()
    |> Gen.map (fun list -> String.Join("/", list |> List.map (fun x -> x.Value)) |> RelativeUrl)

尽管它很简单，但我不喜欢使用 Random.Next 方法而不是使用 FsCheck 随机生成器。所以我试着像这样重新定义它：

static member RelativeUrl_1() =
    Arb.generate<byte> 
    |> Gen.map int 
    |> Gen.suchThat (fun x -> x > 0 && x <= 10)
    |> Gen.map (fun length -> Gen.listOfLength length <| Generators.Alphanumeric())
    |> Gen.map (fun list -> String.Join("/", list))

编译器接受它，但实际上它是错误的：最后一条语句中的“列表”不是字母数字值的列表，而是 Gen。下一次尝试：

static member RelativeUrl() =
    Arb.generate<byte> 
    |> Gen.map int 
    |> Gen.suchThat (fun x -> x > 0 && x <= 10)
    |> Gen.map (fun length -> Gen.listOfLength length <| Generators.Alphanumeric())
    |> Gen.map (fun list -> list |> Gen.map (fun elem -> String.Join("/", elem |> List.map (fun x -> x.Value))  |> RelativeUrl))

但这也不起作用：我返回的是 RelativeUrl 的 Gen，而不是 RelativeUrl 的 Gen。那么在不同级别组合生成器的正确方法是什么？

Answer 1

Gen.map有签名(f: 'a -> 'b) -> Gen<'a> -> Gen<'b> - 也就是说，它从'a到'b，然后Gen<'a>，并返回Gen<'b>。人们可能会认为它是“将”给定的函数应用于给定生成器的“内部”。

但是您提供的功能在您的map call是，实际上，int -> Gen<Alphanumeric list> - 也就是说，它返回了一些'b，但更具体地说，特别是Gen<'b>，所以整体表达的结果成为Gen<Gen<Alphanumeric list>>。这就是为什么Gen<Alphanumeric list>显示为下一个map的输入。所有设计。

你真正想要的操作通常被称为bind。此类功能将具有签名(f: 'a -> Gen<'b>) -> Gen<'a> -> Gen<'b>。也就是说，它将采用一个函数，在987654338 @，而不是裸价值。

不幸的是，出于某种原因，Gen不公开bind。它可以作为gen computation expression builder或AS operator >>=（是代表bind）的事实上标准操作员。

给出了上面的解释，您可以更改如下所定义：

static member RelativeUrl_1() =
    Arb.generate<int> 
    |> Gen.suchThat (fun x -> x > 0 && x <= 10)
    >>= (fun length -> Gen.listOfLength length <| Generators.Alphanumeric())
    |> Gen.map (fun list -> String.Join("/", list))

您还可以考虑使用计算表达式来构建生成器。不幸的是，没有为gen 987654346 @表达式构建器定义，因此您仍然必须使用suchThat过滤。但幸运的是，有一个特殊的功能Gen.choose在给定的范围内产生值：

static member RelativeUrl_1() =
  gen {
    // let! length = Arb.generate<int> |> Gen.suchThat (fun l -> l > 0 && l <= 10)
    let! length = Gen.choose (1, 10)
    let! list = Gen.listOfLength length <| Generators.Alphanumeric()
    return String.Join ("/", list)
  }

Answer 2

Fyodor Soikin 的评论表明 Gen.choose 没有用，所以也许我遗漏了一些东西，但这是我的尝试：

open System
open FsCheck

let alphanumericChar = ['a'..'z'] @ ['A'..'Z'] @ ['0'..'9'] |> Gen.elements
let alphanumericString =
    alphanumericChar |> Gen.listOf |> Gen.map (List.toArray >> String)

let relativeUrl = gen {
    let! size = Gen.choose (1, 10)
    let! segments = Gen.listOfLength size alphanumericString
    return String.concat "/" segments }

这似乎有效：

> Gen.sample 10 10 relativeUrl;;
val it : string list =
  ["IC/5p///G/H/ur/vs//"; "l/mGe8spXh//au2WgdL/XvPJhey60X";
   "dxr/0y/1//P93/Ca/D/"; "R/SMJ3BvsM/Fzw4oifN71z"; "52A/63nVPM/TQoICz";
   "Co/1zTNKiCwt1/y6fwDc7U1m/CSN74CwQNl/olneBaJEB/RFqKiCa41l//ADo2MIUPFM/vG";
   "Zm"; "AxRpJ/fP/IOvpX/3yo"; "0/6QuDwiEgC/IpXRO8GA/E7UB8"; "jK/C/X/E4/AL3"]

请注意，我对alphanumericString 的定义可能会生成空字符串，所以有时，正如您从上面的 FSI 示例输出中看到的那样，它会生成带有空段的相对 URL 值。

我将把它作为练习留给读者定义非空字母数字字符串。如果您需要这方面的帮助，请再问一个问题并联系我 ;)