在 spock 测试中抛出 MissingPropertyException where block

Question

我一直在使用 spock 对我的 java 项目进行单元测试，但遇到了问题。我有一个实用方法可以从 http 请求中获取参数，或者如果 http 请求为空，则为空字符串，并且我正在尝试使用 spock 对其进行测试。我的测试如下所示：

package foo.bar.test

import foo.bah.HttpRequestPropertyLoader
import spock.lang.Unroll
import javax.servlet.http.HttpServletRequest
import spock.lang.Specification

class HttpRequestPropertyLoaderTest extends Specification {

    HttpRequestPropertyLoader subjectUnderTest
    def result

    def setup() {
        subjectUnderTest = new HttpRequestPropertyLoader()
    }

    @Unroll("When my http request is #nullOrNot then when I get parameter from it the response=#response" )
    def "Test load data from request"() {
        given:
        HttpServletRequest mockHttpRequest = Mock()
        mockHttpRequest.getAttribute("foo") >> "bar"
        when:
        result = subjectUnderTest.loadStringFromHttpRequest(httpRequest, "foo")
        then:
        result == response
        where:
        httpRequest     | response | nullOrNot
        null            |  ""      | "null"
        mockHttpRequest | "bar"    | "not null"
    }
}

但是，当我运行此测试时，我收到以下错误：

groovy.lang.MissingPropertyException: No such property: mockHttpRequest for class: foo.bar.test.HttpRequestPropertyLoaderTest at foo.bar.test.HttpRequestPropertyLoaderTest.Test load data from request(HttpRequestPropertyLoaderTest.groovy)

经过研究，我了解到where 块在given 块之前运行，因此出现错误，但只是想知道是否有解决方法？

我知道要使用测试外部的变量，我需要使用 @Shared 注释来注释变量，这对我来说似乎是不好的做法。每个测试都应该与其他测试完全分开运行，所以不要真的希望有一个对象在测试之间保持其状态。

是否可以设置 Mock 对象以其他方式从 where 块返回？

Answer 1

按照 tim_yates 的建议查看 https://code.google.com/p/spock/issues/detail?id=15#c4，我发现了一个相当优雅的解决方案，它不涉及使用 @Shared 注释。测试定义现在如下所示：

package foo.bar.test

import foo.bah.HttpRequestPropertyLoader
import spock.lang.Unroll
import javax.servlet.http.HttpServletRequest
import spock.lang.Specification

class HttpRequestPropertyLoaderTest extends Specification {

    HttpRequestPropertyLoader subjectUnderTest
    def result

    def setup() {
        subjectUnderTest = new HttpRequestPropertyLoader()
    }

    @Unroll("When my http request is #nullOrNot then when I get parameter from it the response=#response" )
    def "Test load data from request"() {
        when:
        result = subjectUnderTest.loadStringFromHttpRequest(httpRequest, "foo")
        then:
        result == response
        where:
        httpRequest << {
            HttpServletRequest mockHttpRequest = Mock()
            mockHttpRequest.getAttribute("foo") >> "bar"
            [null, mockHttpRequest]
        }()
        response << ["", "bar"]
        nullOrNot << ["null", "not null"]
    }
}