vbObjectError 应该使用哪些数字？答案

【问题标题】：What numbers should be used with vbObjectError?vbObjectError 应该使用哪些数字？
【发布时间】：2021-11-20 23:45:13
【问题描述】：

This page 说：

“如果您产生错误，那么您应该将您的号码添加到 vbObjectError 常量。例如 Err.Raise Number = vbObjectError + 1000。 513 - 65535 范围可用于用户定义的错误。"

还有O'Reilly says:

“我们剩下的数字在 vbObjectError + 512 到 vbObjectError + 65535 范围内”

好的，我做到了，但我得到的是本地错误，而不是自定义错误：

Err.Raise vbObjectError + 515
Automation error
A syntax error occurred trying to evaluate a query string

This site 表示该错误消息的错误代码是

EVENT_E_QUERYSYNTAX As Long = &H80040203

VBA 即时窗格证实了这一点：

?&H80040203
-2147220989  <-- equals vbObjectError + 515

bettersolutions.com 还说：

“范围 513 - 65535 可用于用户定义的错误”

如果我应该添加 vbObjectError，并且如果 513-65535 可用，那么为什么 Err.Raise vbObjectError + 515 会给我一个原生 Visual Basic 错误！？

好吧，假设他们的意思是我的自定义代码应该从 513 开始，忘记 vbObjectError。但是更好的解决方案Codes page 显示了 520、521、一些 700 和一些 31000 的本机错误。

我已经阅读了关于这个主题的各种文章和 SO 页面，但仍然很困惑。

我读过的微软文档似乎给出了不同的建议：

“用户定义的错误编号应该大于这个值。” https://docs.microsoft.com/en-us/dotnet/api/microsoft.visualbasic.constants.vbobjecterror

那么，我可以从 vbObjectError + 1 开始吗？

更新 1：本机错误

此过程列出您设置的任何数字范围内的每个唯一错误。

Sub ListErrs()
          Dim lRow As Long, lCol As Long, lErr As Long, sError As String
          lCol = 4
          Application.ScreenUpdating = False

          For lErr = -2000000 To 1000000
                    Application.StatusBar = lErr
                    On Error Resume Next
                    Err.Raise lErr
                    If (Error <> sError) Then
                              lRow = lRow + 1
                              If lRow > 1048576 Then
                                        lRow = 1
                                        lCol = lCol + 1
                              End If
                              sError = Error
                              Cells(lRow, lCol) = lErr & " : " & sError
                              Windows(1).ScrollRow = lRow
                    End If
                    On Error GoTo 0
                    DoEvents
          Next lErr


          Application.ScreenUpdating = True
End Sub

我对 -200 万到 +100 万之间的每个数字以及 -20 亿 (vbObjectErr) 到 -200 万之间的许多（不是全部）数字运行它。我没有跑完 -20 亿 (vbObjectErr) 和 -200 万之间的所有数字，因为这需要一周时间（也许有人可以让它更快）。

这是我发现的。这些结果似乎与有关更好解决方案的信息不一致。

