在 html 类问题中获取股票价格。通过 InternetExplorer.application 创建股票代码

Question

我正在尝试创建自己的股票价格。现在我正在尝试获取指数和信托基金的股票价格，这会使事情变得复杂。我想访问以下网址的股票价格：https://www.avanza.se/fonder/om-fonden.html/313047/norron-active-r

现在的问题是 180,05（在“NAV-kurs”下）的票价，它在 HTML 类“SText 粗体”下（右键单击价格并选择视图组件）。

我可以通过 yahoo Finance 通过 getelementbyid 做个股，但我如何访问 HTML 类的内部文本？我找不到任何与我尝试过的 getelementbyclassname 相关的属性。

代码如下

Private Sub get_ticker()

Dim ie_app As InternetExplorer
Dim ie_doc As htmldocument
Dim ticker As String

Set ie_app = CreateObject("internetexplorer.application")

ie_app.Visible = True
ie_app.navigate ("https://www.avanza.se/fonder/om-fonden.html/313047/norron-active-r")

Do Until ie_app.readyState = READYSTATE_COMPLETE
    DoEvents
Loop

Set ie_doc = ie_app.document

ticker = ie_doc.getelement <<---- gaah 
Debug.Print ticker



End Sub

Answer 1

如果您完全不愿意使用 Javascript，您可以尝试类似的方法。

注意：此代码依赖于早期绑定，并且需要在您的引用中勾选 Microsoft XML (v6.0) 和 Microsoft HTML 对象库。

Sub getPrice()

    Dim xhr As MSXML2.XMLHTTP60
    Dim doc As MSHTML.HTMLDocument
    Dim XSText As MSHTML.IHTMLElementCollection
    Dim elt As MSHTML.HTMLDivElement
    Dim parentElt As MSHTML.HTMLLIElement
    Dim myPrice As Single

    Set xhr = New MSXML2.XMLHTTP60

    With xhr
        .Open "GET", "https://www.avanza.se/fonder/om-fonden.html/313047/norron-active-r", False
        .send

        If .readyState = 4 And .Status = 200 Then
            Set doc = New MSHTML.HTMLDocument
            doc.body.innerHTML = .responseText
        Else
            MsgBox "xhr error"
            Exit Sub
        End If
    End With

    set xhr = Nothing

    Set XSText = doc.getElementsByClassName("XSText")

    For Each elt In XSText
        If InStr(elt.innerHTML, "NAV SEK") <> 0 Then
            Set parentElt = elt.parentElement
            myPrice = CSng(parentElt.getElementsByClassName("SText bold")(0).innerHTML)
        End If
    Next

    MsgBox myPrice

End Sub

Answer 2

Cheat - 该页面包含 jQuery，它更适合用于选择没有 ID 的元素，例如告诉它寻找包含 XSText 的 XSText 类的 div ：div.XSText:contains('NAV SEK') 并阅读下一个元素的文本：

...
Set ie_doc = ie_app.Document

''Create a new element in the document we can read from:
Dim tempInput As HTMLInputElement
Set tempInput = ie_doc.createElement("input")
tempInput.Type = "hidden"
tempInput.ID = "tempInput"

'' add it to the document
ie_doc.appendChild tempInput

'' use jQuery to lookup the value and assign it to the temp input
ie_doc.parentWindow.execScript("$('#tempInput').val($( ""div.XSText:contains('NAV SEK')"" ).next().text())")

'' read the value
msgbox tempInput.Value