如何在 perl 中验证多维散列的值？

Question

我有一个像这样的多维散列

%hash = {'5' => {'DS' => 'TESTD1',
                 'DN' => 'TESTD1',
                 'PP' => 'APPLE44'},
         '6'=> {'DS' => 'TESTD2',
                'DN' => 'TESTD2',
                'PP' => 'APPLE44'},
         '7'=>{'DS' => 'TESTD1',
               'DN' => 'TESTD3',
               'PP' => 'APPLE44'} 
         '8'=>{'DS' => 'TESTD1',
               'DN' => 'TESTD1',
               'PP' => 'ORANGE33' }
          };

现在我想检查整个 hash 的 'PP' 值和 'DS' 值之间是否存在唯一映射。 例如，第 7 个键不是唯一的，因为它与 DS 和 PP 值的第 5 个相同。 只有当 PP 和 DS 值相同时，我才应该增加计数。

到目前为止，我已经尝试使用 'exists'，但似乎并没有按照我想要的方式工作，那么我们该如何实现呢？

Answer 1

您可能在使用 exists 时遇到了问题，因为您错误地定义了您的哈希值。当您应该使用 %hash = ( ... ) 创建散列或使用 $hash = { ... } 创建散列引用时，您执行 %hash = { ... }。阅读perldoc perlreftut 了解所有血腥细节。

使用另一个哈希来存储各种 DS / PP 组合并使用它来检查唯一性。

use warnings;
use strict;

my $hash = {
    '5' => {'DS' => 'TESTD1',
            'DN' => 'TESTD1',
            'PP' => 'APPLE44'},
    '6' => {'DS' => 'TESTD2',
            'DN' => 'TESTD2',
            'PP' => 'APPLE44'},
    '7' => {'DS' => 'TESTD1',
            'DN' => 'TESTD3',
            'PP' => 'APPLE44'}, 
    '8' => {'DS' => 'TESTD1',
            'DN' => 'TESTD1',
            'PP' => 'ORANGE33'},
};

my %check_for_dups;
for my $key ( sort keys %$hash ) {
    my $subhash = $hash->{ $key };
    my $combo = join '_', 'DS', $subhash->{ DS }, 'PP', $subhash->{ PP };
    $check_for_dups{ $combo }->{ $key } = 1;
}

my $found_dups = 0;
for my $combo ( sort keys %check_for_dups ) {
    my @keys_for_combo = sort { $a <=> $b } keys %{ $check_for_dups{ $combo } };
    if ( scalar @keys_for_combo > 1 ) {
        print "Duplicate keys for combo '$combo' : " . join(',',@keys_for_combo) . "\n";
        $found_dups = 1;
    }
}

print "All combos are unique!\n"
    unless $found_dups;

输出

Duplicate keys for combo 'DS_TESTD1_PP_APPLE44' : 5,7

Answer 2

成功了

 my %dup; 
 if(exists($dup{'DS'}{'PP'}))
 {
     count++;
 }

Answer 3

我使用的答案与 xxfelixxx 几乎相同，但在他的代码中，当它找到第一个重复项时，我们无法找到所有重复项，因为脚本存在（实际上死了 :)）。

因此我使用数组的哈希来存储重复的索引，所以你知道重复的索引和它们的计数（数组值的计数）

#!/usr/bin/perl
use strict;
use warnings FATAL => 'all';
my $hash = {'5' => {'DS' => 'TESTD1',
                 'DN' => 'TESTD1',
                 'PP' => 'APPLE44'},
         '6'=> {'DS' => 'TESTD2',
                'DN' => 'TESTD2',
                'PP' => 'APPLE44'},
         '7'=>{'DS' => 'TESTD1',
               'DN' => 'TESTD3',
               'PP' => 'APPLE44'},
         '8'=>{'DS' => 'TESTD1',
               'DN' => 'TESTD1',
               'PP' => 'ORANGE33' }
          };

my %result;
foreach (keys %{$hash}) {
   my $n_key = $hash->{$_}{'DS'} . '_' . $hash->{$_}{'PP'};
   if( ! defined $result{$n_key} ) {
      $result{$n_key} = [ $_ ];
   } else {
      push @{$result{$n_key}}, $_;
   }
}

foreach (keys %result) {
   if( @{$result{$_}} > 1 ) {
      my($DD, $PP) = split('_', $_);
      print "Duplicated values found for DD => $DD, PP => $PP, ";
      print "No of duplicates : ".scalar(@{$result{$_}})." and there respective indexes are @{$result{$_}}\n";
   }
}

print "$_ : @{$result{$_}}\n" foreach(keys %result);

输出

Duplicated values found for DD => TESTD1, PP => APPLE44, No of duplicates : 2 and there respective indexes are 7 5
TESTD2_APPLE44 : 6
TESTD1_ORANGE33 : 8
TESTD1_APPLE44 : 7 5