Excel - 使用组合（值和格式）条件查找和替换

Question

我想为工作表中的所有单元格清空单元格格式并将其设置为常规：

• 包含“MyText”和
• 格式为百分比

我正在使用查找和替换对话框 (CTRL+H)，但是：

• 如果我将“替换为”框留空，则只替换格式； “MyText”仍然存在；
• 如果我在“替换为”框中写入“SomeText”，也会执行文本替换，以及格式替换

看来我无法一次性获得两个替换项（空文本和更改的格式）。

是否有可以在“替换为：”字段中使用的“无”通配符？或者任何其他简单的解决方案？

更新： 我尝试录制宏。 这会进行文本和格式替换：

Application.FindFormat.NumberFormat = "0.00%"
Application.ReplaceFormat.NumberFormat = "General"
Cells.Replace What:="MyText", Replacement:="nothing", LookAt:=xlPart, _
    SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=True, _
    ReplaceFormat:=True

但是如果我删除替换文本，它只会进行格式替换（这在某种程度上是有意义的，但这不是我想要实现的）

Application.FindFormat.NumberFormat = "0.00%"
Application.ReplaceFormat.NumberFormat = "General"
Cells.Replace What:="MyText", Replacement:="", LookAt:=xlPart, _
    SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=True, _
    ReplaceFormat:=True

Answer 1

也许一个简单的循环可能更容易：

Sub FixingData()
    Dim r As Range

    For Each r In ActiveSheet.Cells.SpecialCells(xlCellTypeConstants)
        With r
            If .Value = "MyText" Then
                If .NumberFormat = "0.00%" Then
                    .ClearContents
                    .NumberFormat = "General"
                End If
            End If
        End With
    Next r
End Sub

编辑#1：

这个版本可能会快一点：

Sub FixingDataFast()
    Dim r As Range, rUnion As Range
    Dim calcM

    Set rUnion = Nothing
    calcM = Application.Calculation
    Application.ScreenUpdating = False
    Application.Calculation = xlCalculationManual

    For Each r In ActiveSheet.Cells.SpecialCells(xlCellTypeConstants)
        If r.Value = "MyText" Then
            If r.NumberFormat = "0.00%" Then
                If rUnion Is Nothing Then
                    Set rUnion = r
                Else
                    Set rUnion = Union(rUnion, r)
                End If
            End If
        End If
    Next r

    If rUnion Is Nothing Then
    Else
        rUnion.ClearContents
        rUnion.NumberFormat = "General"
    End If

    Application.ScreenUpdating = True
    Application.Calculation = calcM
End Sub