如何进行 CSV 记录拆分 [重复]

Question

我需要从 CSV 文件中获取特定字段并将其放入数组中。我不知道该怎么做。这是我迄今为止尝试过的。

#!/usr/bin/perl

use strict;
use warnings;

my @array  = <>;
my @fields = split ",", @array;

print @fields[2];

这是 CSV 文件的示例

9988,Kathleen,Brown,kbrownc@goo.gl,OH,Female,Italian
9989,Antonio,Ford,afordb@bigcartel.com,IL,Male,
9990,Diana,Banks,dbanksa@jalbum.net,MA,Female,English

Answer 1

如果您的 CSV 文件有可能包含带引号的字段（因此每个字段本身可能包含逗号），那么您应该使用 Text::CSV 正确处理数据。但是，对于您问题中的简单数据，只需使用 split 即可。

您的代码看起来像这样。请注意，通常不需要将整个文件读入内存，并且逐行处理更节省内存。它还倾向于将程序员的注意力集中在一行上，从而改进最终的设计。

use strict;
use warnings;

my @names;

while ( <> ) {
  chomp;
  my @fields = split /,/;
  push @names, $fields[2];
}

print "$_\n" for @names;

输出

Brown
Ford
Banks

---

更新

如果您对map 感到满意，那么您可能更喜欢这个。它更简洁，但与您自己的代码一样，效率低下，因为它一次将整个文件读入内存（尽管它会立即再次丢弃它）。除非文件很大，否则应该不是问题。

use strict;
use warnings;

my @names = map { chomp; ( split /,/ )[2]; } <>;

print "$_\n" for @names;

Answer 2

有一个 perl 模块可以处理包括 csv 在内的许多文件格式。您可以通过运行安装模块：

$ sudo cpan install Text::CSV;

现在您可以轻松地解析逗号分隔符（这是默认设置）或指定任何其他字符。

安装 perl 模块后，这是一个完成任务的快速脚本。我使用您的数据创建了一个名为 test.csv 的文本文件。

#!/usr/bin/perl

use strict;
use warnings;
require Text::CSV;

my $csv = Text::CSV->new;

open (DATA, "<test.csv") or die "Can't open file...";
while (<DATA>) {
    $csv->parse($_);
    my@fields = $csv->fields(); 
    print $fields[2];
}
close DATA;

您可以通过运行以下命令查看 Text::CSV 模块的其他功能：

$ perldoc Text::CSV