Perl 查找和替换（带编号替换）进入无限循环

Question

今天早些时候我发布了一个类似的问题，其解决方案导致了一个新问题，-,-

好吧，故事是我希望 Perl 从文本中捕获 cmets，将它们存储在数组中，然后用新编号的 cmets 替换它们，比如原始 $txt：

//first comment
this is a statement //second comment
//third comment
more statements //fourth comment

我想将 4 个 cmets 推入一个数组，并获得新的 $txt ，例如：

//foo_0
this is a statement //foo_1
//foo_2
more statements //foo_3

我尝试了以下 Perl：

$i=0;
$j=0;
#while ($txt =~ s/(\/\/.*?\n)/\/\/foo_$i\n/gs) {
#while ($txt =~ s/(\/\/.*?\n)/\/\/foo_$i\n/s) {
#foreach ($txt =~ s/(\/\/.*?\n)/\/\/foo_$i\n/gs) {
foreach ($txt =~ s/(\/\/.*?\n)/\/\/foo_$i\n/s) {
        if(defined $1) {
                push (@comments, $1);
                print " \$i=$i\n";
                $i++
                }
        print " \$j=$j\n";
        $j++;
        }

print "after search & replace, we have \$txt:\n";
print $txt;

foreach (0..$#comments) {
        print "\@comments[$_]= @comments[$_]";
        }

在其中，我尝试了四种口味的“while/foreach (... s///gs)”，但它们都没有真正做到我想要的。

“foreach”语句只对文本起作用一次；更糟糕的是，“while”语句将进入无限循环，似乎新的“//foo_xx”内容被放回字符串中以进行进一步的搜索操作，使其成为无限迭代。奇怪的是，这么看似简单的查找替换机制，竟然会陷入死循环，还是有一些我不知道的明显技巧？

顺便说一句，我已经浏览了by highsciguy 的帖子。对他来说，“只需在上面的代码中用 foreach 替换 while 就可以了”；但对我来说，foreach 不起作用，我不知道为什么。

任何人有任何想法可以帮助我解决这个问题吗？谢谢~

Answer 1

我会以不同的方式处理它 - 一个 while 循环逐行读取文件句柄，并从中“抓取”所有注释行。

类似这样的：

#!/usr/bin/perl

use warnings;
use strict;

my @comments; 

#iterate stdin or filename specified on command line
while ( <> ) { 
   #replace anything starting with // with foo_nn
   #where nn is current number of comments. 
   s,//(.*),"//foo_".@comments,e && push (@comments, $1 );
   #$1 is the contents of that bracket - the string we replaced
   #stuff it into commments; 

   #print the current line (altered by the above)
   print;
}
#print the comments. 
print "Comments:\n", join "\n", @comments;

不解决重复问题，如果你有 // 引号或其他东西，它会中断，但对你的例子有用。 while 基于文件句柄逐行迭代。如果您的文本 blob 已经有了标量，那么您可以使用 foreach ( split ( "\n", $text ) ) { 完成相同的操作

输出：

//foo_0
this is a statement //foo_1
//foo_2
more statements //foo_3
Comments:
first comment
second comment
third comment
fourth comment

Answer 2

遍历文本的每一行，如果替换成功，存储注释：

#!/usr/bin/perl

use strict;
use warnings;

my $txt = <<END;                        # define text
//first comment
this is a statement //second comment
//third comment
more statements //fourth comment
END

my @comments = ();
my $i = 0;
foreach (split qq(\n), $txt) {          # iterate over input lines
        if (s&(//.*)&//foo_$i&) {       # do we match?
                push @comments, $1;     # then push comment
                $i++;                   # and increase counter
                }
        print;                          # print modified row
        print qq(\n);                   # print newline
        }

print qq(\nComments:\n);
foreach (@comments) {
        print;                          # print the comment
        print qq(\n);                   # print newline
        }