使用 javascript 以管理员身份运行批处理的简单方法

Question

我想推导出一种简单可靠的方法来自动提升正在运行的批处理，而无需使用其他线程中提出的额外 VBS 文件或提升的快捷方式。通过 javascript 从批处理中调用 UAC 对话框可确保简短的简单代码。

当在对话框中选择“是”时，以下脚本会自动将用户正确提升为管理员权限，但会弹出错误对话框（在 Cmd 窗口之外）“Windows 找不到 'test.bat' ”。可能是因为文件路径包含空格吗？如何修复代码或抑制此错误弹出？

@echo off
:: test admin rights
>nul 2>&1 net file
echo '%errorlevel%'
MSHTA "javascript: var shell = new ActiveXObject('shell.application'); shell.ShellExecute("%~nx0", '', '', 'runas', 1);close();"
:: test admin rights
>nul 2>&1 net file
echo '%errorlevel%'
if !errorlevel! equ 0 echo Hello >%temp%\tst.txt
exit /b

Answer 1

我修复了脚本，现在它运行良好。根据我的研究，这是在任何地方发布的运行批处理中动态授予普通用户管理员权限的最简单可靠的方法。

它不需要使用函数、混合批处理和 VBS 构造、额外文件或提升的快捷方式。它是 Windows 原生的。用户可以在:usercode部分添加自己的任务代码以批量运行。

@echo off
setlocal EnableDelayedExpansion
:: test and acquire admin rights
cd /d %~dp0 & echo/
if not "%1"=="UAC" (
    >nul 2>&1 net file && echo Got admin rights || (echo No admin rights & ^
MSHTA "javascript: var shell = new ActiveXObject('shell.application'); shell.ShellExecute("%~snx0", 'UAC', '', 'runas', 1);close();"))
:: re-test admin rights
echo/ & >nul 2>&1 net file && (echo Got admin rights & echo/) || (echo No admin rights. Exiting... & goto :end)

:usercode
:: add your code here
echo Performing admin tasks
echo Hello >C:\test.txt

:end
timeout /t 5 >nul
exit /b