Actionscript 3 - 如何在删除该事件后保留该事件的值

Question

我在我的事件处理函数（该函数在 event.COMPLETE 之后执行）期间以及如果我在我的事件中跟踪对象时为我的 xml 对象 (xml = new XML(e.currentTarget.data);) 设置了一个值函数处理程序，它显示我的 xml 数据。

但是如果我尝试在事件处理函数之外跟踪它，它不会显示我的 xml 内容。有没有办法让我的 xml 对象内容值显示在其他函数中但不在事件处理函数中？

private var xml:XML; 

public function XMLLoader(xmlURL:String) 
{ 
    var xmlURLRequest:URLRequest = new URLRequest(xmlURL); 
    var xmlURLLoader:URLLoader  = new URLLoader(xmlURLRequest); 
    xmlURLLoader.addEventListener(Event.COMPLETE, xmlData); 
}

private function xmlData(e:Event):void 
{
    e.currentTarget.removeEventListener(Event.COMPLETE, xmlData); 
    xml = new XML(e.currentTarget.data); 
    dispatchEvent(new Event(Event.COMPLETE)); 
    trace(xml); 
} 

public function getXMLData():void 
{ 
     //I've find out that this shows null because this function is faster
     //what do i do? put an event.complete in every following function?
    trace(xml);
}

谢谢。

Answer 1

我认为你在XMLLoader() 之后立即调用getXMLData()，此时xml 对象仍然为空。尝试调用getXMLData() inside xmlData() 函数，您应该会看到不同。

Answer 2

您可能在 URLLoader 完成之前调用 getXMLData() 但是，通常，您正在执行的代码是不好的做法。 Actionscript 没有任何阻塞，因此当您使用 URLRequest 实例化新的 URLLoader 时，它会立即开始加载操作。例如，如果您的文件被缓存，则您的 Event.COMPLETE 侦听器可能永远不会触发，因为您在开始加载操作后附加它。

我在下面附上了创建和加载数据的理想过程：

var data:XML;
var urlLoader:URLLoader = new URLLoader();

urlLoader.addEventListener(Event.COMPLETE, urlLoader_completeHandler);
urlLoader.load(new URLRequest("path"));

private function urlLoader_completeHandler(event:Event):void
{
    data = new XML(urlLoader.data);
}

如果你想把它应用到你自己的 XMLLoader 类中，我已经在 AS3 中包含了“正确”的实现......但是非常冗长。

import flash.net.URLLoader;
import flash.events.Event;

class XMLLoader extends URLLoader
{
    public function XMLLoader()
    {
        super();
        addEventListener(Event.COMPLETE, completeHandler);
    }

    private function completeHandler(event:Event):void
    {
        dispatchEvent(new XMLLoaderEvent(XMLLoaderEvent.COMPLETE, new XML(data)));
    }
}

class XMLLoaderEvent extends Event
{
    public static const COMPLETE:String = "xmlLoaderComplete";

    public var data:XML;

    public function XMLLoaderEvent(type:String, data:XML = null, bubbles:Boolean = false, cancelable:Boolean = false)
    {
        super(type, bubbles, cancelable);

        this.data = data;
    }

    override public function clone():Event
    {
        return new XMLLoaderEvent(type, data, bubbles, cancelable);
    }
}

使用 XMLLoader 类：

var xmlLoader:XMLLoader = new XMLLoader();
xmlLoader.addEventListener(XMLLoaderEvent.COMPLETE, function(event:XMLLoaderEvent):void
{
    trace(event.data);
});

xmlLoader.load(new URLRequest("data.xml"));

祝你好运！

Answer 3

更改您的跟踪方法以指示 xml 是否已加载...
你遇到了竞争状况

private var _xmlLoaded:Boolean=false;// add this to see if the xml is loaded
private function xmlData(e:Event):void 
{
    e.currentTarget.removeEventListener(Event.COMPLETE, xmlData); 
    xml = new XML(e.currentTarget.data); 
    _xmlLoaded=true;
    dispatchEvent(new Event(Event.COMPLETE)); 
    trace(xml); 
} 
public function getXMLData():void 
{ 
    if (_xmlLoaded)
        trace(xml);
    else
        trace("not yet loaded");
}

Answer 4

//注意：如果你想直接访问这个“类”的函数而不使用任何事件监听器，请使用它，因为它已经在每个函数上都有它的事件监听器（这会导致一个函数只有 getXMLData() )

私有变量 xml:XML;

公共函数 XMLLoader(xmlURL:String) {

     var xmlURLRequest:URLRequest = new URLRequest(xmlURL); 
     var xmlURLLoader:URLLoader  = new URLLoader(xmlURLRequest); 
     xmlURLLoader.addEventListener(Event.COMPLETE, xmlData); 

}

私有函数 xmlData(e:Event):void {

     e.currentTarget.removeEventListener(Event.COMPLETE, xmlData); 
     xml = new XML(e.currentTarget.data); 
     dispatchEvent(new Event(Event.COMPLETE)); 
     trace("1");//this used to come second of getXMLData() but it's solved now
     trace(xml); 

}

公共函数 getXMLData():void {

     //This function was coming first so if you don't want to use an event listener outside    
     //this class to wait for event.complete you can use it here to wait for it and access
     //the function directly without being afraid of the object being null:
     addEventListener(Event.COMPLETE, go)
     function go(e:Event){
          trace("2"); //now it ONLY comes AFTER the event.complete, no need for external                   listeners over this class. declare the class object and use getXMLData() directly cause it always comes second the event handler xmlData() :)
          trace(xml);
     }
}