在 Visual Basic 中对数组的浅拷贝感到困惑

Question

我的理解是数组的浅拷贝复制数组变量，这样你就有两个指针指向堆上的同一个内存位置。但是按照这个逻辑，下面这段代码应该可以工作，但不能：

Sub Main()
    Dim row As Long() = {1, 2, 3, 4}
    ChangeRow(row.Clone)
    Console.WriteLine(row(0))
End Sub

Sub ChangeRow(ByVal array As Long())
    array(0) = 0
End Sub

Clone 方法应该是做一个浅拷贝。这意味着您将指向原始数组的指针作为参数传递。到目前为止，我在该主题上阅读的所有内容都指向这段代码有效，但事实并非如此。谁能解释一下？

有问题的方言是 VB.Net

Answer 1

我的理解是数组的浅拷贝复制数组变量，这样你就有两个指针指向堆上的同一个内存位置。

没有。它创建了一个新容器，包含所有相同的项目，其他方面与前一个容器相同，但容器本身位于堆上的不同位置。它不会创建对前一个容器的重复引用。

您所描述的只是一个参考。考虑这段代码：

Dim row As Long() = {1, 2, 3, 4}
Dim otherRow as Long() = row

程序的内存现在看起来有点像这样：

Clone 确实会创建一个浅拷贝——也就是说，它将创建一个 new 数组，其中包含与原始数组相同的所有值。然后，您在该新数组的第一项设置值，但这不会影响原始数组，因为它们是完全不同的数组，彼此之间没有运行时引用。考虑这段代码：

Dim row As Long() = {1, 2, 3, 4}
Dim otherRow as Long() = row.Clone

程序的内存现在看起来有点像这样：

如果您想在ChangeRow 子例程中修改原始数组，请不要调用clone。

Sub Main()
    Dim row As Long() = {1, 2, 3, 4}
    ChangeRow(row)
    Console.WriteLine(row(0)) ' outputs 0
End Sub

Sub ChangeRow(ByVal array As Long())
    array(0) = 0
End Sub

为了说明为什么这实际上是一个“浅”副本，请检查它如何与引用类型一起使用。

Class Ref
    Public Value As Long 
    Public Sub New(ByVal value As Long)
        Value = value
    End Sub
End Class

Sub Main()
    Dim row As Ref() = {New Ref(1), New Ref(2), New Ref(3), New Ref(4)}
    ChangeRow(row.Clone)
    Console.WriteLine(row(0).Value) ' outputs 0
End Sub

Sub ChangeRow(ByVal array As Ref())
    array(0).Value = 0
End Sub

尽管row 和row.Clone 引用了不同的数组，但这些数组（Ref 的实例）中的值是相同的，因此修改array(0).Value 与修改row(0).Value 相同。在这种情况下，程序的内存看起来有点像这样：