如何在 Perl 中将时间转换为 hh:mm:ss 格式？

Question

我们需要将数字格式的时间列转换为标准时间格式，即perl中的hh:mm:ss。

例子：

1. 如果时间值为1500，则转换后的值应为00:15:00。
2. 如果时间值为11500，则转换后的值应为01:15:00。

我试过这个：

use POSIX qw(strftime); 
printf( strftime("%H:%M:%S",localtime(1500))); 

但是输出是00:25:00，我需要输出是00:15:00。

我该如何解决这个问题？

Answer 1

您首先需要通过添加左零填充将数字变为六位数。之后，您需要在每两位数后插入冒号:。最简单的方法是使用sprintf 和正则表达式。

use strict;
use warnings;
use feature 'say';

my $date = '11500';
my $formatted = sprintf '%06d', $date;
$formatted =~ s/(\d\d)(\d\d)(\d\d)/$1:$2:$3/;

say $formatted;

输出

01:15:00
00:15:00 (for 1150)

请注意，长度大于 6 的字符串会中断。

Answer 2

更新

要将 24 小时制转换为 12 小时制，最好使用Time::Piece 模块将%H%M%S 转换为%I:%M:%S%p。 sprintf 仍然是必要的，作为将字符串用零填充到六位数的初始步骤

此示例程序每小时格式化并打印从 5900 到 235900 的时间值

use strict;
use warnings;
use 5.010;

use Time::Piece;

say format_time(1500);
say format_time(11500);
say '';

for my $time (0 .. 23) {
    $time = $time * 10000 + 5900;
    say format_time($time);
}

sub format_time {
    my ($time) = @_;
    $time = Time::Piece->strptime(sprintf('%06d', $time), '%H%M%S');
    lc $time->strftime('%I:%M:%S%p');
}

输出

12:15:00am
01:15:00am

12:59:00am
01:59:00am
02:59:00am
03:59:00am
04:59:00am
05:59:00am
06:59:00am
07:59:00am
08:59:00am
09:59:00am
10:59:00am
11:59:00am
12:59:00pm
01:59:00pm
02:59:00pm
03:59:00pm
04:59:00pm
05:59:00pm
06:59:00pm
07:59:00pm
08:59:00pm
09:59:00pm
10:59:00pm
11:59:00pm

---

原方案

在此解决方案中，sprintf('%06d', $time) 用于使用零将字符串填充为六位数字，/../g 将结果拆分为（三个）两个字符的块。 join ':' 用冒号重新组合这些块以实现所需的模式

my $time = 1500;

my $converted = join ':', sprintf('%06d', $time) =~ /../g;

print $converted, "\n";

输出

00:15:00

Answer 3

我找到了这段代码，请尝试

#!/usr/local/bin/perl

($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) = localtime();

printf("Time Format - HH:MM:SS\n");
printf("%02d:%02d:%02d", $hour, $min, $sec);

我们的看跌期权： 时间格式 - HH:MM:SS 06:58:52