-2147221504 Automation error
-2147221230 ActiveX component can't create object
-2147221229 Automation error
-2147221164 ActiveX component can't create object
-2147221163 Automation error
-2147221021 ActiveX component can't create object
-2147221020 Automation error
-2147221018 File name or class name not found during Automation operation
-2147221017 Automation error
-2147221014 File name or class name not found during Automation operation
-2147221013 Automation error
-2147221006 Automation error
-2147221005 ActiveX component can't create object
-2147221004 Automation error
-2147221003 ActiveX component can't create object
-2147221002 Automation error
-2147220994 ActiveX component can't create object
-2147220993 Automation error
-2000000    Automation error
0   Invalid procedure call or argument
1   Application-defined or object-defined error
3   Return without GoSub
4   Application-defined or object-defined error
5   Invalid procedure call or argument
6   Overflow
7   Out of memory
8   Application-defined or object-defined error
9   Subscript out of range
10  This array is fixed or temporarily locked
11  Division by zero
12  Application-defined or object-defined error
13  Type mismatch
14  Out of string space
15  Application-defined or object-defined error
16  Expression too complex
17  Can't perform requested operation
18  User interrupt occurred
19  Application-defined or object-defined error
20  Resume without error
21  Application-defined or object-defined error
28  Out of stack space
29  Application-defined or object-defined error
35  Sub or Function not defined
36  Application-defined or object-defined error
47  Too many DLL application clients
48  Error in loading DLL
49  Bad DLL calling convention
50  Application-defined or object-defined error
51  Internal error
52  Bad file name or number
53  File not found
54  Bad file mode
55  File already open
56  Application-defined or object-defined error
57  Device I/O error
58  File already exists
59  Bad record length
60  Application-defined or object-defined error
61  Disk full
62  Input past end of file
63  Bad record number
64  Application-defined or object-defined error
67  Too many files
68  Device unavailable
69  Application-defined or object-defined error
70  Permission denied
71  Disk not ready
72  Application-defined or object-defined error
74  Can't rename with different drive
75  Path/File access error
76  Path not found
77  Application-defined or object-defined error
91  Object variable or With block variable not set
92  For loop not initialized
93  Invalid pattern string
94  Invalid use of Null
95  Application-defined or object-defined error
96  Unable to sink events of object because the object is already firing events to the maximum number of event receivers that it supports
97  Can not call friend function on object which is not an instance of defining class
98  A property or method call cannot include a reference to a private object, either as an argument or as a return value
99  Application-defined or object-defined error
321 Invalid file format
322 Can't create necessary temporary file
323 Application-defined or object-defined error
325 Invalid format in resource file
326 Application-defined or object-defined error
380 Invalid property value
381 Invalid property array index
382 Set not supported at runtime
383 Set not supported (read-only property)
384 Application-defined or object-defined error
385 Need property array index
386 Application-defined or object-defined error
387 Set not permitted
388 Application-defined or object-defined error
393 Get not supported at runtime
394 Get not supported (write-only property)
395 Application-defined or object-defined error
422 Property not found
423 Property or method not found
424 Object required
425 Application-defined or object-defined error
429 ActiveX component can't create object
430 Class does not support Automation or does not support expected interface
431 Application-defined or object-defined error
432 File name or class name not found during Automation operation
433 Application-defined or object-defined error
438 Object doesn't support this property or method
439 Application-defined or object-defined error
440 Automation error
441 Application-defined or object-defined error
442 Connection to type library or object library for remote process has been lost. Press OK for dialog to remove reference.
443 Automation object does not have a default value
444 Application-defined or object-defined error
445 Object doesn't support this action
446 Object doesn't support named arguments
447 Object doesn't support current locale setting
448 Named argument not found
449 Argument not optional
450 Wrong number of arguments or invalid property assignment
451 Property let procedure not defined and property get procedure did not return an object
452 Invalid ordinal
453 Specified DLL function not found
454 Code resource not found
455 Code resource lock error
456 Application-defined or object-defined error
457 This key is already associated with an element of this collection
458 Variable uses an Automation type not supported in Visual Basic
459 Object or class does not support the set of events
460 Invalid clipboard format
461 Method or data member not found
462 The remote server machine does not exist or is unavailable
463 Class not registered on local machine
464 Application-defined or object-defined error
481 Invalid picture
482 Printer error
483 Application-defined or object-defined error
735 Can't save file to TEMP
736 Application-defined or object-defined error
744 Search text not found
745 Application-defined or object-defined error
746 Replacements too long
747 Application-defined or object-defined error
65536   Invalid procedure call or argument

更新 2：.Source

如果 VB 允许每个应用程序使用消歧器定义它自己的错误号（甚至重叠的错误号）似乎会更好，但我知道什么？我在下面的回答演示了使用 .Source 作为歧义符的可能解决方案。

【问题讨论】：

(Err.)Number property
@T.M.是的，该页面显示“通过将您选择的数字作为错误代码添加到 vbObjectError 常量来设置 Err.Number。”这篇文章没有告诉我可用范围是多少，也没有澄清我帖子中的困惑。

标签： excel vba error-handling custom-errors custom-error-handling

