VBA-如何在来自excel的日期数组中搜索日期

Question

我正在尝试在 VBA 中编写一个简单的函数，该函数将来自 Excel 的日期和日期数组作为输入。如果给定日期是数组的一部分，则返回 true，否则返回 false。

我的问题是来自 excel 的数组是二维的，但我总是传入一维数组。换句话说，一个列和一个行值，所以我可以检查我的数组中的值，但我传入一个一维数组。

这是我的代码：

Function IsInArray(ByVal MyDate As Date, ByRef Holiday_Calendar As Range) As Boolean
Dim length As Integer
length = WorksheetFunction.Count(Holiday_Calendar)
Dim counter As Integer
'counter = 0

For counter = 0 To length
If Holiday_Calendar(counter) = MyDate Then
IsInArray = True
End If
Next counter

IsInArray = False
End Function

Answer 1

为了帮助您，我对您的代码进行了一些调整和更改。

首先，您可以使用WorksheetFunction.Transpose(myRange) 方法将Range 对象（通常是二维的）转换为一维数组，其中myRange 是您要转换为一维的范围。

我在Call 语句中这样做了，所以它看起来像这样：

Option Explicit

Private Sub DateArrays()

        Dim rngToPass As Range
        Dim dtMyDate As Date
        Dim containsDt As Boolean

        Set rngToPass = Sheet1.Range("A1:A4")
        dtMyDate = "8/7/2015"

        containsDt = IsInArray(dtMyDate, Application.WorksheetFunction.Transpose(rngToPass))

End Sub

这将传入一个由rngToPass 组成的一维数组。

我确实不得不稍微修改你的功能：

Function IsInArray(ByVal MyDate As Date, ByRef Holiday_Calendar As Variant) As Boolean
        Dim length As Integer
        length = WorksheetFunction.Count(Holiday_Calendar)
        Dim counter As Integer

        For counter = 1 To length
                If Holiday_Calendar(counter) = MyDate Then
                        IsInArray = True
                        Exit Function
                End If
        Next counter

        IsInArray = False
End Function

我注意到您的 counter 变量从 0 开始，但转置后的数组索引从 1 开始，所以我将 0 更改为 1。

我还注意到，当条件匹配时，函数会短暂地将 IsInArray 设置为 true，但会继续执行，因此 IsInArray 会在函数结束时重置为 false，因此总是返回 false。我已经包含了一个 Exit Function 语句，如果我们找到匹配项，则可以退出该函数。

这至少应该让你开始。