在 Cmake 中允许相互依赖

Question

我正在尝试将大量代码从自定义的内部工具链迁移到 Cmake。此代码由许多共享库和一些可执行文件组成。

其中一些库是相互依赖的。我们以 Lib1 和 Lib2 为例，其中 Lib1 使用来自 Lib2 的符号，而 Lib2 使用来自 Lib1 的符号。
为了创建 Lib1 DLL，我们需要从 Lib2 导出符号，而后者又需要从 Lib1 导出符号。目前我们通过两个阶段的链接解决了这个问题，如下所述：Mutual Imports )。这为我们提供了以下步骤：

1. 创建 lib1.lib 和 lib1.exp
   创建 lib2.lib 和 lib2.exp
2. 使用 lib1.obj 和 lib2.lib/lib2.exp 创建 lib1.DLL
   使用 lib2.obj 和 lib1.lib/lib1.exp 创建 lib2.DLL

我知道这是代码异味，但代码库太大，无法尝试纠正所有这些循环。所以我想使用 Cmake 得到类似的结果。我没有从文档中找到任何方法，除了只使用自定义命令会完全违背这个工具的目的。

旧版工具链执行以下调用：

# compile sources
cl lib1\SRC\lib1help.cpp ... /Fo"build\cl\lib1.obj"
cl lib2\SRC\lib2help.cpp ... /Fo"build\cl\lib2.obj"

# create lib + exp symbols
lib /DEF build\cl\lib1.obj /OUT:build\link1\lib1.lib
lib /DEF build\cl\lib2.obj /OUT:build\link1\lib2.lib

# create mutual dependant dll using exp
link build\cl\lib1.obj build\link1\lib2.lib /DLL /OUT:build\link2\lib1.dll 
link build\cl\lib2.obj build\link1\lib1.lib /DLL /OUT:build\link2\lib2.dll

到目前为止，我有以下 CmakeLists.txt：

add_library(lib2 SHARED lib2/src/lib2help.cpp)
add_library(lib1 SHARED lib1/src/lib1help.cpp)

target_include_directories(lib1 PUBLIC lib1/include/)
target_compile_definitions(lib1 PRIVATE __LIB1)
target_link_libraries(lib1 PRIVATE lib2)

target_include_directories(lib2 PUBLIC lib2/include/)
target_compile_definitions(lib2 PRIVATE __LIB2)
target_link_libraries(lib2 PRIVATE lib1)

这给了我以下结果：

[cmake] CMake Error: The inter-target dependency graph contains the following strongly connected component (cycle)  
[cmake]   "lib2" of type SHARED_LIBRARY  
[cmake]     depends on "lib1" (weak)  
[cmake]   "lib1" of type SHARED_LIBRARY  
[cmake]     depends on "lib2" (weak)  

你们知道我可以使用 Cmake 实现这个的方法吗？
目前我计划只针对 Windows 系统，但与操作系统无关的系统会很棒！

谢谢

Answer 1

我非常专注于制作一个 SHARED 库，所以我没有探索 STATIC+SHARED 方式。感谢@arrowd 和@tsyvaref 的建议。

我使用以下 CmakeLists.txt 让它工作

add_library(lib1_obj OBJECT src/lib1help.cpp)
target_include_directories(lib1_obj PUBLIC include/)
target_include_directories(lib1_obj PRIVATE $<TARGET_PROPERTY:lib2_obj,INCLUDE_DIRECTORIES>)
target_compile_definitions(lib1_obj PRIVATE __LIB1)

add_library(lib1_static STATIC $<TARGET_OBJECTS:lib1_obj>)
target_link_libraries(lib1_static PUBLIC lib2_static)
set_target_properties(lib1_static PROPERTIES STATIC_LIBRARY_OPTIONS "/DEF") 
set_target_properties(lib1_static PROPERTIES OUTPUT_NAME lib1)

add_library(lib1_shared SHARED $<TARGET_OBJECTS:lib1_obj>)
target_link_libraries(lib1_shared PRIVATE lib1_static)
set_target_properties(lib1_shared PROPERTIES RUNTIME_OUTPUT_NAME lib1)

add_library(lib1 ALIAS lib1_shared) 

lib2 使用完全相同的文件，当然切换名称除外。 我不确定这是不是最好的方法，但我现在很高兴。 这是正在发生的事情：

• 将源代码编译到 OBJECT 库中
• 将相互依赖的库链接为静态，使用“/DEF”创建导出文件
• 重命名静态库输出以方便链接器使用
• 使用预先创建的 .obj、.lib 和 .exp 链接共享库
• 重命名共享库 dll 以方便使用

这里我们可以使用Dependency Walker查看每个DLL的内容：