组合框依赖于复选框

Question

我已经能够根据是否使用以下代码选择了选项框来更改组合框的列表（或RowSource）：

Private Sub optYes_Click()
    Options
End Sub

Private Sub optNo_Click()
    Options
End Sub

Private Sub Options()
    Select Case True
        Case optYes.Value = True
            cmb.Enabled = True
            cmb.RowSource = "=Options!A1:A4"
        Case optNo.Value = True
            cmb.Enabled = False
    End Select
End Sub

我想稍微修改一下，以便组合框列表仅限于一组已选中的复选框。因此，如果我有 10 个表示不同选项的复选框，而用户只选择其中 4 个，那么只有这 4 个会出现在 Combobox 中。

Answer 1

我会这样做：

Private Sub Algeria_Change()
    Options
End Sub

Private Sub Bangladesh_Change()
    Options
End Sub

Private Sub Canada_Change()
    Options
End Sub

Private Sub Denmark_Change()
    Options
End Sub

Private Sub Options()
    Dim names As Variant, name As Variant
    Dim old As String

    names = Array("Algeria", "Bangladesh", "Canada", "Denmark")

    old = cmb

    cmb.Clear
    cmb.Enabled = False
    For Each name In names
        If Me.Controls(name) Then
            cmb.AddItem Me.Controls(name).Caption
            cmb.Enabled = True
            If name = old Then cmb.SelText = old
        End If
    Next name
End Sub

如果您需要更多复选框，只需将它们的名称添加到 names 并在它们更改时调用 Options。