如何从 Clojure 中的地图数组创建嵌套地图？

Question

所以，作为数据库调用的结果，我得到了一个地图向量，假设它看起来像这样：

[{:make "vw",  :model "vanagon", :color "blue",   :year 1983}
 {:make "vw",  :model "vanagon", :color "red",    :year 1987}
 {:make "vw",  :model "eurovan", :color "blue",   :year 1995}
 {:make "vw",  :model "eurovan", :color "green",  :year 1997}
 {:make "geo", :model "metro",   :color "blue",   :year 1985}
 {:make "geo", :model "metro",   :color "yellow", :year 1994}]

如何使用其中两个字段将其放入嵌套地图中，例如像这样：

{"vw"  {"vanagon" [{:color "blue", :year 1983}, {:color "red", :year 1987}]
        "eurovan" [{:color "blue", :year 1995}, {:color "green", :year 1997}]}
 "geo" {"metro" [{:color "blue", :year 1985}, {:color "yellow", :year 1994}]}}

我已经搞砸了几个小时 group-by 和其他 coll 函数，但我无法完全理解它并想出一个合理的方法来做到这一点。

谢谢！

Answer 1

(reduce (fn [aggr {:keys [make model] :as row}]
          (update-in aggr
                     [make model]
                     (fnil conj [])
                     (dissoc row :make :model)))
        {} data)

匿名函数执行destructuring bind。 update-in 重写绑定结构。基本思想是使用conj 添加行的其他元素。 fnil 用于指定我们想要向量（当找到 nil 时，使用空向量作为 conj 的第一个参数）。结果由reduce 合并到一张地图中。