【解决方案1】：

您可以使用以下代码并找出实际免费错误数是多少：

Sub Errs()

    Dim i As Long
    
    On Error GoTo myErrorHandler
    For i = 1 To 1000 ' change loop control values to your needs 
        Err.Raise vbObjectError + i
    Next
    

myErrorHandler:
    If Err.Description = "Automation error" Then
        With Worksheets("MyErrorSheet") ' change "MyErrorSheet" to your actual "error log" sheet name
            .Cells(.Rows.Count, 1).End(xlUp).Offset(1).Resize(, 2).Value = Array(i, Err.Description)
        End With
    End If
    Resume Next
    
End Sub

【讨论】：

确实可以，但是 1) 我想真正了解 VB，因为它旨在工作。 2）为什么你只去了1000？ 3) 为什么要添加到 vbObjectError？
4) 你为什么不去否定？
就像模板代码一样。（请参阅评论“'根据您的需要更改循环控制值”）
您的模板没有告诉我们限制是什么。
为什么会出现“自动化错误”？

【解决方案2】：

如果我应该添加 vbObjectError，并且如果 513-65535 可用，那么为什么 Err.Raise vbObjectError + 515 会给我一个原生 VB 错误！？

它没有。这不是原生 VB 错误。 Native VB errors 里面没有vbObjectError。

VBA 建立在 COM 之上，并且完全与 COM 对象有关。
vbObjectError，即0x80040000，代表HRESULT error code，它具有：

S = 1 (SEVERITY_ERROR)，表示失败，并且
Facility = FACILITY_ITF

关于FACILITY_ITF 文档指出：

对于从接口方法返回的大多数状态代码。错误的实际含义由接口定义。也就是说，从两个不同接口返回的两个具有完全相同的 32 位值的 HRESULTs 可能具有不同的含义。

这正是您在这里看到的。您合法地使用 vbObjectError + 515 的值作为您自己的错误代码，但由于您从未为该自定义错误提供自定义描述，因此系统 [un] 反而为该 HRESULT 获取了默认 COM 描述，如定义其他一些 COM 组件。

那么，我可以从 vbObjectError + 1 开始吗？

您可以从vbObjectError + 0 开始。只需将第三个参数中的文字描述提供给Err.Raise：

Err.Raise vbObjectError + 515, , "This is totally my own error and not a syntax error about evaluating some strings."

话虽如此，请注意将vbObjectError 添加到您的实际错误代码中仅适用于从类模块中引发错误（坦率地说，不遵循此要求不会对您有用只要您留在 VBA 中，就会受到任何伤害）。当从模块中的普通函数引发错误时，您甚至不会被要求这样做，并且可以直接使用错误代码。

现在，有一个矛盾：Err.Raise 告诉您错误代码 513–65535 可用于您的自定义错误，而 Trappable errors 声称代码 0-1000 保留供将来使用（并在 30000 中列出一些代码也被占用）。请注意，这是关于不涉及添加任何 vbObjectErrors 的原始数字 - 这可能是造成 vbObjectError + 513 是最低可用数字的误解的根源。
或者，您可能会说这不是一个误解，而是一个经验法则，以使您的错误代码保持同步：513 从模块引发，vbObjectError + 513 从对象引发。

我个人经常发现Err.Raise 5, , "Description" 非常适合大多数用途。

【讨论】：

Err.Number 是否独立于 HRESULT？必须有直接关系，否则 VB 怎么能从“其他组件”中找到 HRESULT？“其他组件”是否包括所有第 3 方引用？那么，这是否意味着那些其他组件未能尊重保留范围？如果我们可以随意使用 VB 的“保留”范围，那么保留范围的意义何在？
@johnywhy 是的，Err.Number 独立于 HRESULT，否则在 COM 中提高错误号 5 将没有意义，请参阅docs.microsoft.com/en-us/windows/win32/com/… VB 在这里所做的。我不知道它是如何定义的，默认情况下描述来自哪里（哪个 COM 组件），但它必须是系统的，而不是任何第三方。 VB没有保留范围，COM does（啊，this是512号的来源）。
@johnywhy 您没有其他方法可以在 VBA 中设置错误消息，是吗？除了提供描述，因为这就是sets up error info。因此，有一个消息描述表，并在每次引发错误时从中获取描述。
@johnywhy 因为 COM 这么说？ VBA 类是 COM 对象，因此如果它们遵循 COM 规则并以 COM 世界的其他部分可以理解的形式生成错误代码，那就太好了。我不知道这是怎么回事，例如错误号 5，VBA 很容易自己引发，因此我没有过多关注整个 vbObjectError 业务。
@johnywhy 在 VBA 中意味着您不会将 VBA 类的实例传递给其他一些外部的、非 VBA 的核心 COM 系统。

