是否有系统的方法来检查`strict refs`？

Question

过去几年，我们在旧版 Perl 代码库中采用了use strict。我的任务是把它添加到其余的模块中，同时确保它当然不会破坏任何东西。

现在对于use strict 'vars' 和use strict 'subs' 这很容易，因为这些是简单的perl -c 捕获的编译时错误。但是是否有系统的方法来检查use strict 'refs' 触发的运行时错误？

当然，我可以通过在所有可能的情况下（即完全覆盖）调用所有函数来引发运行时错误，但这很麻烦，尤其是。因为这段代码缺少单元测试。如果您有更好的想法，我将不胜感激。

Answer 1

因为 Perl 是无类型的（变量可能包含引用或非引用），所以只能在运行时检查。考虑：

use strict;

# Usage: foo(HASHREF)
sub foo {
   print $_[0]{name}, "\n" if int(rand(2));
}

my $var = int(rand(2))
   ? { name => "Hello" }
   : "World";  # oopsie!

foo($var);

大约 25% 的时间会失败。无类型语言的静态分析无法捕捉到这种东西——它只能被你的测试套件捕捉到，所以你的首要任务应该是改进它。

也就是说，有一些改进代码的方法可以帮助您。例如，如果我们对传入的参数进行类型检查，我们可以证明 foo 子本身是正确编写的：

sub foo {
   my $href = $_[0];
   ref($href) eq 'HASH' or die("Expected hashref!");
   print $href->{name}, "\n" if int(rand(2));
}

这将确保foo 行为正确性的负担从foo 转移到foo 的调用者身上。在foo 中，您现在有一小段代码，您可以在其中确信每个变量的数据类型。逐步添加这样的断言可以让您不断扩大“信心区域”。

请注意，上面的小改动意味着我们的代码现在将有 50% 的时间失败，而不是 25% 的时间。因为foo 现在失败更频繁，这将帮助我们捕捉到错误的真正源：

my $var = int(rand(2))
   ? { name => "Hello" }
   : "World";  # oopsie!

foo($var);

---

部分是因为我写的，部分是因为它是damn fast，我建议你看看Type::Params 来检查子参数。这是一个如何使用它的示例：

use feature qw(state);
use Types::Standard qw( HashRef );
use Type::Params qw( compile );

sub foo {
   state $signature = compile( HashRef );
   my ($href) = $signature->(@_);
   print $href->{name}, "\n" if int(rand(2));
}

将其扩展为接受多个参数的子...

use feature qw(state);
use Types::Standard qw( -types );
use Type::Params qw( compile );

sub query_get_rows {
   state $signature = compile( InstanceOf['DBI::db'], Str, Optional[Int] );
   my ($dbh, $query, $limit) = $signature->(@_);

   # do stuff here
}