VBA 受保护的工作表可防止宏替换文本，但单元格不受保护

Question

所以我有这个宏：

Application.Goto (ActiveWorkbook.Sheets("Fetch").Range("C33"))

Range("C33").Value = text
Range("B3").Value = text

Cells.Replace What:="ÿþ", Replacement:="", LookAt:=xlPart, SearchOrder _
        :=xlByRows, MatchCase:=False, SearchFormat:=False, ReplaceFormat:=False

Excel 工作表受到保护，但 C33 和 B3 两个单元格不受保护，因为我希望在这两个单元格中替换文本。

当我在工作表不受保护的情况下运行上述宏时，它可以完美运行。 它与将文本字符串导入 Excel 的脚本一起运行。

当我保护工作表时，宏不会替换文本而是保持不变。

基本上我只想运行宏，定位这两个单元格中的文本，将指定部分替换为空，然后保留其余部分，即使工作表受到保护。

Answer 1

假设：

• 单元格 C33 和 B3 处于“提取”状态并且未锁定，并且
• “Fetch”工作表受到保护

以下方法可行：

With ActiveWorkbook.Sheets("Fetch")

    Union(.Range("C33"), .Range("B3")).Replace What:="ÿþ", Replacement:="", LookAt:=xlPart, SearchOrder _
            :=xlByRows, MatchCase:=False, SearchFormat:=False, ReplaceFormat:=False
            
End With

如果这两个单元格已解锁，则无需移除工作表保护。

---

或者，您可以使用以下方法一次替换一个单元格：

With ActiveWorkbook.Sheets("Fetch")

    .Range("C33").Value = Replace(.Range("C33").Value, "ÿþ", "")
    .Range("B3").Value = Replace(.Range("B3").Value, "ÿþ", "")
            
End With

---

最后，现在我们对发生的事情以及文本如何到达那里有了更清晰的了解，以下可能是最简单的方法：

Sub ParentPath_Import_To_Excel()

    Dim myFile As String
    Dim text As String
    Dim textline As String

    myFile = "H:\Temp\PublicFolder-powershell\ParentPath-FETCH\fullpath_X.txt"
      
    Open myFile For Input As #1
        Do Until EOF(1)
            Line Input #1, textline
            text = text & textline
        Loop
    Close #1

    With ActiveWorkbook.Sheets("Fetch")
        .Range("C33").Value = Replace(text, "ÿþ", "")
        .Range("B3").Value = .Range("C33").Value
        .Range("B3").Activate
    End With
        
End Sub

如果在写入单元格时上述操作失败并出错，则说明您尚未解锁要写入的两个单元格。您可以在格式菜单中解锁一次单元格（这是最好的解决方案），或者您可以解锁整个工作表并在运行时重新锁定它 - 但这对于破解某种解决方案来说是一把大锤。

Answer 2

我决定使用 unprotect 方法，因为上面的联合建议在工作表受到保护时不起作用。

所以我最终得到了以下结果：

Sub ParentPath_Import_To_Excel()

    Dim myFile As String
    Dim text As String
    Dim textline As String

myFile = "H:\Temp\PublicFolder-powershell\ParentPath-FETCH\fullpath_X.txt"

Application.Goto (ActiveWorkbook.Sheets("Fetch").Range("C33"))

Open myFile For Input As #1
Do Until EOF(1)
    Line Input #1, textline
     text = text & textline
Loop

Close #1

Application.Goto (ActiveWorkbook.Sheets("Fetch").Range("C33"))

Range("C33").Value = text 'writes text to cell C33
Range("B3").Value = text 'writes text to cell B3

ActiveWorkbook.Sheets("Fetch").Unprotect  ' This removes the protection of the worksheet, so the search for the BOM-chars can be done, and changed.

Cells.Replace What:="ÿþ", Replacement:="", LookAt:=xlPart, SearchOrder _
        :=xlByRows, MatchCase:=False, SearchFormat:=False, ReplaceFormat:=False

ActiveWorkbook.Sheets("Fetch").Protect ' This protects the worksheet again

End Sub