逐行解析数组并将其分解为更多数组

Question

我仍然在学习 Perl，并且知道我还有很长的路要走，我一直在阅读 O'Reilly 的 Perl 书籍，还参加了一些关于 Udemy 的课程，甚至参加了关于 Perl 的 Lynda 课程。

我正在尝试编写一个备份程序来满足我的需求，但我似乎很难使用我的一个功能。

sub list {
    my @zfs_temp = `zfs list`;
    foreach (@zfs_temp) {
    my ($name, $used, $available, $refer, $mount) = split(/\s+/);
    push(@name, $name);
    push(@used, $used);
    push(@available, $available);
    push(@refer, $refer);
    push(@mount, $mount);
#    print "@name, @used, @available, @refer, @mount\n";
    return (@name, @used, @available, @refer, @mount);
    }
}

似乎我只回了一条线，我真的不确定我做错了什么，有人能指出我正确的方向吗？

谢谢

Answer 1

数组可能非常笨拙，从这里看起来有点尴尬。这是一个更惯用的版本，它返回以挂载名称为键的散列的 hashref（并假设它们是唯一的）。我没有要测试的zfs，所以这是未经测试的，但它应该是正确的，Dumper 调用应该清楚发生了什么。

use strict;
use warnings;
use Data::Dumper;
$Data::Dumper::Terse = 1;

print Dumper( list() );

sub list {
    my %info;
    for ( qx { zfs list } )
    {
        my ( $name, $used, $available, $refer, $mount ) = split;
        $info{$name} = {
            used => $used,
            available => $available,
            refer => $refer,
            mount => $mount,
        };
    }
    \%info;
}

如果你仍然要使用数组，这种语法会让返回变得不那么尴尬——

return \( @name, @used, @available, @refer, @mount );

Answer 2

您的问题是您过早返回。

sub list {
    my @zfs_temp = `zfs list`;
    my (@name, @used, @available, @refer, @mount); #declared ahead of time and scoped appropriately 
    foreach (@zfs_temp) {
        my ($name, $used, $available, $refer, $mount) = split(/\s+/);
        push(@name, $name);
        push(@used, $used);
        push(@available, $available);
        push(@refer, $refer);
        push(@mount, $mount);
    }
    return (@name, @used, @available, @refer, @mount); #note how it's outside the loop now

 }

否则你只会在循环一次后返回，可能不是你想要的。

此外，您应该使用my 声明这些数组。否则 Perl 会在 use strict 下抱怨，你应该总是使用它。

欢迎使用 Perl！

编辑：

正如 Joel 所指出的，您可能希望返回对这些数组的引用。这很容易做到，只需使用：

return (\@name, \@used, \@available, \@refer, \@mount);

如果您对此感到困惑，请查看perlref。

Answer 3

您将在一次迭代后返回。将 return 放在循环之外。