在 FsCheck 中生成自定义数据

Question

我有一个FsCheck 问题：
我有以下记录类型（我提前说，我被告知我的单例 DU 可能是一种矫枉过正，但我​​发现它们描述了域，因此是必要的，除非必须，否则我不会删除它们）：

type Name = Name of string
type Quality = Quality of int
type ShelfLife = Days of int
type Style = Plain | Aged | Legendary

type Item = {
    Name: Name
    Quality: Quality
    ShelfLife: ShelfLife
    Style: Style
}

假设我已经定义了函数repeat: Int -> ('a -> 'a) -> 'a 和decreaseQuality: Item -> Item，我想编写一个检查不变量的FsCheck 测试：任何具有传奇以外风格的项目，在 100 天过去后，都有质量为 0.

我的问题是我不知道FsCheck的以下内容：
1.如何定义自定义生成器，生成样式不是传奇的物品？相比之下，我如何only 定义 Legendary 类型的项目（以测试这两种类型）？

我已经调查过了：

 let itemGenerator = Arb.generate<Item>
 Gen.sample 80 5 itemGenerator

但这会创建很奇怪的项目，因为 size 控制器，在示例中为 80，还控制 Name of string 的长度（由于 of string）并且还产生 Quality 和 @ 987654332@ 我的域不可接受的值（即负数），因为它们都被定义为 ... of int，大小也可以控制。
（我也查看了Gen.oneof...，但结果证明这也是一个错误）。

1. 即使我找到了生成自定义数据的方法，我如何定义一个仅测试记录的 Quality 属性的测试？。

谢谢！

Answer 1

一旦您知道如何使用gen { } 计算表达式来发挥最大作用，您想要的大部分事情都会变得容易。

首先，我将解决如何生成不是传奇的Style。您可以使用Gen.oneOf，但在这种情况下，我认为使用Gen.elements 更简单，因为oneOf 需要使用一系列生成器，但elements 只需要一个项目列表并从该列表中生成一项。所以要生成一个不是传奇的Style，我会使用Gen.elements [Plain; Aged]。 （要生成一个 传奇的Style，我只是不使用生成器，而只是将传奇分配给适当的记录字段，稍后会详细介绍。）

至于名称太长，为了将生成的字符串的大小限制为最多 15 个字符，我会使用：

let genString15 = Gen.sized (fun s -> Gen.resize (min s 15) Arb.generate<string>)
// Note: "min" is not a typo. We want either s or 15, whichever is SMALLER
Gen.sample 80 5 genString15
// Never produces any strings longer than 15 characters

但这仍然可以生成null 字符串，所以我可能会将它用于我的最终版本：

let genString15 =
    Gen.sized (fun s -> Gen.resize (min s 15) Arb.generate<NonNull<string>>)
    |> Gen.map (fun (NonNull x) -> x)  // Unwrap
Gen.sample 80 5 genString15
// Never produces any strings longer than 15 characters, AND never produces null

现在，由于Quality 和ShelfLife 都不能为负数，我将使用PositiveInt（也不允许0）或NonNegativeInt（允许0）。 FsCheck 文档中没有详细记录这两者，但它们的工作方式如下：

let x = Arb.generate<NonNegativeInt>
Gen.sample 80 5 x
// Produces [NonNegativeInt 79; NonNegativeInt 75; NonNegativeInt 0;
//           NonNegativeInt 69; NonNegativeInt 16] which is hard to deal with
let y = Arb.generate<NonNegativeInt> |> Gen.map (fun (NonNegativeInt n) -> n)
Gen.sample 80 5 y
// Much better: [79; 75; 0; 69; 16]

为了避免在 Quality 和 Days 的生成器之间重复代码，我会编写如下内容：

let genNonNegativeOf (f : int -> 'a) = gen {
    let! (NonNegativeInt n) = Arb.generate<NonNegativeInt>
    return (f n)
}
Gen.sample 80 5 (genNonNegativeOf Quality)
// Produces: [Quality 79; Quality 35; Quality 2; Quality 42; Quality 73]
Gen.sample 80 5 (genNonNegativeOf Days)
// Produces: [Days 60; Days 27; Days 50; Days 22; Days 23]

最后，让我们用gen { } CE 以一种漂亮、优雅的方式将这一切联系在一起：

let genNonLegendaryItem = gen {
    let! name = genString15 |> Gen.map Name
    let! quality = genNonNegativeOf Quality
    let! shelfLife = genNonNegativeOf Days
    let! style = Gen.elements [Plain; Aged]
    return {
        Name = name
        Quality = quality
        ShelfLife = shelfLife
        Style = style
    }
}
let genLegendaryItem =
    // This is the simplest way to avoid code duplication
    genNonLegendaryItem
    |> Gen.map (fun item -> { item with Style = Legendary })

然后，一旦你这样做了，要在你的测试中实际使用它，你需要注册生成器，正如 Tarmil 在他的回答中提到的那样。我可能会在这里使用单例 DU，以便测试易于编写，如下所示：

type LegendaryItem = LegendaryItem of Item
type NonLegendaryItem = NonLegendaryItem of Item

然后您将genLegendaryItem 和genNonLegendaryItem 生成器注册为生成(Non)LegendaryItem 类型，方法是将它们传递给Gen.map。然后您的测试用例将如下所示（我将在此处使用Expecto 作为示例）：

[<Tests>]
let tests =
    testList "Item expiration" [
        testProperty "Non-legendary items expire after 100 days" <| fun (NonLegendaryItem item) ->
            let itemAfter100Days = item |> repeat 100 decreaseQuality
            itemAfter100Days.Quality = Quality 0
        testProperty "Legendary items never expire" <| fun (LegendaryItem item) ->
            let itemAfter100Days = item |> repeat 100 decreaseQuality
            itemAfter100Days.Quality > Quality 0
    ]

请注意，使用这种方法，您基本上必须自己编写收缩器，而按照 Tarmil 的建议使用 Arb.convert 可以“免费”获得收缩器。不要低估收缩器的价值，但如果你发现没有它们也能活下去，我喜欢gen { } 计算表达式的优美、简洁的特性，以及阅读生成的代码是多么容易。

Answer 2

要始终生成有效的Quality 和ShelfLife，您需要注册任意实例：

type Arbs =
    static member Quality() =
        Arb.Default.NonNegativeInt()
        |> Arb.convert (fun (NonNegativeInt x) -> Quality x) (fun (Quality x) -> NonNegativeInt x)

    static member ShelfLife() =
        Arb.Default.NonNegativeInt()
        |> Arb.convert (fun (NonNegativeInt x) -> ShelfLife x) (fun (ShelfLife x) -> NonNegativeInt x)

Arb.register<Arbs>()

对于您要检查的实际属性，这里有一个改写有助于将其转换为 FsCheck：如果样式不是传奇，那么 100 天后质量为 0。在代码中：

let ``Non-legendary item breaks after 100 days`` (item: Item) =
    (item.Style <> Legendary) ==>
        let agedItem = item |> repeat 100 decreaseQuality
        agedItem.Quality = Quality 0

Answer 3

在解决了我在了解FsCheck 用法方面遇到的所有问题（目前，我相信我将来会遇到更多问题），this is the repo 与我的整个解决方案。

显然，测试代码位于（我认为恰当地命名）GildedRoseTests 文件夹中。

我使用了上面 rmunn 建议的 gen 计算表达式方法，但我做了一个不同的实验，使用 Tarmil 的 Arb 方法也同样有效（而且你可以“免费”缩小）。