如何将 AnyEvent::Handler 与具有端口重用的套接字一起使用答案

【问题标题】：how to use AnyEvent::Handler with socket that has port reuse如何将 AnyEvent::Handler 与具有端口重用的套接字一起使用
【发布时间】：2012-10-30 23:16:12
【问题描述】：

最近我遇到了一个很棒的 perl 模块“AnyEvent”，它允许用户进行异步/事件驱动的编程。

创建了以下运行良好的 sn-p。我遇到的问题是，在打开和关闭大量套接字后，它很快耗尽了所有客户端端口（“netstat -ant”显示 20,000 多个套接字处于 TIME_WAIT 状态）。

$hdl = new AnyEvent::Handle (
  connect => [$ip, $port],
  on_connect=> sub {
      my ($handle, $host, $port, $tmp) = @_;
      #print "connect routine for $handle->{ue}\r\n";
      #update states.
  },
  on_read => sub {
      my $hdl = $_[0];
      #read data
      #send response.
  });

我想知道是否可以使用 IO::Socket::INET 创建 TCP 套接字，然后在 AnyEvent::Handle: 中使用新创建的套接字：

my $sock = IO::Socket::INET->new( Proto    => 'tcp',
                             PeerAddr => $ue->{vars}->{ip},
                             PeerPort => $ue->{vars}->{dstPort},
                             ReusePort => 1,
            KeepAlive => 1
) || die "failed to setup outsock $@\n";
$hdl = new AnyEvent::Handle (
  fh => $sock,
  on_connect=> sub {
      my ($handle, $host, $port, $tmp) = @_;
      #print "connect routine for $handle->{ue}\r\n";
      #update states.
  },
  on_read => sub {
      my $hdl = $_[0];
      #read data
      #send response.
  });

试过了，还是不行。感谢任何建议/cmets。

感谢 ikegami 对此进行了调查并提出了建议。但是，似乎 SO_REUSEADDR 没有生效。这是我使用的代码（基于他的建议）

use strict;
use warnings;

use AnyEvent           qw( );
use AnyEvent::Handle   qw( );
use AnyEvent::Impl::EV qw( );
use AnyEvent::Socket   qw( tcp_connect );
use Socket             qw( SOL_SOCKET SO_REUSEPORT SO_REUSEADDR);

my $ts = 0;
my $trans = 0;
my $currentTS;

sub transaction {
   my ($host, $port) = @_;
   tcp_connect($host, $port, sub {
      my ($sock) = @_
         or die "Can't connect: $!";

      my $handle;
      $handle = AnyEvent::Handle->new(
         fh => $sock,
         on_eof => sub {
            $handle->destroy();
         },
         on_read => sub {
            my ($handle) = @_;
            #print $handle->rbuf();
            $trans ++;
            $currentTS = time();
            if ($currentTS > $ts) {
                $ts = $currentTS;
                print "$trans\n";
            }
            #printf "recved %d bytes of data\n", length($handle->rbuf);
            # This should continue to read until header +
            # Content-Length bytes have been read instead
            # of stopping after one read.
            if (length($handle->rbuf) > 0) {
                $handle->destroy();
            }
         },
      );
      $handle->push_write("GET /s HTTP/1.1\r\nHost: $host\r\n\r\n");
      #$handle->push_shutdown();  # Done writing.
   }, sub {
      my ($sock) = @_;

      #setsockopt($sock, SOL_SOCKET, SO_REUSEPORT, 1) or die $!;
      setsockopt($sock, SOL_SOCKET, SO_REUSEADDR, 1)  or die $!;
        #   die "failed to set linger $!\n";
      return undef;
   });
}
{
   my $cv = AnyEvent->condvar();

   my $t = AnyEvent->timer(after=>0.001, interval=>1, cb=> sub {
      transaction("10.3.0.6", 80 );
   });

   $cv->recv();
}

我的系统是 Ubuntu 11.04。在目录/proc/sys/net/ipv4，下面是两个文件的内容：

% 更多 tcp_tw_recycle

1

% 更多的 tcp_tw_reuse

1

【问题讨论】：

如果有可运行的代码来测试和玩......
感谢 ikegami 的建议。添加了一个有效的 sn-p。
第一个想法：你不想使用 IO::Socket::INET。你想要 AnyEvent::Socket::tcp_connect。现在来了解如何设置选项。
我所说的SO_REUSEPORT 也适用于SO_REUSEADDR。它可以满足您的要求，但根据我阅读的内容，我看不出它有什么帮助，因为您没有 bind 将套接字连接到任何端口（也不是您想做的事情）。

