≡-推理和“与”模式

Question

我正在证明filter 和map 的一些属性，一切都很顺利，直到我偶然发现了这个属性：filter p (map f xs) ≡ map f (filter (p ∘ f) xs)。以下是相关代码的一部分：

open import Relation.Binary.PropositionalEquality
open import Data.Bool
open import Data.List hiding (filter)

import Level

filter : ∀ {a} {A : Set a} → (A → Bool) → List A → List A
filter _ [] = []
filter p (x ∷ xs) with p x
... | true  = x ∷ filter p xs
... | false = filter p xs

现在，因为我喜欢使用 ≡-Reasoning 模块编写证明，所以我尝试的第一件事是：

open ≡-Reasoning
open import Function

filter-map : ∀ {a b} {A : Set a} {B : Set b}
             (xs : List A) (f : A → B) (p : B → Bool) →
             filter p (map f xs) ≡ map f (filter (p ∘ f) xs)
filter-map []       _ _ = refl
filter-map (x ∷ xs) f p with p (f x)
... | true = begin
  filter p (map f (x ∷ xs))
    ≡⟨ refl ⟩
  f x ∷ filter p (map f xs)
--  ...

但是很可惜，这没有用。试了一个小时，终于放弃了，用这个方法证明了：

filter-map (x ∷ xs) f p with p (f x)
... | true  = cong (λ a → f x ∷ a) (filter-map xs f p)
... | false = filter-map xs f p

仍然好奇为什么通过≡-Reasoning 不起作用，我尝试了一些非常琐碎的事情：

filter-map-def : ∀ {a b} {A : Set a} {B : Set b}
                 (x : A) xs (f : A → B) (p : B → Bool) → T (p (f x)) →
                 filter p (map f (x ∷ xs)) ≡ f x ∷ filter p (map f xs)
filter-map-def x xs f p _  with p (f x)
filter-map-def x xs f p () | false
filter-map-def x xs f p _  | true = -- not writing refl on purpose
  begin
    filter p (map f (x ∷ xs))
  ≡⟨ refl ⟩
    f x ∷ filter p (map f xs)
  ∎

但是 typechecker 不同意我的观点。目前的目标似乎仍然是filter p (f x ∷ map f xs) | p (f x)，即使我在p (f x) 上进行模式匹配，filter 也不会减少到f x ∷ filter p (map f xs)。

有没有办法让≡-Reasoning 工作？

谢谢！

Answer 1

with-clauses 的问题在于 Agda 会忘记它从模式匹配中学到的信息，除非您事先安排好保留这些信息。

更准确地说，当 Agda 看到 with expression 子句时，它会将当前上下文和目标中所有出现的 expression 替换为新变量 w，然后将具有更新上下文和目标的变量提供给with 子句，忘记关于它的起源的一切。

在您的情况下，您在 with 块内写入filter p (map f (x ∷ xs))，因此它在 Agda 执行重写后进入范围，因此 Agda 已经忘记了 p (f x) 是 true 并且不会减少术语。

您可以使用标准库中的“检查”模式之一来保留相等性证明，但我不确定它对您的情况有何用处。