如何在 perl 的范围内获取开始/结束日期的哈希值，其中开始日期和结束日期不是月份的开始/结束？

Question

我要做的是，给定格式为 YYYY-MM-DD 的开始和结束日期，编写一个函数，该函数将返回该格式的日期键/值对，表示中间月份的开始和结束需要注意的是，第一对将以任何开始日期开始，最后一对将以任何结束日期结束。虽然我认为 Date::Manip 或 Date::Calc 可以完成这项工作，但我一直无法找到所需的解决方案。

例如，如果调用看起来像：

&get_date_pairs('2014-08-18', '2014-10-17');

那么函数返回的哈希值如下：

%hash = (
        2014-08-18 => 2014-08-31,
        2014-09-01 => 2014-09-30,
        2014-10-01 => 2014-10-17,

);

Answer 1

你没有说你遇到了什么问题，所以我猜你是在要求一种算法来实现你想要的。

1. 将 $current_date 设置为 $start_date。
2. 循环：
   1. 将 $end_of_month 设置为 $current_date 月份的最后一天。
   2. 如果 $end_date 小于或等于 $end_of_month，
      1. 将散列的元素 $current_date 设置为 $end_date。
      2. 退出循环。
   3. 将散列的元素 $current_date 设置为 $end_of_month。
   4. 将 $current_date 设置为 $end_of_month。
   5. 在 $current_date 上加一天。

当我需要处理日期和时间时，我使用DateTime 对象（通常由DateTime::Format::Strptime 构造），但 Date::Calc 也应该能够胜任这项任务。我对 Date::Manip 一无所知。

Answer 2

使用Time::Piece：

use strict;
use warnings;

use Time::Piece;
use Time::Seconds;

my $start = '2014-08-18';
my $end   = '2014-10-17';
my $fmt   = '%Y-%m-%d';

# Normalized to Noon to avoid DST
my $month_start = Time::Piece->strptime( $start, $fmt ) + 12 * ONE_HOUR;
my $period_end  = Time::Piece->strptime( $end,   $fmt );

while (1) {
    print $month_start->strftime($fmt), ' - ';

    my $month_end = $month_start + ONE_DAY * ( $month_start->month_last_day - $month_start->mday );

    # End of Cycle if current End of Month is greater than or equal to End Date
    if ( $month_end > $period_end ) {
        print $end, "\n";
        last;
    }

    # Print End of Month and begin cycle for next month
    print $month_end->strftime($fmt), "\n";
    $month_start = $month_end + ONE_DAY;
}

输出：

2014-08-18 - 2014-08-31
2014-09-01 - 2014-09-30
2014-10-01 - 2014-10-17