标签： perl sockets event-driven anyevent

【解决方案1】：

我无法运行以下内容，因为 Windows 不提供 SO_REUSEPORT，但我非常有信心以下内容可以满足您的要求。

也就是说，我不确定它是否会有所帮助。根据我的阅读，SO_REUSEPORT 允许您绑定到一个已经处于活动状态的端口，但您没有绑定到任何端口。

use strict;
use warnings;

use AnyEvent           qw( );
use AnyEvent::Handle   qw( );
use AnyEvent::Impl::EV qw( );
use AnyEvent::Socket   qw( tcp_connect );
use Socket             qw( SOL_SOCKET SO_REUSEPORT );

sub transaction {
   my ($host, $port) = @_;
   tcp_connect($host, $port, sub {
      my ($sock) = @_
         or die "Can't connect: $!";

      my $handle;
      $handle = AnyEvent::Handle->new(
         fh => $sock,
         on_eof => sub {
            $handle->destroy();
         },
         on_read => sub {
            my ($handle) = @_;
            print $handle->rbuf();

            # This should continue to read until header +
            # Content-Length bytes have been read instead
            # of stopping after one read.
            $handle->destroy();
         },
      );

      $handle->push_write("GET / HTTP/1.1\r\nHost: $host\r\n\r\n");
      $handle->push_shutdown();  # Done writing.
   }, sub {
      my ($sock) = @_;

      setsockopt($sock, SOL_SOCKET, SO_REUSEPORT, 1)
         or die $!;

      return undef;
   });
}

{
   my $cv = AnyEvent->condvar();

   my $t = AnyEvent->timer(after=>0.001, interval=>0.001, cb=> sub {
      transaction("localhost", $ARGV[0] // die("usage"));
   });

   $cv->recv();
}

用于测试的服务器：

use strict;
use warnings;
use 5.010;

use IO::Socket::INET qw( );
use Socket           qw( inet_ntoa );

my $serv = IO::Socket::INET->new(
   Listen => 1,
);

say inet_ntoa($serv->sockaddr) . ":" . $serv->sockport;

while (my $client = $serv->accept()) {
   say "Connection from ".inet_ntoa($client->peeraddr).":".$client->peerport;
   while (<$client>) {
      last if /^(?:\r?\n)?\z/;
   }

   say $client "HTTP/1.1 200 OK\r\n"
      .        "Content-Type: text/plain\r\n"
      .        "\r\n"
      .        "Hello\n";

   say "   done.";
}

【讨论】：

ikegami，非常感谢您的代码示例！效果很好！您是对的，使用“SO_REUSEPORT”，我得到以下信息： EV：回调错误（忽略）：您的供应商尚未定义套接字宏 SO_REUSEPORT，在 anyEvent1.pl 第 37 行使用在我将 SO_REUSEPORT 更改为 SO_REUSEADDR 后，它工作正常。非常感谢您的帮助！
您好 ikegami，感谢您的建议。我认为这是更好的一步。但似乎 SO_REUSEADDR 尚未生效。知道为什么吗？我刚刚更新了问题。

【解决方案2】：

您正在做的事情无法通过 TCP/IP 完成 - 发生的情况是您遇到了一种保护机制（TIME_WAIT 状态），该机制确保 (srcip, srcport, dstip, dstport) 元组不再使用. REUSEADDR、REUSEPORT 和 IO::Socket 在这里都无济于事——这是协议限制。

唯一合法的出路是不要太快地创建相同的元组，例如，使用不同的源 IP 地址或重用现有的 tcp 连接以进行更多事务。甚至使用多个目标端口或 IP 地址 - 任何使元组更“独特”的东西都会有所帮助。

如果你不顾一切，你可以在你的操作系统中启用不安全的端口重用，但这会带来数据损坏的真正危险，所以当涉及到其他人的数据时不要这样做:)

据我所见，ikegamis 示例 sn-ps 非常好，并且很好地展示了如何从 IO::Socket “导入”套接字，以及如何使用 tcp_connect 绑定套接字。如果您选择使用多个源 IP 地址，那么他的代码会显示如何绑定到它们。

【讨论】：