将字典放入类

Question

几周前，我得到了一个关于如何在这个位置制作通用类模块的精彩答案：Class "let" stuck in infinite loop

老实说，我仍然不太了解，因为我 100% 的 vba 知识都是自学的，并且从这里开始，几年前的一个学期 C 中剩下的一些通用编程逻辑。但我认为我对此有很好的把握，因为这是一个很好的解释。我现在正在尝试将其应用于我的课程中的字典并遇到一些麻烦。

我的班级模块如下：

Option Explicit

Private Type categories
    Temp As scripting.Dictionary
    Humid As scripting.Dictionary
    Wind As scripting.Dictionary
End Type

Private this As categories

Public Sub Initialize()
    Set this.Temp = New scripting.Dictionary
    Set this.Humid = New scripting.Dictionary
    Set this.Wind = New scripting.Dictionary
End Sub

Public Property Get Temp(ByVal HourIndex As Long) As Double
    Temp = this.Temp(HourIndex)
End Property

Public Property Let Temp(ByVal HourIndex As Long, ByVal Value As Double)
    this.Temp(HourIndex) = Value
End Property

Public Property Get Humid(ByVal HourIndex As Long) As Double
    Humid = this.Humid(HourIndex)
End Property

Public Property Let Humid(ByVal HourIndex As Long, ByVal Value As Double)
    this.Humid(HourIndex) = Value
End Property

Public Property Get Wind(ByVal HourIndex As Long) As Double
    Wind = this.Wind(HourIndex)
End Property

Public Property Let Wind(ByVal HourIndex As Long, ByVal Value As Double)
    this.Wind(HourIndex) = Value
End Property

然后我尝试在即时窗口中使用set tester = new WeatherData（模块名称）和Initialize对此进行测试。那没有用。然后我将 Initialize 修改为：

Public Sub Initialize(ByVal variable As categories)
    Set variable.Temp = New scripting.Dictionary
    Set variable.Humid = New scripting.Dictionary
    Set variable.Wind = New scripting.Dictionary
End Sub

并输入Initialize tester，但这也不起作用（“编译错误：未定义子或函数”）。

那么，结束问题：如何将三个字典放在一个类模块中？

编辑：我是个傻瓜。以下内容本身并没有真正解决问题，但它至少绕过了它，以至于我不必承认它：

Option Explicit

Private Type categories
    Temp(23) As Double
    Humid(23) As Double
    wind(23) As Double
End Type

Private this As categories

Public Property Get Temp(ByVal HourIndex As Long) As Double
    Temp = this.Temp(HourIndex)
End Property

Public Property Let Temp(ByVal HourIndex As Long, ByVal Value As Double)
    this.Temp(HourIndex) = Value
End Property

Public Property Get Humid(ByVal HourIndex As Long) As Double
    Humid = this.Humid(HourIndex)
End Property

Public Property Let Humid(ByVal HourIndex As Long, ByVal Value As Double)
    this.Humid(HourIndex) = Value
End Property

Public Property Get wind(ByVal HourIndex As Long) As Double
    wind = this.WindChill(HourIndex)
End Property

Public Property Let wind(ByVal HourIndex As Long, ByVal Value As Double)
    this.wind(HourIndex) = Value
End Property

tl;dr：制作数组而不是字典，并完全删除初始化。你的“钥匙”别无选择，只能是数字，但至少它有效。如果有人愿意，我真的很想知道一个实际的解决方案，但我遇到的具体问题已经解决了。

Answer 1

在这种情况下，您应该按如下方式使用后期绑定：

Private Type categories
    Temp As Object
    Humid As Object
    Wind As Object
End Type

Private this As categories

Public Sub Initialize()
    Set this.Temp = CreateObject("Scripting.Dictionary")
    Set this.Humid = CreateObject("Scripting.Dictionary")
    Set this.Wind = CreateObject("Scripting.Dictionary")
End Sub

此外，您不能将Let 与多个参数一起使用。你应该使用一个函数来做到这一点：

