如何获取 Elm 的当前时间？

Question

我正在运行 elm-repl 来玩弄该语言。

我想看看现在是几点。我该怎么做？当前的库似乎不可能。这是为什么呢？

---

编辑：我做了一个包来帮助解决这个问题。 http://package.elm-lang.org/packages/z5h/time-app

这是围绕 elm 0.15 提出的问题 - elm 0.17 和 0.18 中的情况有所不同：请参阅 How do I get the current time in Elm 0.17/0.18?

Answer 1

0.19 更新 使用标准库无法获取当前时间。您需要使用elm/time。与 0.18 一样，您只需要一个命令和 Msg 来处理结果

type Msg
    = OnTime Time.Posix 

getTime : Cmd Msg
getTime = 
    Task.perform OnTime Time.now 

0.18 更新 这又变得更简单了。现在你只需要一个命令和消息来处理结果

type Msg
    = OnTime Time 

getTime : Cmd Msg
getTime = 
    Task.perform OnTime Time.now 

看到这个Ellie

原答案

使用 0.17，这变得容易多了。现在Time library 中有一个任务。例如，我们现在有：

Time.now
|> Task.Perform NoOp CurrentTime

Answer 2

您可以使用the Time package 和/或the Date package。

这是一个使用两者的人为示例：

import Signal
import Time exposing (every, second)
import Date exposing (year, hour, minute, second, fromTime)
import Graphics.Element exposing (show)

main =
  Signal.map currentTime (Time.every Time.second)

currentTime t =
  let date' = fromTime t
      hour' = toString (Date.hour date')
      minute' = toString (Date.minute date')
      second' = toString (Date.second date')
      year' = toString (year date')
      now = "The current time is: " ++ hour' ++ ":" ++ minute' ++ ":" ++ second'
  in 
      show now

Answer 3

为了解决我自己的问题，我创建了一个 StartApp 变体，其中包含每个操作的时间戳。
所以更新函数有签名：
update : action -> Time -> model -> (model, Effects action)

要点就在这里。 https://gist.github.com/z5h/41ca436679591b6c3e51

Answer 4

榆树 0.19

• https://elm-lang.org/examples/time
• https://elm-lang.org/examples/clock
• 时间https://ellie-app.com/3f6X2DW4cbma1
• 模拟svg时钟https://ellie-app.com/3dYXjr3bJNWa1

下面我将初始时间设置为 unix 时间开始 Time.millisToPosix 0，但您可以将其设置为 Nothing 并稍后设置为 Just time 或使用 Flag 传递。

module Main exposing (main)

import Browser
import Html exposing (Html)
import Task
import Time exposing (Posix)


main : Program () Model Msg
main =
    Browser.element
        { init = \_ -> init
        , view = view
        , update = update
        , subscriptions = \_ -> Sub.none
        }



-- MODEL


type alias Model =
    { zone : Time.Zone
    , now : Posix
    }


init : ( Model, Cmd Msg )
init =
    ( Model Time.utc (Time.millisToPosix 0), Task.perform Zone Time.here )



-- UPDATE


type Msg
    = Zone Time.Zone
    | Now Posix


update : Msg -> Model -> ( Model, Cmd Msg )
update msg model =
    case msg of
        Zone zone ->
            ( { model | zone = zone }, Task.perform Now Time.now )

        Now now ->
            ( { model | now = now }, Cmd.none )



-- VIEW


formatTime zone posix =
    (String.padLeft 2 '0' <| String.fromInt <| Time.toHour zone posix)
        ++ ":"
        ++ (String.padLeft 2 '0' <| String.fromInt <| Time.toMinute zone posix)
        ++ ":"
        ++ (String.padLeft 2 '0' <| String.fromInt <| Time.toSecond zone posix)


view : Model -> Html Msg
view model =
    Html.div []
        [ Html.text <| formatTime model.zone model.now
        ]

Answer 5

如果您想要程序开始的时间，您可以执行以下操作：

Now.elm

module Now where

import Native.Now

loadTime : Float
loadTime = Native.Now.loadTime

Native/Now.js

Elm.Native.Now = {};

Elm.Native.Now.make = function(localRuntime) {

  localRuntime.Native = localRuntime.Native || {};


  localRuntime.Native.Now = localRuntime.Native.Now || {};

  if (localRuntime.Native.Now.values) {
    return localRuntime.Native.Now.values;
  }

  var Result = Elm.Result.make(localRuntime);

  return localRuntime.Native.Now.values = {
    loadTime: (new window.Date).getTime()
  };

};

你的代码

programStart = Now.loadTime

Answer 6

您可以查看pdoherty926's answer，了解如何使用 Elm 中的当前时间进行操作。

elm-repl 无法与Signals 一起工作，并且时间“随时间而变化”，因此它是一个信号。 据我所知，也没有Task 来获取时间。也不是在 repl 中执行任务的方法，尽管我希望这将成为未来的功能。

Answer 7

我可以想到两种主要方法来处理 Elm 中的当前时间：

1. 编写/使用本机模块创建一个以毫秒为单位返回当前时间的函数（或返回将执行相同操作的任务）。一般不推荐这种方法。我认为＃2是一种更好的方法。但是可以在这里找到 #1 的示例：https://github.com/evancz/task-tutorial/blob/1.0.2/src/TaskTutorial.elm（请参阅getCurrentTime 函数）

2. 使用 Elm 应用程序架构 (https://github.com/evancz/elm-architecture-tutorial/) 编写程序，然后将当前时间信号作为输入提供给更新周期，在您选择的每个间隔使用新的当前时间更新模型。然后你所有的其他方法都可以同步地从模型中获取当前时间。

Answer 8

Simon H 的答案（针对 0.18）让我开始朝着正确的方向前进，但我确实在弄清楚如何在那个时候真正做某事时遇到了一些麻烦。 （user2167582 在 Simon 的回答中添加了一条评论，提出了同样的问题：你如何“抽出时间？”）。

我的具体问题是我想在服务器的 POST 正文中包含当前时间。

我最终解决了这个问题，并对最终结果感到非常满意——使用Task.andThen 意味着我在我的postTime 函数中可以只使用timestamp 作为“常规”浮点值参数（我想这是任务运行的时候）。

我的完整答案是here。

以下是我想出的解决方案和here it is in Ellie：

module Main exposing (..)

import Html exposing (..)
import Html.Events exposing (..)
import Http
import Json.Decode as JD
import Json.Encode as JE
import Task
import Time


type alias Model =
    { url : String
    }


type Msg
    = PostTimeToServer
    | PostDone (Result Http.Error String)


update : Msg -> Model -> ( Model, Cmd Msg )
update msg model =
    case msg of
        PostTimeToServer ->
            ( model, postTimeToServer model.url )

        PostDone _ ->
            ( model, Cmd.none )


view : Model -> Html Msg
view model =
    div []
        [ div []
            [ button [ onClick PostTimeToServer ] [ Html.text "POST the current time." ]
            ]
        ]


postTimeToServer : String -> Cmd Msg
postTimeToServer url =
    let
        getTime =
            Time.now

        postTime t =
            JD.string
                |> Http.post url (JE.float t |> Http.jsonBody)
                |> Http.toTask

        request =
            getTime                                            <<-- Here is
                |> Task.andThen postTime                       <<-- the key bit.
    in
        Task.attempt PostDone request


main =
    Html.program
        { init = ( Model "url_here", Cmd.none )
        , update = update
        , view = view
        , subscriptions = always Sub.none
        }