无法从规范文件中的 GebConfig.groovy 文件中读取系统变量集

Question

我正在使用 geb spock。我正在尝试从 GebConfig 文件中读取系统变量，但是它返回 null 值。

下面是我的 GebConfig.groovy 文件。

def final DEFAULT_BROWSER = "chrome"   
def final DEFAULT_LANGUAGE = "nl"                  //"en" or "nl"

def browser = System.getProperty("geb.env")
//Default browser
if (!correctBrowser(browser)) {
    browser = DEFAULT_BROWSER
}

def envLang = System.getProperty("geb.env.lang")
//Default language
if (!correctLanguage(envLang)) {
    envLang = DEFAULT_LANGUAGE
}

System.setProperty("geb.env.lang", envLang)

System.setProperty("geb.env", browser)

environments {
    driver = { getDriver(browser, envLang) }
}

下面是我试图在变量中获取语言值的规范文件。

@Stepwise
class TC001_SMO_Scenario_Spec extends GebReportingSpec {


    @Shared
    def lang = System.getProperty("geb.env.lang")


    def "Step 1: Perform Login"() {

        when: "Load File"
        to WUPage

        then: " File loaded successfully"
        println " Getting data from Geb Config File: " + lang

    }

}

你能帮我怎么做吗，因为这对我访问并将其存储在变量中非常重要。谢谢

Answer 1

问题在于您的 @Shared 变量。 Geb manual 说：

(...) 声明一个@Shared 字段。同样，最好在声明时初始化该字段。 （语义上，这相当于在setupSpec() 方法的最开始初始化字段。）

问题是，setupSpec() 运行 之前 GebConfig 被评估。如果您将其添加到 GebConfig 的末尾，您可以看到它：

println "Finished evaluating GebConfig"

然后运行这个 Geb 规范（我已经将变量赋值包装到闭包中并添加了打印语句，然后我正在评估闭包以使赋值起作用）：

package de.scrum_master.stackoverflow

import geb.spock.GebReportingSpec
import spock.lang.Shared

class GebConfigIT extends GebReportingSpec {
  @Shared
  def sharedLang = {
    println "Initialising sharedLang"
    System.getProperty("geb.env.lang")
  }()

  def normalLang = {
    println "Initialising normalLang"
    System.getProperty("geb.env.lang")
  }()

  def setup() {
    println "sharedLang = $sharedLang"
    println "normalLang = $normalLang"
  }

  def foo() {
    expect:
    !sharedLang
    normalLang
  }

  def bar() {
    expect:
    !sharedLang
    normalLang
  }
}

Initialising sharedLang

Finished evaluating GebConfig
Initialising normalLang
sharedLang = null
normalLang = nl

Initialising normalLang
Finished evaluating GebConfig
sharedLang = null
normalLang = nl

你能看到sharedLang 是如何在一开始只初始化一次，甚至在GebConfig 有机会启动之前吗？

底线：只需从您的代码中删除 @Shared。无论如何，大多数人都过度使用它，他们认为这样可以节省时间来获取廉价资源并篡改干净的夹具设置。 @Shared 真的只适用于非常昂贵的资源和非常特殊的情况。