通过VBA在Access前端执行带有参数的MySQL存储过程

Question

所以，数据库热点。

• 我有一个包含存储过程的 MySQL 数据库。
• 我有一个 Access 文档，它链接到 MySQL 数据库（我可以调查表）作为前端（包含表单和内容）
• 我已经成功地创建了一个 ODBC 直通查询（我认为这就是它们的名称）来调用数据库中的一个存储过程。 Access 中的查询实际上只是 CALL myProcName;，当我使用 Set Result = CurrentDb.OpenRecordset("myProcName") 从 VBA 调用它时，它给出了我期望的结果

我想要达到的目标如下：

• 在 MySQL 中有一个带有一个参数的存储过程 => 检查！
• 该存储过程是否按预期工作 => 在 phpMyAdmin 中检查 => 检查！
• 在 Access 中有一个保存的查询，该查询链接到这个参数存储过程，并给定了一个固定的参数值 => 检查！ （CALL myProcName('myParameterValue')，我可以像执行非参数查询一样从 VBA 调用它）
• 每次执行查询时都可以指定'myParameterValue' => 不检查

我需要以某种方式在已保存查询的 SQL 定义中指定一个参数占位符，并在 VBA 中设置该参数。对于我拥有的 VBA 部分，我认为我会觉得相当优雅：

Private Sub ParametricQuery()
  Dim QDef As QueryDef
  Set QDef = CurrentDb.QueryDefs("myProcName")
  QDef.Parameters(*insert parameter name here*) = parameter value
  Dim Result As Recordset
  Set Result = QDef.OpenRecordset

  Do While Not Result.EOF
    MsgBox Result.Fields(1) 'Display a field from the results
  Loop
End Sub

但是我将如何构建我的 SQL 定义？

PARAMETERS in_param TEXT;
CALL myProcName(in_param);

不起作用。如果我尝试

Set QDef = CurrentDb.QueryDefs("myProcName")
MsgBox QDef.Parameters.Count

我收到一个消息框，告诉我在我的查询定义中总共有 0 个参数，所以这不起作用。

我在网上发现很多人通过字符串操作在 VBA 中构建实际的 SQL。这让我不寒而栗，原因有很多（其中包括安全性、可维护性和优雅）。我坚信有更好的方法，希望能按照我上面勾勒的路线。唯一的问题是：怎么做？

Answer 1

考虑使用ADO 进行参数化查询来调用您的存储过程。目前，您正在使用DAO（Access 的默认数据库 API）来访问 pass-thru 查询（保存的 Access querydef）。但是，这种类型的查询在前端看不到任何东西，只有后端 RDMS，特别是 MySQL SQL 方言及其连接的数据库对象。因此，您不能将本地参数值绑定到它。而PARAMETERS 子句只是 Access SQL 方言的一部分，会导致 MySQL 语法失败。

MySQL存储过程

CREATE PROCEDURE `mystoredproc`(IN param VARCHAR(254))
BEGIN
   SELECT * FROM table WHERE field=param;
END

ADO参数化查询

Public Sub CallMySQLProc()    
    Dim conn As Object, cmd As Object, rst As Object
    Const adCmdStoredProc = 4, adParamInput = 1, adVarChar = 200

    Set conn = CreateObject("ADODB.Connection")
    Set rst = CreateObject("ADODB.Recordset")

    ' DSN-LESS CONNECTION
    conn.Open "Driver={MySQL ODBC 5.3 Unicode Driver};host=hostname;database=databasename;" _
                & "UID=username;PWD=****"

    ' CONFIGURE ADO COMMAND
    Set cmd = CreateObject("ADODB.Command")
    With cmd
        .ActiveConnection = conn
        .CommandText = "mystoredproc"
        .CommandType = adCmdStoredProc
        .CommandTimeout = 15
    End With

    ' APPEND NAMED PARAM
    cmd.Parameters.Append cmd.CreateParameter("param", adVarChar, _
                                              adParamInput, 254, "some.name@example.com")
    Set rst = cmd.Execute

    ' FREE RESOURCES
    rst.Close
    Set rst = Nothing
    Set cmd = Nothing
    Set conn = Nothing

End Sub

---

DAO动态直通查询

这里可以动态构建querydef的.SQL语句，但不会被参数化：

Private Sub ParametricQuery()
  Dim QDef As QueryDef
  Dim Result As Recordset

  Set QDef = CurrentDb.QueryDefs("PassThruQ")
  QDef.SQL = "CALL mystoredproc('some.name@example.com')"

  Set Result = QDef.OpenRecordset

  Do While Not Result.EOF
    Debug.Print Result.Fields(1)    'Print to immediate window a field from the results
  Loop

  Result.close
  Set Result = Nothing
  Set QDef = Nothing
End Sub