解析注释行

Question

鉴于以下基本语法，我想了解如何处理注释行。缺少的是对通常终止注释行的<CR><LF> 的处理——唯一的例外是 EOF 之前的最后一个注释行，例如。 g.：

# comment
abcd := 12 ;
# comment eof without <CR><LF>

grammar CommentLine1a;

//==========================================================
// Options
//==========================================================



//==========================================================
// Lexer Rules
//==========================================================

Int
  : Digit+
  ;

fragment Digit
  : '0'..'9'
  ;

ID_NoDigitStart
  : ( 'a'..'z' | 'A'..'Z' ) ('a'..'z' | 'A'..'Z' | Digit )*
  ;

Whitespace
  : ( ' ' | '\t' | '\r' | '\n' )+ { $channel = HIDDEN ; }
  ; 


//==========================================================
// Parser Rules
//==========================================================

code
  : ( assignment | comment )+
  ;

assignment
  : id_NoDigitStart ':=' id_DigitStart ';'
  ;

id_NoDigitStart
  : ID_NoDigitStart
  ;  

id_DigitStart
  : ( ID_NoDigitStart | Int )+
  ;

comment
  : '#' ~( '\r' | '\n' )*
  ;

Answer 1

除非您有非常令人信服的理由将注释放入解析器（我想听听），否则您应该将其放入词法分析器中：

Comment
  :  '#' ~( '\r' | '\n' )*
  ;

而且由于您已经在 Space 规则中考虑了换行符，因此像 # comment eof without <CR><LF> 这样的输入没有问题

此外，如果您在解析器规则中使用文字标记，ANTLR 会在后台自动创建它们的词法分析器规则。所以在你的情况下：

comment
  :  '#' ~( '\r' | '\n' )*
  ;

将匹配 '#' 后跟零个或多个 tokens，而不是 '\r' 和 '\n' 和 not 零个或多个'\r' 和 '\n' 以外的字符。

供将来参考：

内部解析器规则

• ~ 否定令牌
• . 匹配任何令牌

内部词法分析器规则

• ~ 否定字符
• . 匹配 0x0000 ... 0xFFFF 范围内的任何字符