VBA 从 Web 服务器导入 UTF-8 CSV 文件

Question

我有一个 UTF-8 CSV 文件存储在网络服务器上。当我下载文件时，把它放在我的硬盘上，然后我用这个宏（来自宏记录器）将它导入到 Excel 表中：

Sub Macro2()
Workbooks.OpenText Filename:= _
    "C:/myFile.csv", Origin _
    :=65001, StartRow:=1, DataType:=xlDelimited, TextQualifier:= _
    xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=False, Semicolon:=False _
    , Comma:=True, Space:=False, Other:=False
End Sub

所有字符（越南语字符）都正确显示。

当我尝试相同的宏但没有给出文件的本地地址（“C:/myFile.csv”）时，我传递了文件的 URL（“http://myserver.com/myFile.csv”），CSV 被正确导入到我的Excel 工作表，但越南语字符不再正确显示。

我也尝试过使用“数据”选项卡，但 Excel 似乎忽略了编码：

With ActiveSheet.QueryTables.Add(Connection:= _
                "TEXT;C:/myFile.csv" _
                , Destination:=Range("$A$1"))
                .Name = "myFile.csv"
                .FieldNames = True
                .RowNumbers = False
                .FillAdjacentFormulas = False
                .PreserveFormatting = True
                .RefreshOnFileOpen = False
                .RefreshStyle = xlInsertDeleteCells
                .SavePassword = False
                .SaveData = True
                .AdjustColumnWidth = True
                .RefreshPeriod = 0
                .TextFilePromptOnRefresh = False
                .TextFilePlatform = 65001
                .TextFileStartRow = 1
                .TextFileParseType = xlDelimited
                .TextFileTextQualifier = xlTextQualifierDoubleQuote
                .TextFileConsecutiveDelimiter = False
                .TextFileTabDelimiter = True
                .TextFileSemicolonDelimiter = False
                .TextFileCommaDelimiter = False
                .TextFileSpaceDelimiter = False
                .TextFileOtherDelimiter = "~"
                .TextFileColumnDataTypes = Array(1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1)
                .TextFileTrailingMinusNumbers = True
                .Refresh BackgroundQuery:=False
       End With

样本数据：„; Â; ˜; Â1/4; ‰; ™,™

哪个 Excel 错误读取为：„; Â; ˜; Â1/4; ‰; ™,™;

Answer 1

IMO，使用记录的宏代码打开 UTF-8/UTF-8-BOM 文件时，Excel 中似乎存在错误/冲突，特别是当 Origin 参数设置为 65001 时 应该是UTF-8。

我找到了两个解决这个问题的方法：

1. 从函数调用中删除Origin参数，看看文件是否正确加载Workbooks.OpenText Filename:="C:\file.csv"。

   MSDN says：

   如果省略此参数，则该方法使用当前设置 文本导入向导中的文件来源选项。

   我认为，一旦您将文件与 Excel 链接，它应该尝试读取文件的标题并自动选择正确的Country Code（好吧，假设标题没有丢失)。

2. 我尝试了不同的Country Codes，发现在我的特定场景设置中Origin:=1252 (1252 - windows-1252 - ANSI Latin 1; Western European (Windows)) 可以很好地在 Excel 中加载文件。

   李>

Answer 2

如果您自己下载csv文件时字符显示正确，我会将过程分为2个阶段：

正在下载

Sub DownloadFile(ByVal url As String, ByVal local As String)

Dim WinHttpReq As Object
Set WinHttpReq = CreateObject("Microsoft.XMLHTTP")
WinHttpReq.Open "GET", url, False, "username", "password"
WinHttpReq.send

myURL = WinHttpReq.responseBody
If WinHttpReq.Status = 200 Then
    Set oStream = CreateObject("ADODB.Stream")
    oStream.Open
    oStream.Type = 1
    oStream.Write WinHttpReq.responseBody
    oStream.SaveToFile local, 2 
    oStream.Close
End If

End Sub

加载 CSV

Sub OpenCsv(ByVal csvfile As String)
Workbooks.OpenText Filename:= _ 
csvfile,Local:=True,StartRow:=1, DataType:=xlDelimited, TextQualifier:= _
xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=False, Semicolon:=False _
, Comma:=True, Space:=False, Other:=False
End Sub

注意：Local参数是这里的关键，它使VBA使用你的excel的本地配置（越南语），默认设置为False。

把它们放在一起

Sub DownloadAndLoad
  DownloadFile "http://myserver.com/myFile.csv","C:\myFile.csv"
  OpenCsv "C:\myFile.csv"
End Sub

Answer 3

我一直在研究一个类似的问题，我们将 utf-8 编码的 csv 文件导入到工作表中。我没有从 Web 服务器中提取数据，但这可能会有所帮助。

我的解决方案是将 utf-8 文件读取到局部变量，然后将其插入工作表中。我尝试将数据保存到使用 ansi 编码的临时文件中，但这样做会导致所有字符丢失重音。

Function ReadUTF8CSVToSheet(file As String)
    Dim ws As Worksheet
    Dim strText As String

    ' read utf-8 file to strText variable
   With CreateObject("ADODB.Stream")
        .Open
        .Type = 1  ' Private Const adTypeBinary = 1
        .LoadFromFile file
        .Type = 2  ' Private Const adTypeText = 2
        .Charset = "utf-8"
        strText = .ReadText(-1)  ' Private Const adReadAll = -1
    End With

    ' parse strText data to a sheet
    Set ws = Sheets.Add()
    intRow = 1
    For Each strLine In Split(strText, chr(10))
        If strLine <> "" Then
            With ws
                .Cells(intRow, 1) = strLine
                .Cells(intRow, 1).TextToColumns Destination:=Cells(intRow, 1), DataType:=xlDelimited, _
                    TextQualifier:=xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=False, _
                    Semicolon:=False, Comma:=True, Space:=False, Other:=False
            End With

            intRow = intRow + 1
        End If
    Next strLine

    ReadUTF8CSVToSheet = ws.Name

End Function

' to run
strSheetName = ReadUTF8CSVToSheet("C:\temp\utf8file.csv")