使用 gensub 和 awk 进行非贪婪匹配替换

Question

我正在尝试使用 AWK 清理一堆带有 POS 标签的句子。每个句子可以没有、一个或多个格式为\POS{word|type} 的标签。我很难处理带有多个标签的句子。我找不到使正则表达式不贪婪的方法。示例

输入

sentence_1,My \POS{tailor,noun} is \POS{rich,adj}.

期望的输出

sentence_1,My tailor is rich.

我现在在哪里

echo "sentence_1,My \POS{tailor,noun} is \POS{rich,adj}."|awk -F "," 'BEGIN{OFS=","} {_id=$1;$1="";s=gensub(/\\POS{(.+?),.+?}/, "\\1", "gm", $0); print _id s}'

我得到错误的输出：

sentence_1,My tailor,noun} is \POS{rich.

句子正则表达式不贪心。我知道 awk 不能处理贪婪的表达式，但你会怎么做呢？提前致谢。

Answer 1

对于您展示的示例，您能否尝试在 GNU awk 中进行跟踪、编写和测试，我相信应该可以在任何 awk 中使用。

echo "sentence_1,My \POS{tailor,noun} is \POS{rich,adj}." | 
awk '
{
  first=val=finalVal=""
  count=0
  while(match($0,/[a-zA-Z]+ \\POS{[^,]*/)){
    if(++count==1){
      first=substr($0,1,RSTART-1)
    }
    val=substr($0,RSTART,RLENGTH)
    sub(/\\POS{/,"",val)
    finalVal=(finalVal?finalVal OFS:"")val
    $0=substr($0,RSTART+RLENGTH)
  }
  print first finalVal
}'

或者尝试关注，如果您在\POS{rich,adj}. 之后有任何内容，例如.，那么就这样吧：

echo "sentence_1,My \POS{tailor,noun} is \POS{rich,adj}." | 
awk '
{
  while(match($0,/[a-zA-Z]+ \\POS{[^,]*/)){
    if(++count==1){
      first=substr($0,1,RSTART-1)
    }
    val=substr($0,RSTART,RLENGTH)
    sub(/\\POS{/,"",val)
    finalVal=(finalVal?finalVal OFS:"")val
    $0=substr($0,RSTART+RLENGTH)
  }
  sub(/.*}/,"")
  print first finalVal $0
}'

说明：为上述添加详细说明。

echo "sentence_1,My \POS{tailor,noun} is \POS{rich,adj}." |  ##Using echo to print value.
                                               ##Sending its output as input to awk program.
awk '                                          ##Starting awk program from here.
{
  first=val=finalVal=""                        ##Nullifying variables here.
  count=0                                      ##Setting count to 0 here.
  while(match($0,/[a-zA-Z]+ \\POS{[^,]*/)){    ##Using while loop to run match in it.
  ##Match has regex to match one or more alphabets space \POS{ till comma comes.
    if(++count==1){                            ##Checking condition if count is 1 then do following.
      first=substr($0,1,RSTART-1)              ##Creating first to have everything before matched this should have very first matches before value eg--> sentence_1,My
    }
    val=substr($0,RSTART,RLENGTH)              ##Creating val which is sub string of matched regex.
    sub(/\\POS{/,"",val)                       ##Using substitute \POS{ with NULL.
    finalVal=(finalVal?finalVal OFS:"")val     ##Creating finalVal to have all values in it.
    $0=substr($0,RSTART+RLENGTH)               ##Re-creating whole line to have only rest of the line in it, removing matched part.
  }
  print first finalVal                         ##Printing first and finalVal here.
}'

Answer 2

这是一个使用否定括号表达式的sed 解决方案：

s='sentence_1,My \POS{tailor,noun} is \POS{rich,adj}.'
sed -E s'/\\POS\{([^,]+),[^}]*\}/\1/g' <<< "$s"

sentence_1,My tailor is rich.

RegEx 解释：

• \\POS\{：匹配\POS{
• ([^,]+)：匹配 1 个或多个非逗号字符并在 #1 组中捕获
• ,：匹配逗号
• [^}]*：匹配 0 个或多个非} 字符
• \}：匹配一个}
• /\1：替换为 \1，即捕获组 #1 的反向引用

Answer 3

或者用 gawk 的gensub 稍微“更简单”（？）（最初尝试过）：

$ echo 'sentence_1,My \POS{tailor,noun} is \POS{rich,adj}' | gawk '{s=gensub(/\\POS{([^,]+),[^}]+}/, "\\1", "G", $0); print s}'
sentence_1,My tailor is rich