如何将 std::string 转换为 NSString？

Question

您好，我正在尝试将标准 std::string 转换为 NSString，但运气不佳。

我可以使用以下代码从NSString 成功转换为std::string

NSString *realm = @"Hollywood";
std::string REALM = [realm cStringUsingEncoding:[NSString defaultCStringEncoding]];

但是当我尝试以下操作时出现编译时错误

NSString *errorMessage = [NSString stringWithCString:REALM encoding:[NSString defaultCStringEncoding]];

我得到的错误是

Cannot convert 'std::string' to 'const char*' in argument passing

我错过了什么吗？

提前致谢。

Answer 1

从 std::string 中获取 c-string 进行转换：

NSString *errorMessage = [NSString stringWithCString:REALM.c_str() 
                                   encoding:[NSString defaultCStringEncoding]];

Answer 2

首先，你必须使用 Objective-C++ 才能让它工作。确保这一点的最简单方法是将所有 *.m 文件重命名为 *.mm

到目前为止，将 C++ std::string 转换为 NSString 的最有用（非弃用）手动方法是：

std::string param; // <-- input
NSString* result = [NSString stringWithUTF8String:param.c_str()];
NSString* alternative = [[NSString alloc] initWithUTF8String:param.c_str()];

这在大多数情况下都有效 - 如果您不进行特定的编码检测和转换，UTF-8 将为您提供一个很好的结果，让非拉丁字符“正常工作”。

但是，如果您正在制作一个更大的应用程序，或者您不是唯一一个在开发该应用程序的人，那么您可能会想要更容易应用的东西。

改编自cocoa-dev mailing list archives

@interface NSString (cppstring_additions)
+(NSString*) stringWithwstring:(const std::wstring&)string;
+(NSString*) stringWithstring:(const std::string&)string;
-(std::wstring) getwstring;
-(std::string) getstring;
@end

@implementation NSString (cppstring_additions)

#if TARGET_RT_BIG_ENDIAN
const NSStringEncoding kEncoding_wchar_t = CFStringConvertEncodingToNSStringEncoding(kCFStringEncodingUTF32BE);
#else
const NSStringEncoding kEncoding_wchar_t = CFStringConvertEncodingToNSStringEncoding(kCFStringEncodingUTF32LE);
#endif

+(NSString*) stringWithwstring:(const std::wstring&)ws
{
    char* data = (char*)ws.data();
    unsigned size = ws.size() * sizeof(wchar_t);

    NSString* result = [[NSString alloc] initWithBytes:data length:size encoding:kEncoding_wchar_t];
    return result;
}
+(NSString*) stringWithstring:(const std::string&)s
{
    NSString* result = [[NSString alloc] initWithUTF8String:s.c_str()];
    return result;
}

-(std::wstring) getwstring
{
    NSData* asData = [self dataUsingEncoding:kEncoding_wchar_t];
    return std::wstring((wchar_t*)[asData bytes], [asData length] / sizeof(wchar_t));
}
-(std::string) getstring
{
    return [self UTF8String];
}

@end

有了这个就地（并且适当地#imported），您现在可以：

NSString* result = [NSString stringWithstring:param];
string convertedBack = [result getstring];

std::wstring 也一样，非常方便。

Answer 3

NSString* mystring = [NSString stringWithUTF8String:stdstring.c_str()];

Answer 4

Apple 现在有了一种新的方式，他们希望您进行这种转换。在 XCode7 中，我使用 Edit > Convert > To Modern Objective C Syntax... 选项来找出答案。它使用简写@符号。

std::string sCPPString = "Hello World!";
NSString *sAppleString = @(sCPPString.c_str());

Answer 5

我还发现：

NSString *nsString = [NSString stringWithFormat:@"%s",standardString];

像冠军一样工作。

Answer 6

这里是代码sn-p/example：

string str_simple = "HELLO WORLD";

//string to NSString
NSString *stringinObjC = [NSString stringWithCString:str_simple.c_str()
                                encoding:[NSString defaultCStringEncoding]];            
NSLog(stringinObjC);