批处理文件中带有 vbscript 命令的批处理脚本问题

Question

我是批处理脚本和 vbscript 的新手。我想要做的是将 .xlsx Excel 文件转换为 .csv Excel 文件，在多个目录中（递归）。例如：

Main directory
   subdirectory1
      file1.xlsx
      file2.xlsx
   subdirectory2
      file3.xlsx
      file4.xlsx

我已经制作了这个批处理脚本：

FOR /r %%a in (*.xlsx) do (
    SET filename=%%a
    ExceltoCSV.vbs %filename% *.csv
)

for 循环内部是 ExceltoCSV.vbs。我从这个线程 Convert XLS to CSV on command line 得到了这段代码，我已经尝试了前 2 个答案（两者都不需要下载任何东西）。

    if WScript.Arguments.Count < 2 Then
    WScript.Echo "Error! Please specify the source path and the destination. Usage: XlsToCsv SourcePath.xls Destination.csv"
    Wscript.Quit
End If
Dim oExcel
Set oExcel = CreateObject("Excel.Application")
Dim oBook
Set oBook = oExcel.Workbooks.Open(Wscript.Arguments.Item(0))
oBook.SaveAs WScript.Arguments.Item(1), 6
oBook.Close False
oExcel.Quit
WScript.Echo "Done"

错误是无法访问 ExceltoCSV.vbs 文件。但是，我相信批处理脚本正在运行，例如它会说：

SET filename=C:\folder\subfolder\test1.xlsx

然后它调用：

ExceltoCSV.vbs C:\folder\subfolder\test1.xlsx *.csv

我不确定问题是什么，我目前很困惑。

Answer 1

您正在使用 VBScript 进行转换。为什么不只用它来迭代你的文件夹呢？这样您就不必担心从 BAT 调用 VBS 并传递正确的参数。

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set oExcel = CreateObject("Excel.Application")
DoFolder "c:\mainfolder"
oExcel.Quit

Sub DoFolder(strFolder)

    ' Recursively process each subfolder...
    For Each objSubFolder In objFSO.GetFolder(strFolder).SubFolders
        DoFolder objSubFolder.Path
    Next

    ' Convert any XLSX files...
    For Each objFile In objFSO.GetFolder(strFolder).Files
        If StrComp(objFSO.GetExtensionName(objFile.Name), "xlsx", vbTextCompare) = 0 Then

            strNewName = Left(objFile.Path, Len(objFile.Path) - 4) & "csv"

            ' Convert...
            Set oBook = oExcel.Workbooks.Open(objFile.Path)
            oBook.SaveAs strNewName, 6
            oBook.Close False

        End If            
    Next

End Sub

Answer 2

VBS 需要与 BAT 文件位于同一目录中。

问题是FOR 循环中的变量扩展规则意味着filename 不会被设置为当前文件变量值；只需使用 %%a 代替：

FOR /r %%a in (*.xlsx) do (
   ExceltoCSV.vbs "%%a" "%%~dpna.csv"
)

您正在将字符串 "*.CSV" 传递给无法运行的脚本，%%~dpna.csv 采用 %%a 中的文件名并将扩展名更改为 .CSV。

引号是为了在路径中留出空格。