Public Function SetTemp(ByVal HourIndex As Long, ByVal Value As Double)
    this.Temp(HourIndex) = Value
End Function

为了运行这个，我使用了：

Sub test()
    Dim multi As Dictionaries
    Set multi = New Dictionaries

    multi.Initialize

    multi.SetTemp 13, 25.522
    Debug.Print multi.Temp(13)
End Sub

我的课程模块被命名为Dictionaries。所以基本上使用后期绑定并将所有多参数让函数更改为简单函数。

Answer 2

您似乎想实现一个索引属性。

简化到最低限度：

Option Explicit
Private values As Scripting.Dictionary

Private Sub Class_Initialize()
    Set values = New Scripting.Dictionary
End Sub

Public Property Get Something(ByVal key As String) As Double
    Something = values(key)
End Property

Public Property Let Something(ByVal key As String, ByVal value As Double)
    values(key) = value
End Property

您将字典安全地封装为类的实现细节（例如，外部代码不能将它们设置为Nothing），并为每个封装字典公开一个索引Get+Let 属性，这需要索引（/key）作为参数。

对于您的 WeatherData 类，这意味着您可以像这样填充数据：

Set data = New WeatherData
With data
    .Temp("day 1") = 76
    .Temp("day 2") = 78
    .Humid("day 1") = 0.55
    .Humid("day 2") = 0.61
    .Wind("day 1") = 0.92
    .Wind("day 2") = 1.27
End With

然后用data.Temp("day 1")检索"day 1"的温度。

至于您的初始化方法，它需要从类的 instance 中调用 - 作为 instance 方法。

因此，您应该使用tester.Initialize 而不是Initialize tester。

无论您将内部封装存储设为数组，Collection 还是 Dictionary 对调用代码都没有影响 - 这是一个封装的实现细节：您的类也可以将数据存储在 .csv 文件或如果需要，可以放入数据库中。

Answer 3

我发现 Mathieu Guindon 的示例非常有启发性，但对于初学者来说却非常简约。

感谢 Mathieu Guindon，但让我分享一下他的代码的扩展版本，使用后期绑定只是为了更改一些小细节。

名为 WeatherData 的类代码模块：

'Mathieu Guindon,Feb 6 '17
'https://stackoverflow.com/a/43263480
Option Explicit
Private dTemp As Object
Private dHumid As Object
Private dWind As Object
Private Sub Class_Initialize()
    Set dTemp = CreateObject("Scripting.Dictionary")
    Set dHumid = CreateObject("Scripting.Dictionary")
    Set dWind = CreateObject("Scripting.Dictionary")
End Sub
Public Property Get Temp(ByVal key As String) As Double
    Temp = dTemp(key)
End Property
Public Property Let Temp(ByVal key As String, ByVal value As Double)
    dTemp(key) = value
End Property
Public Property Get TempItemCount() As Long
    TempItemCount = dTemp.Count
End Property
Public Property Get Humid(ByVal key As String) As Double
    Humid = dHumid(key)
End Property
Public Property Let Humid(ByVal key As String, ByVal value As Double)
    dHumid(key) = value
End Property
Public Property Get HumidItemCount() As Long
    HumidItemCount = dHumid.Count
End Property
Public Property Get Wind(ByVal key As String) As Double
    Wind = dWind(key)
End Property
Public Property Let Wind(ByVal key As String, ByVal value As Double)
    dWind(key) = value
End Property
Public Property Get WindItemCount() As Long
    WindItemCount = dWind.Count
End Property

标准代码模块：

Sub test()
Set Data = New WeatherData
With Data
    .Temp("day 1") = 76
    .Temp("day 2") = 78
    .Humid("day 1") = 0.55
    .Humid("day 2") = 0.61
    .Wind("day 1") = 0.92
    .Wind("day 2") = 1.27

    Debug.Print .Temp("day 2")
    Debug.Print .Humid("day 2")
    Debug.Print .Wind("day 2")
    Debug.Print .Wind("day 2")
    Debug.Print .TempItemCount
End With
End Sub