填写所有单元格后的时间戳

Question

情况是这样的

A 到 G 列被设计为下拉列表（数据验证）：姓名、编号、ID、电话等。到达办公室后，每个员工必须在行的每个单元格中填写他们的信息，在 A 到 G 列中。

我想从 VBA 代码中得到什么：

只有当每个单元格都填写A:G时，日期和时间才会在相应的单元格中，在H列中标记。它是永久的。它永远不会改变。一旦盖上日期，单元格列A:G 也会被锁定。

到目前为止我的编码：

Private Sub Worksheet_Change(ByVal Target As Range)
     If Target.Column = 1 Then
          Target.Offset(0,1) = Now
     End If
End Sub

此时间戳仅在 A 列中的单元格发生更改时有效:(

我应该使用“案例选择”语句吗？

Answer 1

这是你正在尝试的吗？ （经过试验和测试）

Option Explicit

'~~> Change this to the relevant password
Const MYPASSWORD As String = "BlahBlah"

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Cells.CountLarge > 1 Then Exit Sub

    On Error GoTo Whoa

    Application.EnableEvents = False

    Dim rng As Range
    Dim nRow As Long

    nRow = Target.Row

    Set rng = Range("A" & nRow & ":G" & nRow)

    '~~> Check if all cell from A-G are filled and
    '~~> There is no time stamp already there
    If Application.WorksheetFunction.CountA(rng) = 7 _
    And Len(Trim(Range("H" & nRow).Value)) = 0 Then
       ActiveSheet.Unprotect MYPASSWORD
       Range("H" & nRow).Value = Now
       Range("A" & nRow & ":H" & nRow).Locked = True
       ActiveSheet.Protect MYPASSWORD
    End If
Letscontinue:
    Application.EnableEvents = True
    Exit Sub
Whoa:
    MsgBox Err.Description
    Resume Letscontinue
End Sub