DCG：将余数分配给 DCG {} 代码中的变量

Question

这个答案：Very basic dcg prolog syntax 帮助了我一点，但 [X] 只得到下一个字符，我想要整个辣酱玉米饼馅，继续阅读！

我正在使用 GNU Prolog 编写命令选项解析器，但我被困在 DCG 点上。例如，我有一个查找“foo --as=json”的语法规则，但我无法弄清楚如何获得“任何东西”的结果，代码：

as_opt --> "--as=", anything, { c( as_opt )}, !.
anything --> [], {c(anything_match)}.

而 gprolog 的扩展是：

as_opt([45, 45, 97, 115, 61|A], B) :-
        anything(A, C),
        c(as_opt), !,
        C = B.

anything(A, B) :-
        c(anything_match), !,
        A = B.

“c()”谓词很简单，仅用于跟踪使用 format() 到标准输出执行的规则，因此我可以看到它运行时发生了什么。如果我手动编写代码，我会这样做：

%% for completeness here!
c(Msg) :- format("Processed ~w~n", [Msg]).

as_opt([45, 45, 97, 115, 61|A], B) :-
        anything(A, C),
        c(as_opt), !,
        C = B,
        { g_assign( gvValue, B )}. %% just for example

回到原来的 DCG：

as_opt --> "--as=", anything, { c( as_opt ), gassign( gvValue, ??? )}, !.

那么“？？？”是。有没有可能……应该有。我将重新阅读 gprolog 规则，了解它如何再次扩展 DCG 规则，以防我自己（捂脸）但同时欢迎任何帮助。

谢谢， 肖恩。

Answer 1

有一个比 mat 描述的更好的解决方案，它更快并且避免了虚假的选择点，但它需要支持 call//1 内置非终端，如在例如SWI-Prolog、GNU Prolog 和其他 Prolog 编译器。也在 Logtalk 上。考虑：

as_opt(Option) --> "--as=", list(Option).

list([L|Ls]) --> [L], list(Ls).
list([]) --> [].

as_opt2(Option) --> "--as=", call(rest(Option)).

rest(Rest, Rest, _).

使用 SWI-Prolog 更好地说明差异：

?- phrase(as_opt(Option), "--as=json").
Option = [106, 115, 111, 110] ;
false.

?- phrase(as_opt2(Option), "--as=json").
Option = [106, 115, 111, 110].

?- time(phrase(as_opt(Option), "--as=json")).
% 9 inferences, 0.000 CPU in 0.000 seconds (57% CPU, 562500 Lips)
Option = [106, 115, 111, 110] ;
% 2 inferences, 0.000 CPU in 0.000 seconds (63% CPU, 133333 Lips)
false.

?- time(phrase(as_opt2(Option), "--as=json")).
% 6 inferences, 0.000 CPU in 0.000 seconds (51% CPU, 285714 Lips)
Option = [106, 115, 111, 110].

虚假选择点来自list//1 非终结符的定义。性能差异在于，虽然call//1 允许我们简单地访问隐式列表参数，但list//1 非终端正在逐个元素地执行该隐式参数的列表复制。因此，list//1 版本的性能在--as= 前缀后面的字符上是线性的，而call//1 版本的性能是恒定的，与前缀后面的字符数无关：

?- time(phrase(as_opt(Option), "--as=jsonjsonjsonjsonjsonjsonjsonjsonjsonjsonjsonjson")).
% 54 inferences, 0.000 CPU in 0.000 seconds (83% CPU, 2700000 Lips)
Option = [106, 115, 111, 110, 106, 115, 111, 110, 106|...] ;
% 4 inferences, 0.000 CPU in 0.000 seconds (69% CPU, 137931 Lips)
false.

?- time(phrase(as_opt2(Option), "--as=jsonjsonjsonjsonjsonjsonjsonjsonjsonjsonjsonjson")).
% 6 inferences, 0.000 CPU in 0.000 seconds (79% CPU, 333333 Lips)
Option = [106, 115, 111, 110, 106, 115, 111, 110, 106|...].

Answer 2

我认为你不应该使用全局变量。相反，向 DCG 子句添加参数，以取​​回值：

anything([C|Cs]) --> [C], anything(Cs).
anything([]) --> [].

否则，在规则成功后，剩余部分可用作短语/3 的最后一个参数，“消耗”标题匹配。

Answer 3

您要的是最简单的 DCG 非终结符之一，它可以描述任何列表：

list --> [].
list --> [_], list.

要实际访问正在描述的列表，您需要引入一个参数：

list([])    --> [].
list([L|Ls) --> [L], list(Ls)

你可以这样使用它：

as_opt(Option) --> "--as=", list(Option).