如何使用 CMD 从文件路径中获取文件夹路径

Question

我需要包含 cmd 文件的文件夹的路径。 使用%0 我可以获得文件名。但是如何获取文件夹名称呢？

c:\temp\test.cmd >> test.cmd

附：我的当前目录！= 脚本文件夹。

Answer 1

对于文件夹名称和驱动器，您可以使用：

echo %~dp0

您可以使用不同的修饰符获得更多信息：

%~I         - expands %I removing any surrounding quotes (")
%~fI        - expands %I to a fully qualified path name
%~dI        - expands %I to a drive letter only
%~pI        - expands %I to a path only
%~nI        - expands %I to a file name only
%~xI        - expands %I to a file extension only
%~sI        - expanded path contains short names only
%~aI        - expands %I to file attributes of file
%~tI        - expands %I to date/time of file
%~zI        - expands %I to size of file

The modifiers can be combined to get compound results:
%~dpI       - expands %I to a drive letter and path only
%~nxI       - expands %I to a file name and extension only
%~fsI       - expands %I to a full path name with short names only

这是“for /?”的复制粘贴提示符下的命令。希望对您有所帮助。

相关

Top 10 DOS Batch tips (Yes, DOS Batch...) 显示batchparams.bat（作为要点链接到源）：

C:\Temp>batchparams.bat c:\windows\notepad.exe
%~1     =      c:\windows\notepad.exe
%~f1     =      c:\WINDOWS\NOTEPAD.EXE
%~d1     =      c:
%~p1     =      \WINDOWS\
%~n1     =      NOTEPAD
%~x1     =      .EXE
%~s1     =      c:\WINDOWS\NOTEPAD.EXE
%~a1     =      --a------
%~t1     =      08/25/2005 01:50 AM
%~z1     =      17920
%~$PATHATH:1     =
%~dp1     =      c:\WINDOWS\
%~nx1     =      NOTEPAD.EXE
%~dp$PATH:1     =      c:\WINDOWS\
%~ftza1     =      --a------ 08/25/2005 01:50 AM 17920 c:\WINDOWS\NOTEPAD.EXE

Answer 2

为了将这些分配给变量，请确保不要在等号前后添加空格：

set filepath=%~dp1
set filename=%~nx1

那么你应该没有问题。

Answer 3

接受的答案很有帮助，但如果您不使用传入的值，如何从路径中检索文件名并不是很明显。我能够从这个线程中解决这个问题，但如果其他人不那么幸运，那么它是如何完成的：

@echo off
setlocal enabledelayedexpansion enableextensions

set myPath=C:\Somewhere\Somewhere\SomeFile.txt
call :file_name_from_path result !myPath!
echo %result%
goto :eof

:file_name_from_path <resultVar> <pathVar>
(
    set "%~1=%~nx2"
    exit /b
)

:eof
endlocal

现在:file_name_from_path 函数可以在任何地方使用来检索值，而不仅仅是用于传入的参数。如果可以以不确定的顺序将参数传递到文件中，或者根本没有将路径传递到文件中，这将非常有用。

Answer 4

如果有人想要另一种方法......

如果是路径的最后一个子目录，可以用这个单行：

cd "c:\directory\subdirectory\filename.exe\..\.." && dir /ad /b /s

这将返回以下内容：

c:\directory\subdirectory

.... 回退到上一个目录。 /ad 只显示目录 /b 是一个裸格式列表 /s 包括所有子目录。这用于获取要打印的目录的完整路径。

Answer 5

我在循环中遇到了同样的问题，我想在同一目录中提取 zip 文件，然后删除该 zip 文件。问题是 7z 需要输出文件夹，所以我必须获取每个文件的文件夹路径。这是我的解决方案：

FOR /F "usebackq tokens=1" %%i IN (`DIR /S/B *.zip` ) DO (
  7z.exe x %%i -aoa -o%%i\..
) 

%%i 是完整的文件名路径，%ii\.. 只是返回父文件夹。

希望对您有所帮助。

Answer 6

如果 Wadih 接受的答案不适合您，请尝试 echo %CD%

Answer 7

这是与一些经过编辑的示例 cmd 放在一起的

@Echo off

Echo ********************************************************
Echo *  ZIP Folder Backup using 7Zip                        *
Echo *  Usage: Source Folder, Destination Drive Letter      *
Echo *  Source Folder will be Zipped to Destination\Backups *
Echo ********************************************************
Echo off

set year=%date:~-4,4%
set month=%date:~-10,2%
set day=%date:~-7,2%
set hour=%time:~-11,2%
set hour=%hour: =0%
set min=%time:~-8,2%

SET /P src=Source Folder to Backup: 
SET source=%src%\*
call :file_name_from_path nam %src%
SET /P destination=Backup Drive Letter:
set zipfilename=%nam%.%year%.%month%.%day%.%hour%%min%.zip
set dest="%destination%:\Backups\%zipfilename%"


set AppExePath="%ProgramFiles(x86)%\7-Zip\7z.exe"
if not exist %AppExePath% set AppExePath="%ProgramFiles%\7-Zip\7z.exe"

if not exist %AppExePath% goto notInstalled

echo Backing up %source% to %dest%

%AppExePath% a -r -tzip %dest% %source%

echo %source% backed up to %dest% is complete!

TIMEOUT 5

exit;

:file_name_from_path <resultVar> <pathVar>
(
    set "%~1=%~nx2"
    exit /b
)


:notInstalled

echo Can not find 7-Zip, please install it from:
echo  http://7-zip.org/

:end
PAUSE