如何通过批处理文件列出所有大小的文件夹

Question

我想要一个简单的解决方案，以 txt 或 csv 格式列出文件夹列表及其大小。

我将此代码用于文件夹列表

dir C:\Temp\*.* /b /a:d > C:\folderList.txt

电流输出

<<folderList.txt>>
folder1
folder2
folder3

想要的输出

<<folderList.txt>>
folder1 # 100 MB
folder2 # 30 MB
folder3 # 110 MB

它只会生成每个文件夹的大小.. 我该如何进行？任何帮助

Answer 1

对于列表中的每个文件夹，使用dir命令获取文件夹下文件的大小

@echo off
    setlocal disabledelayedexpansion

    set "folder=%~1"
    if not defined folder set "folder=%cd%"

    for /d %%a in ("%folder%\*") do (
        set "size=0"
        for /f "tokens=3,5" %%b in ('dir /-c /a /w /s "%%~fa\*" 2^>nul ^| findstr /b /c:"  "') do if "%%~c"=="" set "size=%%~b"
        setlocal enabledelayedexpansion
        echo(%%~nxa # !size!
        endlocal
    )

    endlocal

它遍历指定的文件夹（作为参数传递给批处理文件，如果没有参数，则传递给当前目录）。

对于其中的每个文件夹 (for /d)，在内部 for 命令内执行递归 dir 命令，并从其输出中解析最后的摘要行（由 findstr 提取）（ for 命令中的 tokens）和该子文件夹下所有文件的总大小被检索。然后文件夹的名称（和扩展名，如果有的话）和它下面元素的大小会回显到控制台。

如果需要创建文件，将批处理的输出重定向到文件

getSizes.cmd "c:\temp" > C:\folderList.txt

Answer 2

使用 MC ND 的出色代码，我添加了对 Kb、Mb、Gb 等的转换。以防万一您希望使用这些格式。

@echo off
setlocal disabledelayedexpansion

set "folder=%~1"
  if not defined folder set "folder=%cd%"

    for /d %%a in ("%folder%\*") do (
        set "size=0"
        for /f "tokens=3,5" %%b in ('dir /-c /a /w /s "%%~fa\*" 2^>nul ^| findstr /b /c:"  "') do if "%%~c"=="" set "size=%%~b"
        setlocal enabledelayedexpansion
        call :GetUnit !size! unit
        call :ConvertBytes !size! !unit! newsize
        echo(%%~nxa - !newsize! !unit!
        endlocal
    )

endlocal
exit /b

:ConvertBytes bytes unit ret
setlocal
if "%~2" EQU "KB" set val=/1024
if "%~2" EQU "MB" set val=/1024/1024
if "%~2" EQU "GB" set val=/1024/1024/1024
if "%~2" EQU "TB" set val=/1024/1024/1024/1024
> %temp%\tmp.vbs echo wsh.echo FormatNumber(eval(%~1%val%),1)
for /f "delims=" %%a in ( 
  'cscript //nologo %temp%\tmp.vbs' 
) do endlocal & set %~3=%%a
del %temp%\tmp.vbs
exit /b


:GetUnit bytes return
set byt=00000000000%1X
set TB=000000000001099511627776X
if %1 LEQ 1024 set "unit=Bytes"
if %1 GTR 1024   set "unit=KB"
if %1 GTR 1048576  set "unit=MB"
if %1 GTR 1073741824  set "unit=GB"
if %byt:~-14% GTR %TB:~-14% set "unit=TB"
endlocal & set %~2=%unit%
exit /b

Answer 3

我采用了@Matt Williamsons 代码并将每一行导出到运行目录folderSizes.csv 中的一个.csv 文件。它以列的形式提供完整的字节大小，以便您可以轻松地在 excel（或其他）中排序。

@echo off
echo Getting folder sizes for you...storing to folderSizes.csv
setlocal disabledelayedexpansion
if EXIST folderSizes.csv del folderSizes.csv
echo Folder,Bytes Size,Short Size > folderSizes.csv

set "folder=%~1"
  if not defined folder set "folder=%cd%"

    for /d %%a in ("%folder%\*") do (
        set "size=0"
        for /f "tokens=3,5" %%b in ('dir /-c /a /w /s "%%~fa\*" 2^>nul ^| findstr /b /c:"  "') do if "%%~c"=="" set "size=%%~b"
        setlocal enabledelayedexpansion
        call :GetUnit !size! unit
        call :ConvertBytes !size! !unit! newsize
        echo(%%~nxa,!size!,!newsize!!unit! >> folderSizes.csv
        endlocal 
    )

endlocal
exit /b

:ConvertBytes bytes unit ret
setlocal
if "%~2" EQU "KB" set val=/1024
if "%~2" EQU "MB" set val=/1024/1024
if "%~2" EQU "GB" set val=/1024/1024/1024
if "%~2" EQU "TB" set val=/1024/1024/1024/1024
> %temp%\tmp.vbs echo wsh.echo FormatNumber(eval(%~1%val%),1)
for /f "delims=" %%a in ( 
  'cscript //nologo %temp%\tmp.vbs' 
) do endlocal & set %~3=%%a
del %temp%\tmp.vbs
exit /b


:GetUnit bytes return
set byt=00000000000%1X
set TB=000000000001099511627776X
if %1 LEQ 1024 set "unit=Bytes"
if %1 GTR 1024   set "unit=KB"
if %1 GTR 1048576  set "unit=MB"
if %1 GTR 1073741824  set "unit=GB"
if %byt:~-14% GTR %TB:~-14% set "unit=TB"
endlocal & set %~2=%unit%
exit /b

Answer 4

我的JREN.BAT utility 可用于获取具有大小的文件夹列表。它是一个混合 JScript/批处理脚本，可以在 XP 以后的任何 Windows 机器上本地运行。

JREN 不能方便地转换为 MB（或任何其他单位）——它只是以字节为单位列出大小。但是获得列表确实很方便（并且相对较快）：

jren "$" "' # '+size()" /d /j /list /p "d:\temp" >"C:\folderList.txt"

您可以考虑将文件夹大小放在首位，空间填充到超过最大文件夹的固定宽度，然后是文件夹名称。我发现这种格式更容易阅读，而且仍然很容易解析：

jren "^" "size('               ')+'  '" /d /j /list /p "d:\temp" >"C:\folderList.txt"

输出看起来像这样

           1852  SomeFolderName
        1616869  Another folder name
         137764  yetAnother

由于 JREN 是一个批处理文件，如果您将命令放在另一个批处理脚本中，则必须使用 CALL JREN。

Answer 5

在 Windows 上尝试sed：

dir /-c /a /w /s|sed -nr "/:$/q;/:/h;/^\s+[0-9]/{s/.*[^0-9]([0-9]+.*)/\1/;H;g;s/\n/ /p}"

Answer 6

如果您使用的是 windows 7 或新的使用 powershell 并输入命令

ls-r >> log.txt

它将列出当前目录中的所有文件以及以字节为单位的文件大小以记录文件。