访问表单上的过滤器属性不起作用

Question

在过去的几天里，我一直在尝试对 Access-2010 表单应用过滤器。表单的记录源是一个表格。过滤器是由表单上的一系列按钮创建的。以下是构建过滤器的按钮

列表按钮的事件过程：

Private Sub btnListInterfaceLog_Click()
    Dim List As String
    List = StartList()
End Sub

StartList() 函数代码

Private Function StartList()

   Dim strWhereClause As String
   strWhereClause = MakeWhere()  
   MsgBox strWhereClause

   Me.FilterOn = True
   Me.Filter = strWhereClause
   Me.Requery

End function

MakeWhere() 的代码

Private Function MakeWhere() As String

   Dim whereClause As String
   whereClause = ""

   If Me![cboinstrument].Enabled = True And Me![cboinstrument] <> "" Then
       whereClause = RvAppendCondition(whereClause, "InstrumentName", "String", "=", Me![cboinstrument])
   End If

   If Me![cboFolder].Enabled = True And Me![cboFolder] <> "" Then
    whereClause = RvAppendCondition(whereClause, "folder", "String", "=", Me![cboFolder])
   End If

   If Me![BatchFrom].Enabled = True And Me![BatchFrom] > 0 And Me![BatchTo].Enabled = True And Me![BatchTo] > 0 Then
    whereClause = RvAppendCondition(whereClause, "BatchID", "Number", "=", Me![BatchFrom], Me![BatchTo])
   End If

   If Me![AnalyzedFrom].Enabled = True And Me![AnalyzedFrom] > 0 And Me![AnalyzedTo].Enabled = True And Me![AnalyzedTo] > 0 Then
    whereClause = RvAppendCondition(whereClause, "Dateofbatch", "Date", "=", Me![AnalyzedFrom], Me![AnalyzedTo])
   End If

   MakeWhere = whereClause

 End Function

RvAppendCondition 函数接受一个给定的字符串并向 where 语句添加一个新参数。它已经过多次测试并且有效，因此您不必过多关注它。如果被问到，我可以包含代码以供参考。

例如：如果我所做的只是选择仪器名称（来自：组合框）并将其余部分留空然后按列表，strWhereClause 将 msgbox“[InstrumentName] = 'ICPMS'”，当我转到主窗体的属性，过滤器下没有列出任何内容。当我按下列表时，如何使一个值出现在过滤器属性中。 （旁注：所有函数都有错误语句，我把它们取出来使它们更短）

Answer 1

这是您的代码应该是什么。

Private Sub btnListInterfaceLog_Click()
   Dim strWhereClause As String
   strWhereClause = MakeWhere()  
   MsgBox strWhereClause

   Me.Filter = strWhereClause
   Me.FilterOn = True
End Sub

Private Function MakeWhere() As String

   Dim whereClause As String

   If Me![cboinstrument].Enabled = True And Me![cboinstrument] <> "" Then
        whereClause = whereClause & "(InstrumentName = '" & Me![cboinstrument] & "') AND "
   End If

   If Me![cboFolder].Enabled = True And Me![cboFolder] <> "" Then
        whereClause = whereClause & "(folder = '" & Me![cboFolder] & "') AND "
   End If

   If Me![BatchFrom].Enabled = True And Me![BatchFrom] > 0 And Me![BatchTo].Enabled = True And Me![BatchTo] > 0 Then
        whereClause = whereClause & "(BatchID BETWEEN " & Me![BatchFrom] & " AND " & Me![BatchTo] & ") AND "
   End If

   If Me![AnalyzedFrom].Enabled = True And Me![AnalyzedFrom] > 0 And Me![AnalyzedTo].Enabled = True And Me![AnalyzedTo] > 0 Then
        whereClause = whereClause & "(Dateofbatch BETWEEN " & Format(Me![AnalyzedFrom], "\#mm\/dd\/yyyy\#") & _
                                    " AND " & Format(Me![AnalyzedTo], "\#mm\/dd\/yyyy\#") & ") AND "
   End If

   MakeWhere = Left(whereClause, Len(whereClause) - 5)

 End Function