在 vs-2005 中将特定标签与特定属性匹配而不贪心

Question

我有一堆文件（数百个）具有如下 img 标签：

<img randomAttr1="randomVal" randomAttr2="valueRand" border="0" 
     randomAttr3="someRandValue">

我正在尝试在 Visual Studio 2005 中进行搜索和替换操作，该操作会将标记标识为 ，但仅匹配字符串的边框 =“0”部分。

我的信念是，我需要正则表达式的非贪婪部分来“匹配”（我松散地使用该术语）img 标签，然后实际匹配边框属性，这样我就可以删除它。

我正在使用正则表达式来执行此操作，因为几乎没有一个标记是格式正确的。

我的目标是从所有 img 标签中删除边框属性。

我尝试了以下正则表达式，但似乎无法让它仅匹配边框标签：

(\<img)#.@border=\"[0-9]+\"

我相信 '#' 和 '@' 是非贪婪匹配字符，因为 VS-2005 的文档就是这么说的，因此我认为它不会匹配这么多字符；但是它匹配从

Answer 1

尝试以下方法：（已测试）

查找：{\<img.#}border=\"[0-9]+\"
替换：\1

请注意，这不会匹配在标签和属性之间有换行符的标签。

Answer 2

不要这么快就放弃真正的解析器。例如，给定近乎垃圾的输入

<TagSoup>lskdjfs
sdfkljs sdfalkjdfs
<img randomAttr1=randomVal randomAttr2="valueRand" border="0" 
     randomAttr3="someRandValue">
sdklfjsdflkj
<img randomAttr1="randomVal" randomAttr2="valueRand123"
     randomAttr3=someRandValue456>

下面的代码删除了边框属性。

#! /usr/bin/perl

use warnings;
use strict;

use HTML::Parser;

sub start {
  my($tag,$attr,$attrseq,$text,$skipped) = @_;

  print $skipped;
  unless ($tag eq "img") {
    print $text;
    return;
  }

  my $changed = 0;
  my @seq;
  for (@$attrseq) {
    if (lc($_) eq "border" && $attr->{$_} =~ /^\s*0+\s*$/) {
      delete $attr->{$_};
      $changed = 1;
    }
    else {
      push @seq => $_;
    }
  }

  if ($changed) {
    print "<$tag ",
            join(" " => map qq[$_="$attr->{$_}"], @seq),
          ">";
  }
  else {
    print $text;
  }
}

die "Usage: $0 html-file\n" unless @ARGV == 1;
my $p = HTML::Parser->new(
  api_version => 3,
  marked_sections => 1,
  case_sensitive => 1,
  start_h => [ \&start => "tag, attr, attrseq, text, skipped_text" ],
  end_h => [ sub { print @_ } => "skipped_text, text" ],
);

undef $/;
$p->parse(<>);