接口、匿名方法和内存泄漏

Question

这是一个构造示例。我不想在这里发布原始代码。不过我尝试提取相关部分。

我有一个管理侦听器列表的界面。

TListenerProc = reference to procedure (SomeInt : ISomeInterface);

ISomeInterface = interface
   procedure AddListener (Proc : TListenerProc);   
end;

现在我注册一个监听器：

SomeObj.AddListener (MyListener);

procedure MyListener (SomeInt : ISomeInterface);
begin
  ExecuteSynchronized (procedure
                       begin
                       DoSomething (SomeInt);
                       end);
end;

我确实遇到了内存泄漏。匿名方法和接口都永远不会被释放。我怀疑这是由于这里的某种循环引用。匿名方法使接口保持活力，接口使匿名方法保持活力。

两个问题：

1. 你支持这个解释吗？还是我在这里错过了其他东西？
2. 我能做些什么吗？

提前致谢！

---

编辑：在一个小到可以在此处发布的应用程序中重现此内容并不容易。我现在能做的最好的事情如下。匿名方法在这里没有发布：

program TestMemLeak;

{$APPTYPE CONSOLE}

uses
  Generics.Collections, SysUtils;

type
  ISomeInterface = interface;
  TListenerProc  = reference to procedure (SomeInt : ISomeInterface);

  ISomeInterface = interface
  ['{DB5A336B-3F79-4059-8933-27699203D1B6}']
    procedure AddListener (Proc : TListenerProc);
    procedure NotifyListeners;
    procedure Test;
  end;

  TSomeInterface = class (TInterfacedObject, ISomeInterface)
  strict private
    FListeners          : TList <TListenerProc>;
  protected
    procedure AddListener (Proc : TListenerProc);
    procedure NotifyListeners;
    procedure Test;
  public
    constructor Create;
    destructor  Destroy; override;
  end;


procedure TSomeInterface.AddListener(Proc: TListenerProc);
begin
FListeners.Add (Proc);
end;

constructor TSomeInterface.Create;
begin
FListeners := TList <TListenerProc>.Create;
end;

destructor TSomeInterface.Destroy;
begin
FreeAndNil (FListeners);
  inherited;
end;

procedure TSomeInterface.NotifyListeners;

var
  Listener : TListenerProc;

begin
for Listener in FListeners do
  Listener (Self);
end;

procedure TSomeInterface.Test;
begin
// do nothing
end;

procedure Execute (Proc : TProc);

begin
Proc;
end;

procedure MyListener (SomeInt : ISomeInterface);
begin
Execute (procedure
         begin
         SomeInt.Test;
         end);
end;

var
  Obj     : ISomeInterface;

begin
  try
    ReportMemoryLeaksOnShutdown := True;
    Obj := TSomeInterface.Create;
    Obj.AddListener (MyListener);
    Obj.NotifyListeners;
    Obj := nil;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

Answer 1

您的代码远非最小。以下：

program AnonymousMemLeak;

{$APPTYPE CONSOLE}

uses
  SysUtils;

type
  TListenerProc  = reference to procedure (SomeInt : IInterface);

procedure MyListener (SomeInt : IInterface);
begin
end;

var
  Listener: TListenerProc;

begin
  try
    ReportMemoryLeaksOnShutdown := True;

    Listener := MyListener;
    Listener := nil;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

有同样的问题（这里是 Delphi 2009）。这是无法解决或设计的。在我看来，这就像编译器中的错误。

编辑：

或者这可能是内存泄漏检测的问题。它与作为接口的参数无关，无参数过程会导致相同的“泄漏”。很奇怪。

Answer 2

在我看来，这是一个明确的循环引用问题。匿名方法是通过隐藏接口管理的，如果 TList<TListenerProc> 归实现 ISomeInterface 的对象所有，那么您就会遇到循环引用问题。

一种可能的解决方案是在 ISomeInterface 上放置一个 ClearListeners 方法，该方法在 TList<TListenerProc> 上调用 .Clear。只要没有其他东西持有对匿名方法的引用，这将使它们全部消失并放弃对 ISomeInterface 的引用。

我写了几篇关于匿名方法的结构和实现的文章，这些文章可能会帮助您了解您真正使用的是什么以及它们如何更好地运行。你可以在http://tech.turbu-rpg.com/category/delphi/anonymous-methods找到他们。

Answer 3

问题在于 dpr main 中的匿名方法。

只需将您的代码放入例程中并在 dpr main 中调用它，内存泄漏报告就消失了。

procedure Main;
var
  Obj: ISomeInterface;
begin
  try
    ReportMemoryLeaksOnShutdown := True;
    Obj := TSomeInterface.Create;
    Obj.AddListener (MyListener);
    Obj.NotifyListeners;
    Obj := nil;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end;

begin
  Main;
end.