带有标题的 Gnuplot 5.2 错误行忽略行设置（Windows 终端）

Question

我正在尝试在单个 Gnuplot 5.2 图上绘制多个 xyerrorlines。我发现 xyerrorlines 继承了具有指定标题的任何行的错误栏线属性（线宽、破折号）。

我有语法问题吗？

附加的 MWE 画了两条简单的线 - 一条带有指定的标题，一条没有。你可以看到没有标题的根据它自己的线宽和破折号显示，而有标题的似乎继承了“设置错误栏”行（第2行）的线宽和破折号。

set terminal windows color enhanced "Ariel" 8 close
set errorbars 5 linewidth 2 dashtype 1
set xrange[0:5]
set yrange[0:20]
set xlabel "X Values"
set ylabel "Y Values"

plot '-' with xyerrorlines linecolor rgbcolor "#B2B2B2" pointtype 2 pointsize 4 linewidth 4 dashtype 3 title 'Method 1',\
'-' with xyerrorlines linecolor rgbcolor "#000000" pointtype 2 pointsize 2 linewidth 4 dashtype 4 notitle
1   1   0.1 0.5
2   4   0.1 0.5
3   9   0.1 0.5
4   16  0.1 0.5
e
1   2   0.1 0.5
2   6   0.1 0.5
3   11  0.1 0.5
4   18  0.1 0.5
e

结果如下图：

删除线：

set errorbars 5 linewidth 2 dashtype 1

为带有标题的每一行启用独立的线宽和虚线类型设置，但错误栏继承了我不想要的这些属性。我想为错误栏和线条设置单独的线条和破折号样式（如手册第 128 页中所暗示的那样。）

这种行为在 postscript 终端中也有重复。我没有测试任何其他终端。

我正在使用 Gnuplot 版本 5.2 补丁级别 7。

谢谢你， -瑞安

Answer 1

错误似乎是由非空白标题和绘图样式 xyerrorlines 的组合触发的。我不认为错误栏属性的设置本身会影响这一点。我将调查该错误的根本原因，但同时这里有一个解决方法：

$D1 << EOD
1   1   0.1 0.5
2   4   0.1 0.5
3   9   0.1 0.5
4   16  0.1 0.5
EOD
$D2 << EOD
1   2   0.1 0.5
2   6   0.1 0.5
3   11  0.1 0.5
4   18  0.1 0.5
EOD

set errorbars 5 linewidth 2 dashtype 1
plot $D1 with xyerrorlines lc rgbcolor "#B2B2B2" pt 2 ps 4 lw 4 dt 3 notitle,\
     $D2 with xyerrorlines lc rgbcolor "#000000" pt 2 ps 2 lw 4 dt 4 notitle, \
keyentry with xyerrorlines lc rgbcolor "#B2B2B2" pt 2 ps 4 lw 4 dt 3 title "Method 1",\
keyentry with xyerrorlines lc rgbcolor "#000000" pt 2 ps 2 lw 4 dt 4 title "Method 2"

诀窍是首先绘制没有标题的所需数据以避免错误，然后使用标题但没有数据创建相应的关键条目。 “keyentry”绘图组件相对较新，但它存在于 5.2.7 版中。