Excel VBA 突出显示活动列中的重复项

Question

我正在尝试创建一个宏，该宏将突出显示正在输入文本的列中的重复项。

我有 54 列，并希望在输入文本时突出显示每列中的重复项。场景是：如果在 B 列中输入两次“订书钉”，则单元格（B3、B22）将被突出显示。我想要一个可以为每一列执行此操作的宏，所以如果“STAPLES”仅在 E 列中输入一次，则不会发生任何事情。

使用条件格式 =COUNTIF 不一定有帮助（由于将列复制到新工作表的工作流程）。

我已经有了这个宏：

Private Sub Worksheet_SelectionChange(ByVal Target As Range)


Dim Rng As Range
Dim cel As Range

'Test for duplicates in a single column
'Duplicates will be highlighted in red


Set Rng = Range(Range("C1"), Range("C" & Rows.Count).End(xlUp))


For Each cel In Rng
    If WorksheetFunction.CountIf(Rng, cel.Value) > 1 Then

cel.Interior.ColorIndex = 3
    End If
Next cel

End Sub

它工作正常，但仅适用于一列（“C”）。

如何将范围设置为活动列？

我已经尝试将 Rng 更改为

'Set Rng = Range(ActiveCell,ActiveCell.Column.End(xlUp)) 

但这显然是错误的。

有什么想法吗？

Answer 1

试试这个：

Set Rng = Range(Cells(1, Target.Column), Cells(Rows.Count, Target.Column).End(xlUp))

最好使用Worksheet_Change 事件而不是Worksheet_SelectionChange。

顺便说一句，重复项有特殊的 CF：

---

统一更新： 如果您想使用 VBA，请尝试以下代码：

Private Sub Worksheet_Change(ByVal Target As Range)

    Dim Rng As Range
    Dim cel As Range
    Dim col As Range
    Dim c As Range
    Dim firstAddress As String



    'Duplicates will be highlighted in red
    Target.Interior.ColorIndex = xlNone
    For Each col In Target.Columns
        Set Rng = Range(Cells(1, col.Column), Cells(Rows.Count, col.Column).End(xlUp))
        Debug.Print Rng.Address

        For Each cel In col
            If WorksheetFunction.CountIf(Rng, cel.Value) > 1 Then
                Set c = Rng.Find(What:=cel.Value, LookIn:=xlValues)
                If Not c Is Nothing Then
                    firstAddress = c.Address
                    Do
                        c.Interior.ColorIndex = 3
                        Set c = Rng.FindNext(c)
                    Loop While Not c Is Nothing And c.Address <> firstAddress
                End If
            End If
        Next
    Next col

End Sub