【解决方案3】：

可能有任意数量的工作簿生成自定义错误。试图绕过本地数字并相互绕过会产生复杂而脆弱的错误处理情况。

这是一个建议的解决方案，我认为可以解决这个问题。

如果我的自定义错误编号与本机错误编号重叠，则此解决方案不关心。它使我能够拥有自定义错误编号策略，而不必担心与本机错误（或其他工作簿或加载项生成的错误）发生冲突。

该解决方案利用了 Err 的 .Source 属性。通常，.Source 会加载导致错误的 VBA 项目的名称。如果您已命名 VBA 项目，该自定义名称将被加载到 .Source。

因此，我们可以轻松地使用 .Source 来消除错误编号的歧义。

工作表上名为“tblCustomErrors”的表：

ErrNum  ErrDescription
11  User clicked pause
53  User cancelled the process
1   User had a chicken
2   Chicken ate user

VBA：

Enum CustomErrs
          LaidEgg = 1
          UserEaten = 2
          Paused = 11
          Cancelled = 53
End Enum


Sub Test_Handler()
          On Error GoTo HANDLER

          ' Native errors
          Debug.Print 1 / 0            ' 11, Division by zero
          Err.Raise 11                 ' same
          Kill "C:\Doesn't-Exist.txt"         ' 53, File not found

          ' Custom errors 
          Err.Raise CustomErrs.Paused, xlCustom    ' re-uses native err number
          Err.Raise CustomErrs.Cancelled, xlCustom    ' re-uses native err number
          Err.Raise CustomErrs.LaidEgg, xlCustom
          Err.Raise CustomErrs.UserEaten, xlCustom
          
          Exit Sub
HANDLER:
          GlobalHandler
          Resume Next
End Sub


Sub GlobalHandler()
          Dim sDesc As String
          With Err
                    If (.Source = xlCustom) Then
                              ' get description from worksheet
                              sDesc = Application.VLookup(.Number, [tblCustomErrors], 2, False)
                              .Description = sDesc
                    End If 

                    MsgBox .Description
          End With
End Sub

枚举

使用枚举而不是显式数字的一个优点是您可以获得有意义的智能感知和自记录代码。

Err.Raise LaidEgg, xlCustom

警告：不要使用 0 作为错误编号，它会因“自动化错误”而失败。

我相信这可能是 .Source 的用途。

vbObjectError

这个解决方案可以结合vbObjectError来避免原生数字，同时仍然提供集中处理的便利，这样：

Enum CustomErrs
          LaidEgg = vbObjectError
          UserEaten
          Paused
          Cancelled
End Enum

编码说明

可选地，不是将描述存储在工作表中，而是可以通过这种方式将它们硬编码到 VBA 中。这是对上述 VBA 的修改。

...
Sub GlobalHandler()
    ...
          Select Case Err.Number
                    Case LaidEgg
                              MsgBox "User had a chicken."
                              ' other custom actions
                    Case UserEaten
                              MsgBox "Chicken ate the user."
                              ' other custom actions
                    Case Paused
                              MsgBox "User clicked pause."
                              ' other custom actions
                    Case Cancelled
                              MsgBox "User cancelled the process."
                              ' other custom actions
              End Select
    ...

【讨论】：

@GSerg 提到重复使用本机错误编号可能会“混淆其他消费者”。可能。需要考虑的事情。
我更新了解决方案以使用 vbObjectError 来避免原生数字。