VBA遍历复选框并从excel表中获取其名称

Question

正如您在上面看到的，我在 Excel 工作表中有一个表格，其中指示 A 可以包含产品 1、产品 2 等等（产品名称因指示而异，这只是为了简单起见！）。

在我的用户表单中显示了类似的格式。我想基本上将我的 excel 表上的指示名称与我的用户表单中的指示名称相匹配。如果它们匹配，则产品 11 获得 A 的产品 1 名称，产品 12 获得 A 的产品 2 名称，依此类推。

我尝试了以下方法，但我才刚刚开始使用 VBA，所以我确信它甚至可能没有意义。

Dim code_ind As String
Dim sel_ind As String
Dim chkbx As Control
Dim labx As Control
Dim i As Integer
Dim col_value As Integer
Dim row_value As Integer

For i = 1 To 8
For j = 1 To 4
For row_value = 4 To 11
col_value = 0

Set chkbx = Me.Controls("seg_l_selInd_" & i)
Set labx = Me.Controls("seg_cb_selInd_" & i & j)

sel_ind = tWb.Worksheets("LALALA").Columns(2).Find(what:=chkbx)

If code_ind = sel_ind Then
    labx.Name = tWb.Worksheets("LALALA").Cells(row_value, 3 + col_value)
    col_value = col_value + 1
End If
Next row_value
Next j
Next i

有什么办法可以做到吗？我知道我可以手动编写名称，但我需要我的工具尽可能灵活。理想情况下，如果将更多信息添加到 excel 表中，用户表单将自动更新。

Answer 1

请检查下一条路。我尝试以这种方式思考您的项目：

1. 下一个示例中的表单必须命名为frmChkBox。表单上的复选框将具有“CheckBox11”、“CheckBox12”等名称，“CheckBox”字符串后的第一个数字为行，下一个为列。如果您意识到您的实际情况将超过行号的一位数字，它们可以用“_”或其他东西分隔。您还可以在 flay 上创建复选框。

一个。请在表单代码模块中粘贴下一行代码：

Option Explicit

Private ChkBColl As New Collection
Private ChkB() As New ChkBoxChClss

Private Sub UserForm_Initialize()
   Dim ws As Worksheet, rng As Range, iRow As Long, iCol As Long
   Dim ctrl As MSForms.Control, ext As String, arrUsed, k As Long
   
   ReDim ChkB(32)
   ReDim arrUsed(Me.Controls.count)
   Set ws = Sheets("INDICATION-PRODUCT")
   Set rng = ws.Range("B2:E9")
   For iRow = 1 To 8
        For iCol = 1 To 4
            For Each ctrl In Me.Controls
                If TypeOf ctrl Is MSForms.CheckBox Then
                    If IsError(Application.Match(ctrl.Caption, arrUsed, 0)) Then
                        ext = Right(ctrl.Caption, Len(ctrl.Caption) - 8)
                        If left(ext, 1) = iRow And Right(ext, 1) = iCol Then
                            ctrl.Tag = rng.cells(iRow, iCol).Address
                            ctrl.Caption = rng.cells(iRow, iCol).Value
                            arrUsed(k) = ctrl.Caption: k = k + 1
                            ChkBColl.Add ctrl, ctrl.Name
                            Set ChkB(k).chkBEvent = ctrl
                        End If
                    End If
                End If
            Next
        Next iCol
   Next iRow
End Sub

Public Sub DoSomething(chk As MSForms.CheckBox)
   Dim ws As Worksheet
   
   Set ws = Sheets("INDICATION-PRODUCT"): ws.Activate
   If chk.Value = True Then
        ws.Range(chk.Tag).Select 'do whatever needed with the cell...
   Else
        ws.Range("A1").Select
   End If
End Sub

每个复选框Tag 都会收到相关联的单元格地址。

为了自动为它们分配相同的事件，将创建一个简单的类包装器（名为“ChkBoxChClss”）。它将识别单击的复选框并将对象发送到表单子，根据需要在其中进行处理。请在类中粘贴下一个代码：

Option Explicit

Public WithEvents chkBEvent As MSForms.CheckBox

Private Sub chkBEvent_Change()
    frmChkBox.DoSomething chkBEvent
End Sub

您可以使用Public Sub DoSomething 来处理被单击的复选框。现在，点击一个复选框，如果它的值为True，对应的单元格将被选中。如果False，将选择“A1”单元格。你可以为所欲为。

Answer 2

我终于解决了！

我的工作表上的表格（图 1）具有与我的用户表单上的指示值相对应的指示列。每种适应症都有几种产品。

我希望我的工具尽可能灵活，因此我需要匹配指示名称，并且对于我的用户表单中的每个复选框，我将从表中获取它的名称。

例如：指示 A，Prod 1 = Prod 1 (Checkbox.Name = Cell(x,y))

这是我正在使用的代码：

Dim code_ind As String
Dim sel_ind As String
Dim chkbx As Control
Dim labx As Control
Dim i As Integer
Dim j As Integer
Dim col_value As Integer
Dim row_value As Integer

For i = 1 To 8

Set chkbx = Me.Controls("seg_l_selInd_" & i)
sel_ind = tWb.Worksheets("INDICATION-PRODUCT").Columns(2).Find(what:=chkbx)

If chkbx = sel_ind Then
    col_value = 0
    While tWb.Worksheets("INDICATION-PRODUCT").Cells(i + 3, 3 + col_value) <> ""
    For j = 1 To 4
        
    Set labx = Me.Controls("seg_cb_selInd_" & i & j)
    labx.Caption = tWb.Worksheets("INDICATION-PRODUCT").Cells(i + 3, 3 + col_value)
    col_value = col_value + 1
    Next j
    Wend
End If
Next i

这对你有意义吗？ 有什么办法可以让我的代码更灵活？例如，我假设有 8 个适应症（i = 1 到 8），但实际上未来可能会有更多。