如何在 Neo4j 中用 Cypher 总结与起始和结束节点不同的节点类型的属性值

Question

我有 Neo4j 社区 3.5.5，我在其中构建了一个包含火车站和车站之间的线路部分的图形数据模型。车站和线段是节点，连接是连接它们的关系。

我想命名一个起点站和一个终点站，并总结其间所有铁路段的长度。我尝试了下面的 Cypher 查询，但 Neo4j 无法将 line_section 识别为节点类型。

match (n1:Station)-[:Connect]-(n2:Station)
where n1.Name='Station1' and n2.Name='Station3'
return sum(Line_Section.length)

我知道可以使用 Neo4j Traversal API 进行求和。是否可以在 Cypher 中执行此操作？

Answer 1

首先capture变量中从开始节点到结束节点的路径，然后reduce它上面的长度属性。

MATCH path=(n1: Station { name: 'Station1' })-[:Connect]->(n2: Station { name: 'Station2' })
RETURN REDUCE (totalLength = 0, node in nodes(path) | totalLength + node.length) as totalDistance

Answer 2

假设线段节点有标签Line_Section，您可以使用variable-length relationship 模式获取整个路径，list comprehension 获取线段节点列表，UNWIND 获取单个节点，然后使用aggregation 到SUM 的所有线段长度：

MATCH p = (n1:Station)-[:Connect*]-(n2:Station)
WHERE n1.Name='Station1' AND n2.Name='Station3'
UNWIND [n IN NODES(p) WHERE 'Line_Section' in LABELS(n)] AS ls
RETURN p, SUM(ls.length) AS distance

或者，您可以使用REDUCE 代替UNWIND 和SUM：

MATCH p = (n1:Station)-[:Connect*]-(n2:Station)
WHERE n1.Name='Station1' AND n2.Name='Station3'
RETURN p, REDUCE(s = 0, ls IN [n IN NODES(p) WHERE 'Line_Section' in LABELS(n)] |
  s + ls.length) AS distance

[更新]

Note: a variable-length relationship with an unbounded number of hops is expensive, and can take a long time or run out of memory.

If you only want the distance for the shortest path, then this should be faster:

MATCH
  (n1:Station { name: 'Station1' }),
  (n2:Station {name: 'Station3' }),
  p = shortestPath((n1)-[*]-(n2))
WHERE ALL(r IN RELATIONSHIPS(p) WHERE TYPE(r) = 'Connect')
RETURN p, REDUCE(s = 0, ls IN [n IN NODES(p) WHERE 'Line_Section' in LABELS(n)] |
  s + ls.length) AS distance