只是想知道，VBA 中是否有与 VB .NET 的 PadLeft 和 PadRight 方法等效的方法？
到目前为止，每当我想获取一个字符串并将其设置为带有前导空格的固定长度时，我都会根据字符串的长度执行 For...Next 循环。
例如，我将使用以下代码将字符串格式化为 8 个字符并带有前导空格：
intOrdNoLen = Len(strOrdNo)
For i = 1 To (8 - intOrdNoLen) Step 1
strOrdNo = " " & strOrdNo
Next
有没有办法在 VBA 中用更少的行来做同样的事情？
【问题讨论】：
我对这个答案采取了不同的方法。它不是最简单的，但可能是最通用的。我使用了 LittleBobbyTables 和 Brad 的一些代码来制作这个。下面是几个如何使用该函数的例子：
Sub test()
Debug.Print PadStr("ABC", 6) 'returns "ABC "
Debug.Print PadStr("ABC", 6, "-") 'returns "ABC---"
Debug.Print PadStr("ABC", 6, , xlHAlignRight) 'returns " ABC"
Debug.Print PadStr("ABC", 7, "*", xlHAlignCenter) 'returns "**ABC**"
Debug.Print PadStr("ABC", 9, "*", xlHAlignDistributed) 'returns "**A**B*C*"
Debug.Print PadStr("ABC", 7, "*", xlHAlignFill) 'returns "ABCABCA"
End Sub
函数如下：
Function PadStr(Expression As Variant, length As Integer, Optional padChar As String = " ", Optional alignment As XlHAlign = xlHAlignGeneral) As String
'Pads a string with a given character.
'@Expression - the string to pad
'@length - the minimum length of the string (if @Expression is longer than @length, the original Expression will be returned)
'@padChar - the character to pad with (a space by default)
'@alignment - what type of alignment to use. Uses the XlAlign object for enumeration.
' xlHAlignLeft - (Default) Aligns input text to the left
' xlHAlignGeneral - Same as Default
' xlHAlignRight - Aligns input text to the right
' xlHAlignCenter - Center aligns text
' xlHAlignCenterAcrossSelection - Same as xlHAlignCenter
' xlHAlignDistributed - Distributes the text evenly within the length specified
' xlHAlignJustify - Same as xlHAlignDistributed
' xlHAlignFill - Fills the specified length with the text
'example: if input is "ABC", " ", "8", see code below for what the output will be given the different direction options
If Len(Expression) >= length Or (padChar = "" And alignment <> xlHAlignFill) Then
'if input is longer than pad-length padChar or no input given for padChar (note: padChar doesn't matter when
'using xlHAlignFill) just return the input
PadStr = Expression
ElseIf Len(padChar) <> 1 And alignment <> xlHAlignFill Then
'give error if padChar is not exactly 1 char in length (again, padChar doesn't matter when using xlHAlignFill)
'padChar must be 1 char long because string() only accepts 1 char long input.
Err.Raise vbObjectError + 513, , "input:'padChar' must have length 1." & vbNewLine & "SUB:PadStr"
Else
Dim pStr As String, i As Long
Select Case alignment
Case xlHAlignLeft, xlHAlignGeneral '(Default)
'"ABC "
PadStr = CStr(Expression) & String(length - Len(CStr(Expression)), padChar)
Case xlHAlignRight
'" ABC"
PadStr = String(length - Len(CStr(Expression)), padChar) & CStr(Expression)
Case xlHAlignCenter, xlHAlignCenterAcrossSelection
'" ABC "
pStr = String(Application.WorksheetFunction.RoundUp((length / 2) - (Len(Expression) / 2), 0), padChar)
PadStr = pStr & Expression & pStr
Case xlHAlignDistributed, xlHAlignJustify
'" A B C " (" A B C " if lenth=9)
Dim insPos As Long, loopCntr As Long: loopCntr = 1
PadStr = Expression
Do While Len(PadStr) < length
For i = 1 To Len(Expression)
PadStr = Left(PadStr, insPos) & padChar & Right(PadStr, Len(PadStr) - insPos)
insPos = insPos + 1 + loopCntr
If Len(PadStr) >= length Then Exit For
Next i
PadStr = PadStr & padChar
loopCntr = loopCntr + 1
insPos = 0
Loop
Case xlHAlignFill
'"ABCABCAB"
For i = 1 To Application.WorksheetFunction.RoundUp(length / Len(Expression), 0)
PadStr = PadStr & Expression
Next i
Case Else
'error
Err.Raise vbObjectError + 513, , "PadStr does not support the direction input ( " & direction & ")." & vbNewLine & "SUB:PadStr"
End Select
PadStr = Left(PadStr, length) 'output cannot be longer than the given length
End If
End Function
【讨论】：
合并前两个答案（感谢 LittleBobbyTables 和 Brad）并注意辅助函数 max，我建议：
Function PadLeft(ByVal text As Variant, ByVal totalLength As Integer, ByVal padCharacter As String) As String
PadLeft = Right(String(totalLength, padCharacter) & CStr(text), max(totalLength, Len(CStr(text))))
End Function
Function PadRight(ByVal text As Variant, ByVal totalLength As Integer, ByVal padCharacter As String) As String
PadRight = Left(CStr(text) & String(totalLength, padCharacter), max(totalLength, Len(CStr(text))))
End Function
Public Function max(ByVal x As Variant, ByVal y As Variant) As Variant
max = IIf(x > y, x, y)
End Function
totalLength 最好命名为 minimumLength，因为总是返回整个原始字符串，可能导致结果比 minimumLength 长。
【讨论】：
Excel.WorksheetFunction.Max，尽管这会使解决方案不再是纯 VBA/VB Classic。
我通过重新分配变量解决了这个问题。
在我的代码中，我从工作簿单元格获取数据并将其限制为 5 个字符（如有必要，填充足够的 0..）：
MB = Right(String(5, "0") & Worksheets("HOME").Range("b3"), 5)
MB = Right(MB, 5)
【讨论】：
Format("abc","!@@@@@@") ' width >= 6; pad right side with spaces
Format("abc","@@@@@@") ' width >= 6; pad left side with spaces
【讨论】：
你可以使用这些。将它们放在公共模块中
'NB 如果输入字符串长于总长度则失败
Function PadLeft(text As Variant, totalLength As Integer, padCharacter As String) As String
PadLeft = String(totalLength - Len(CStr(text)), padCharacter) & CStr(text)
End Function
Function PadRight(text As Variant, totalLength As Integer, padCharacter As String) As String
PadRight = CStr(text) & String(totalLength - Len(CStr(text)), padCharacter)
End Function
【讨论】：
您还可以在 VBA 中使用固定长度的字符串：
Dim myString As String * 10
myString = "test"
Debug.Print myString, "(" & Len(myString) & ")" '// Prints "test (10)"
虽然这只对右边的填充有用。
【讨论】：
由于我们一般在左侧填充，所以 Format() 函数更短，更简单：
Format(number, " ")
Format(number, "00")
【讨论】：
? "!" & Format("a"," ") & "!"，你会得到!a!，并带有一个数字：? "!" & Format(1.23," ") & "!" 给出! !
我不相信有任何明确的PADLEFT 或PADRIGHT 函数，但您可以使用SPACE 和LEFT 或RIGHT 的组合在您的字符串前面添加空格，然后获取右 X 个字符。
PADLEFT
strOrdNo = RIGHT(Space(8) & strOrdNo, 8)
如果你想要一个字符而不是空格，你可以使用STRING 来代替空格（下面的例子左-pads 与 X）：
strOrdNo = RIGHT(String(8, "X") & strOrdNo, 8)
PADRIGHT
strOrdNo = LEFT(strOrdNo & Space(8), 8)
strOrdNo = LEFT(strOrdNo & String(8, "X"), 8)
【讨论】：