错误处理不适用于幻灯片 ID

Question

无法处理我的代码中的异常。我已经编写了下面的代码来将 powerpoint 表的内容传输到数组中，但它一直抛出一个异常说

幻灯片（未知成员）：请求无效。幻灯片 ID 无效。

我输入了错误句柄来尝试跳过它，因为在出​​现错误的情况下条目是否留空对我来说并不重要。但是，我无法让它通过这个错误！ （接下来我不能使用简历）。任何帮助都会很棒。

'loop through table and store values to a temporary array in order to sort it
'NOTE that the Table starts at (1,1) and the  storage array starts at (0,0) (see "j")
For j = 1 To oTbl.Rows.Count

    'First check that the string being stored is a hyperlink and not an empty cell
    If Not (oTbl.Cell(j, 2).Shape.TextFrame.TextRange.ActionSettings(ppMouseClick).Hyperlink.SubAddress) = "" Then

        'create a temp variable to operate on the hyperlink address in each row in the table
        subAd = oTbl.Cell(j, 2).Shape.TextFrame.TextRange.ActionSettings(ppMouseClick).Hyperlink.SubAddress

        'Find the CURRENT slideIndex and store in column 1 (for sorting)
        'write error condition for if the slideID points to a slide that has been deleted
On Error GoTo errCatch
        pLinkNumber = Left(subAd, InStr(subAd, ",") - 1)
        aStorage(j - 1, 1) = ActivePresentation.slideS.FindBySlideID(CLng(pLinkNumber)).SlideIndex

        'store the CURRENT hyperlink address as column 0 (after defining colum 1 for error handling reasons)
        aStorage(j - 1, 0) = subAd

    Else
errCatch:
    End If
Next j

Answer 1

你的错误路径与你的“快乐路径”交织在一起。

良好的错误处理应该在它自己的执行路径中。

我会将 errCatch 标签重命名为例如Skip，然后在程序底部添加：

    Exit Sub
 ErrCatch:
     Err.Clear
     Resume Skip

现在“快乐路径”在Exit Sub 结束，“错误路径”跳转到这个小子程序，它清除错误并恢复到Skip 标签。该“恢复”部分告诉 VBA 运行时“嘿，我们不再处于错误状态” - 当前您的代码进入错误状态，然后没有任何信息告诉 VBA 您已完成处理该错误，所以 errCatch 得到跳转到，然后 VBA 将“快乐路径”理解为错误处理子例程：它希望您处理错误并最终 Resume 到“快乐路径”，但发生的是错误本质上是未处理，并且错误状态持续到下一个循环迭代。

这就是说On Error GoTo 语句可能应该被拉出循环范围，假设oTbl.Rows.Count 没有失败的理由（或者是吗？）。每次迭代都运行它是多余的。

---

我不能使用继续下一个

为什么不呢？在其有限的范围内，它是一个很好的工具！

Private Function GetSlideByID(ByVal id As Long) As Slide
    On Error Resume Next
    Set GetSlideByID = ActivePresentation.slideS.FindBySlideID(id)
End Function

现在你可以这样做了：

Dim thisSlide As Slide
Set thisSlide = GetSlideByID(CLng(pLinkNumber))
If Not thisSlide Is Nothing Then
    aStorage(j - 1, 1) = thisSlide.SlideIndex
    aStorage(j - 1, 0) = subAd
End If

不再需要On Error 语句或行标签！