类型族错误

Question

您好，我编写了我的第一个类型为 family 的程序

{-# LANGUAGE TypeFamilies #-}

data Colist a = Colist (Maybe (a,Colist a))

class Listable l where type Item l :: *
    toList :: l -> [Item l]

instance Listable (Colist a) where 
    type Item (Colist a) = (Colist a)
    toList x = [x]

程序应该将 Colist a 放入列表中 我收到“项目 l”无法与实际类型“l”匹配的错误。但我写的是 Item x EQUALS (Colist a)。我的错在哪里？

Answer 1

你是说……

{-# LANGUAGE TypeFamilies #-}

newtype List a = List (Maybe (a, List a))

class Listable l where
    type Item l :: *
    toList :: l -> [Item l]

instance Listable (List a) where
    type Item (List a) = a

    toList (List Nothing) = []
    toList (List (Just (x, xs)) = x : toList xs

我对您的代码进行了一些更改。零，我将Colist 重命名为List（因为在Haskell 中不存在协约列表之类的东西）。一，我修复了缩进，使toList成为Listable类的方法。第二，我让List a 的Item 实例返回a，而不是List a。三，我修复了 toList 以实际返回 List 的元素列表 - 您的版本只是将整个 List 放在一个单例列表中。

我强烈怀疑你在这里滥用类型族。这是这个类的一个更简单、更类似于 Haskell 的表述：

class Listable l where
    toList :: l a -> [a]

instance Listable List where
    toList (List Nothing) = []
    toList (List (Just (x, xs)) = x : toList xs

或者您可以直接派生Foldable 并免费获得toList：

newtype List a = List (Maybe (a, List a)) deriving Foldable

ghci> import Data.Foldable
ghci> toList $ List (Just ('a', List Nothing))
"a"