将新类注入到咖啡脚本继承链中

Question

我有三个咖啡脚本类，设置如下：

class A
class C extends A
class B

所以原型链看起来像这样：

A -> C
B

我需要原型链看起来像这样：

A -> B -> C

问题是我无法触及 A 和 C 的定义。

我想做的是创建一个可以像这样调用的注入函数：

inject B, C

在 A 之前将 B 注入到 C 的原型链中，然后将 B 的原型链设置为注入之前的 C 的原型链。

我认为这很简单，就像

C extends (B extends C.prototype)

但不幸的是，由于咖啡脚本的所有原型/__super__ 魔法，事情并没有那么简单。有谁知道如何注入原型链，基本上就像你说的 class C extends B 和 class B extends A 首先？

非常感谢。

澄清：以下代码不起作用，因为无法复制属性。

class A
  foo: 1
class B
  bar: 2
class C extends A
  baz: 3

B extends A
C extends B

c = new C
console.log c.foo
console.log c.bar
console.log c.baz

Answer 1

[更新：我最初回答说C extends B; B extends A 会起作用。这确实使C instanceof B 和B instanceof A 变为true，但它不会根据需要复制原型属性。所以，我重写了答案。]

让我们来看看这个：

class A
  foo: 1
class B
  bar: 2
class C extends A
  baz: 3

此时，C::foo 为 1，C::baz 为 3。如果我们再运行

C extends B

用B (child.prototype = ...) 的实例覆盖C 的现有原型，因此只定义了C::bar。

当我们使用class X extends Y 语法时不会发生这种情况，因为属性仅在其原型被覆盖后才附加到X 的原型。所以，让我们围绕extends 编写一个包装器来保存现有的原型属性，然后恢复它们：

inherits = (child, parent) ->
  proto = child::
  child extends parent
  child::[x] = proto[x] for own x of proto when x not of child::
  child

将此应用于我们的示例：

inherits B, A
inherits C, B

console.log new C instanceof B, new B instanceof A  # true, true
console.log B::foo, B::bar, B::baz  # 1, 2, undefined
console.log C::foo, C::bar, C::baz  # 1, 2, 3

如果您想了解更多关于 CoffeeScript 类的内部工作原理，您可能想查看由 PragProg 的优秀人员发布的my book on CoffeeScript。 :)