为什么 ASTERISK 在谷歌表格中不起作用？答案

【问题标题】：Why doesn't ASTERISK work in google sheets?为什么 ASTERISK 在谷歌表格中不起作用？
【发布时间】：2021-01-24 00:15:14
【问题描述】：

自从我开始使用这台计算机以来，我就遇到了这个问题，并且我一直能够解决它直到没有，但是不能为我的公式使用如此简单和常用的函数真的很烦人。

没有人知道为什么星号在函数中使用时不起作用？在过滤器中，我使用它来排除具有空单元格的行 (B)。

=filter({$A$2:$C},$A$2:$A=F9,$B$2:$B="*"))

我用谷歌搜索了所有内容，但似乎找不到与我有同样问题的人。图为不排除第二行空白单元格的公式。

=filter({$A$2:$C},$A$2:$A=F9))

或者有没有其他方法可以在不使用 Asterisk 的情况下实现这一点？感谢您的帮助...

【问题讨论】：

这能回答你的问题吗？ Google Spreadsheet, filter doesn't allow wildcards? How to countif multiple columns with wildcards?
这是完整的代码。它有重复，所以我需要找到唯一值 ''' =ifna(rows(unique(filter( {$A$2:$C},$A$2:$A=F3))),0) ''' Right现在它正在过滤，然后找到唯一的，然后计算行数。
这个公式适用于哪个单元格？ A、C、F 列中的内容。请提供有用的信息。分享一张测试表或一张显示有列和行的可用图片。
您能分享一个经过消毒的电子表格示例吗？
这是示例电子表格。我需要它只计算带有条形码和位置的单元格。（不包括“超出范围”）docs.google.com/spreadsheets/d/…

标签： google-sheets google-sheets-formula

【解决方案1】：

您可以只使用<> "" 过滤掉空单元格：

=ifna(rows(unique(filter( {$A$2:$C},$A$2:$A=F2,$B$2:$B<>""))),0)

或者将其放在标题单元格 (H1) 中并删除下面的所有内容。该列将填充您需要的数据。

={
  "Barcode+Location";
  ARRAYFORMULA(
    IF(
      F2:F = "",
        "",
        IFNA(
          VLOOKUP(
            F2:F,
            QUERY(
              UNIQUE(FILTER(A2:C, A2:A <> "", B2:B <> "")),
              "SELECT Col1, COUNT(Col1)
               GROUP BY Col1
               LABEL Col1 '',
                     COUNT(Col1) ''",
              0
            ),
            2,
            0
          ),
          0
        )
    )
  )
}

见表kishkin。

【讨论】：