Emacs 中类似 Eclipse 的行注释

Question

在 Eclipse 中，高亮显示多行并按下 Ctrl+/ 会匹配所选内容的每一行。

Emacs 有一个函数 comment-or-uncomment-region，它与我想要的很接近，但如果该区域仅部分覆盖我试图评论的行，则行为会有所不同。

有什么方法可以让我创建一个类似于comment-or-uncomment-region 的函数，但不管区域是如何选择的，都让它注释该区域的每一行？

换句话说，只要该区域包含该行，我希望该函数就好像该区域占据整行一样，因此它的行为与 Eclipse 的选择注释一样。

编辑：我实际上使用的是作为答案提到的comment-or-uncomment-region-or-line 函数，而不是 Emacs 附带的函数 comment-or-uncomment-region。

我觉得这似乎值得一提，因为前者似乎更多地反映了行注释在 Eclipse 中的工作方式。也就是说，如果不存在区域，则注释该点所在的线。

Answer 1

我最终将 juanleon 和 Ehvince 的答案的部分结合起来，得到了更像 Eclipse 的评论的东西。

这是最终产品：

(defun comment-eclipse ()
  (interactive)
  (let ((start (line-beginning-position))
        (end (line-end-position)))
    (when (or (not transient-mark-mode) (region-active-p))
      (setq start (save-excursion
                    (goto-char (region-beginning))
                    (beginning-of-line)
                    (point))
            end (save-excursion
                  (goto-char (region-end))
                  (end-of-line)
                  (point))))
    (comment-or-uncomment-region start end)))

如果有什么问题请告诉我。

Answer 2

请注意，emacs 25 有一个新函数 comment-line 绑定到 C-x C-;。

Answer 3

这里你有一个函数可以做你所描述的：

(defun comment-or-uncomment-region-eclipse-style (beg end &optional arg)
  (interactive "*r\nP")
  (comment-or-uncomment-region
   (save-excursion
     (goto-char beg)
     (beginning-of-line)
     (point))
   (save-excursion
     (goto-char end)
     (end-of-line)
     (point)) arg))

Answer 4

FWIW，我不使用comment-or-uncomment-region。我改用 comment-region。这很相似，但它让您 决定是取消评论还是评论。它允许您嵌套 cmets，而不是在区域已被注释掉时自动取消注释。使用数字前缀 arg 时，它会使用很多注释开始字符（例如，;、;;、;;;、... 在 Lisp 中）。使用普通的 C-u 前缀 arg 它会取消。我将它绑定到C-x C-;。

无论如何，我认为这可以满足您的需求，使用 comment-region（查看一般行为）：

(defun comment-region-lines (beg end &optional arg)
  "Like `comment-region', but comment/uncomment whole lines."
  (interactive "*r\nP")
  (if (> beg end) (let (mid) (setq mid beg beg end end mid)))
  (let ((bol  (save-excursion (goto-char beg) (line-beginning-position)))
        (eol  (save-excursion (goto-char end) (line-end-position))))
    (comment-region bol end arg)))

;; Suggested binding
(define-key ctl-x-map [(control ?\;)] 'comment-region-lines)

这将保存并恢复该区域。如果只选择了一行的一部分，它就可以工作。我什至可能会自己使用它（这说明了很多，因为我对这种东西有很好的习惯）。

Answer 5

与 Juanleon 的解决方案相比，我补充说，如果您不选择区域，它将（取消）注释当前行并转到下一行（而不是根据您看不到的标记做某事）：

  (defun comment-or-uncomment-region-or-line ()
"Comments or uncomments the region or the current line if there's no active region."
(interactive)
(let (beg end)
    (if (region-active-p)
        (setq beg (region-beginning) end (region-end))
        (setq beg (line-beginning-position) end (line-end-position)))
    (comment-or-uncomment-region beg end)
    (next-line)))
;; bind it to F7:
(global-set-key (kbd "<f7>")'comment-or-uncomment-region-or-line)

取自：Emacs comment/uncomment current line

Answer 6

有一个文件提供以下内容

(defun ar-comment-or-uncomment-lor (&optional copy beg end)
  "Comment line or region, unless it's already commented:
uncomment then.

..." ...

之后光标在下一行，允许重复执行。

使用 C-u 复制当前行并将其作为上面的注释插入 - 从而在编辑时提醒先前的状态。

在这里获取：

https://github.com/andreas-roehler/werkstatt/blob/master/ar-comment-lor.el

Answer 7

这里对 Ehvince 的函数进行了细微的更改，如果文本被注释掉，它只会前进到下一行。即，如果取消注释文本，您通常希望光标保留。

(defun comment-or-uncomment-region-or-line ()
  "Comments or uncomments the region or the current line if there's no active region."
  (interactive)
  (let (beg end)
    (if (region-active-p)
        (setq beg (region-beginning) end (region-end))
      (setq beg (line-beginning-position) end (line-end-position)))
    (comment-or-uncomment-region beg end)
    (when (comment-only-p beg end)
        (next-logical-line))))